Topic: Ellipitical leader

[pmvliet]

I am doing a bunch of electrical conduit plans and needs to group runs
of conduit to label the elevations.  I'd like some ideas on creating a leader
which will allow me to group (basic lines) to identify the elevation.
In portions I am only labeling 1 line, in others it can be up to 30.

I was thinking when I place an ellipse, I pick one point (pt1)
then the other point (pt2) then a third point (pt3) for the depth.
I would then like to start pline from pt2 to create the leader.

I guess it would be better if the line goes at the angle of pt1 & pt2.
Ideally, if it was all one line, but that's too advanced for me...

Thanks,
Pieter

[M-dub]

I would love something like that, too... We've always used blocks, standard DOT BLANK leaders or just ellipses and lines...

[Dinosaur]

might something like THIS work for you?

[pmvliet]

might something like THIS work for you?

I looked at it... Not sure how to tweak it to become an ellipse though 

A simple method for me to start would be to use only half an ellipse.
have a pline that starts at the text (pt1), click next to conduit (pt2)
clicks on other side of conduit (pt3) then creates an arc back
to pt2...

[CAB]

Quickie

Code: [Select]

(defun c:ELL ()
  (vl-catch-all-apply 'vl-cmdf (list "ellipse" pause pause pause))
  (vl-catch-all-apply 'vl-cmdf (list ".pline" "nea" pause pause pause ""))
  (princ)
)

[Fatty]

might something like THIS work for you?

I looked at it... Not sure how to tweak it to become an ellipse though 

A simple method for me to start would be to use only half an ellipse.
have a pline that starts at the text (pt1), click next to conduit (pt2)
clicks on other side of conduit (pt3) then creates an arc back
to pt2...

Try ElLead.lsp from this web page:
Scroll 2/3 page down to search

~'J'~

[pmvliet]

Try ElLead.lsp from this web page:
Scroll 2/3 page down to search

~'J'~

Looks interesting, but can't download the code... I get a "page not found error"...

[cmwade77]

The link no longer works , do you have another one?

[gile]

Hi,

Just less quickie than CAB's one

Code: [Select]

(defun c:elleader (/ p1 p2 elps elst)
  (and
    (setq p1 (getpoint "\nMajor axis start point:"))
    (setq p2 (getpoint p1 "\nMajor axis end point:"))
    (vl-cmdf "_ellipse" p1 p2 (/ (distance p1 p2) 8.0))
    (vl-cmdf "_leader" "_non" p2 pause "_a")
    (setq elst (entget (entlast)))
    (entmod (subst '(71 . 0) (assoc 71 elst) elst))
  )
  (princ)
)

[fixo]

Try ElLead.lsp from this web page:
Scroll 2/3 page down to search

~'J'~

Looks interesting, but can't download the code... I get a "page not found error"...

I've found a copy of this file:

Code: [Select]

;|ElLead.Lsp
Draws Ellipse leaders with only 3 picked points.
Size and rotation of the Ellipse is based on your first 2 points.
Uses DTEXT for annotation.
Scale is relative to the DIMSCALE variable.

Change RATIO variable to change width of ellipse - 6 is default

-----------------------------------------------------------------------
-----------------------------------------------------------------------
 Created by J. Tippit, SPAUG President
    E-mail:                     jefft@iglobal.net
    Web Site:                http://www.spaug.org
-----------------------------------------------------------------------
-----------------------------------------------------------------------

1.0 Created 01/22/99

|;

(setq RATIO 6)

(defun c:ELLEAD ()
   (setvar "cmdecho" 0)
   (command "undo" "be")
   (setq #OSMOD (getvar "osmode"))
   (setq #ORMOD (getvar "orthomode"))
   (setvar "osmode" 0)
   (setvar "orthomode" 1)
   (setq PT1 (getpoint "\nFirst point for Ellipse: "))
   (setq PT2 (getpoint PT1 "\nLength/Angle of Ellipse: "))
   (setq ANG (angle PT1 PT2))
   (setvar "snapang" ANG)
   (setq ANG2 (atof (angtos ANG 0)))
   (if (or (>= ANG2 270.0)(<= ANG2 90))
      (setq ANG3 "0")
      (setq ANG3 "180")
   )
   (setvar "orthomode" 1)
   (setq DI1 (/ (distance PT1 PT2) RATIO))
   (setq DI2 (rtos (* (getvar "dimscale") 0.125) 2))
   (command "ellipse" PT1 PT2 DI1)
   (setq PT3 (getpoint PT2 "\nEndpoint of Leader: "))
   (setq PT4 (strcat "@" DI2 "<" ANG3))
   (command "pline" PT2 PT3 PT4 "")
   (setq DI3 (rtos (* (getvar "dimscale") 0.0859375) 2))
   (setq PT5 (strcat "@" DI3 "<" ANG3))
   (setvar "snapang" 0)
   (princ "\nEnter TEXT <ENTER for none>: ")
   (if (= ANG3 "0")
      (command "dtext" "j" "ml" PT5 (* (getvar "dimscale") 0.09375) "")
      (command "dtext" "j" "mr" PT5 (* (getvar "dimscale") 0.09375) "")
   )
   (setvar "orthomode" #ORMOD)
   (setvar "osmode" #OSMOD)
   (command "undo" "e")
   (setvar "cmdecho" 1)
   (princ)
)
(prompt "\n(c) Copyright TIPPIT 1999
\nType ElLead to run.\tVersion 1.0 ")
(princ)

~'J'~