Author Topic: Weld Symbols  (Read 12169 times)

0 Members and 1 Guest are viewing this topic.

deegeecees

  • Guest
Weld Symbols
« on: September 20, 2005, 10:50:34 AM »
Anyone have a good weld symbol routine? I have one from the early 90's, its probably been that long since I've used it. I know MDT has its own, but I've got AutoCAD vanilla right now.

David Hall

  • Automatic Duh Generator
  • King Gator
  • Posts: 4075
Re: Weld Symbols
« Reply #1 on: September 20, 2005, 10:51:49 AM »
Post what you have and maybe we can improve it.
Everyone has a photographic memory, Some just don't have film.
They say money can't buy happiness, but it can buy Bacon and that's a close second.
Sometimes the question is more important than the answer. (Thanks Kerry for reminding me)

Bob Wahr

  • Guest
Re: Weld Symbols
« Reply #2 on: September 20, 2005, 11:05:25 AM »
It's one I've got on the "things I'd like to write when I have the time" list but I haven't made it down to it yet.

Hmmm...I think that I might need to start giving my lists shorter names.

deegeecees

  • Guest
Re: Weld Symbols
« Reply #3 on: September 20, 2005, 11:13:18 AM »
Heres the Lisp:
Code: [Select]
;------------------------------------------------------------------------
;                    AWELD  Ver. 3.1
;         
;          Welding Synbol Placement Procedure
;
;         By Eric Howard [76424,1036] 11-18-92
;
;------------------------------------------------------------------------
;
;          The AWELD Symbol Placement Procedure draws welding symbols
;     without using a library of blocks. All weld symbol geometry is placed
;     on the layer "WELD_SYM" with the blue color assigned to the layer.
;     The size is determined by the variable "DIMSCALE".
;
;     The ACAD.MNU file must be modified for maxinum
;     productive. To do this the following lines of code should
;     be added.
;
;     Add this line to any popup menu:
;
;     [Weld Symbol]^C^C(IF (NULL C:AWELD) (PROGN (PRINC "Initial load -- Please wait...")
;                      (PRINC) (LOAD "{path name} AWELD")(PRINC))(PRINC)) AWELD
;
;     The {path name} is where the LISP file is located
;     ie... "C:/AUTODESK/LISP". Use forward slash instead
;     of the back slash. This line allows that if the
;     program is already loaded that it will not load again.
;
;     To manualy load the file "AWELD.LSP" type the following
;     at the command prompt: (load "{path name}/AWELD") and
;     type AWELD at the command prompt to start the program.
;
;     The file "WELDS.ICN" is the icon menu that selects the
;     weld type and must be added to your main menu under
;     the begining of the "**ICON" section. The file "WELDS.SLB"
;     is the slide library for the icon menu and must be
;     placed in a directory where AUTOCAD can access it.
;     The "SUPPORT" directory is where the other AutoCAD ".SLB"
;     files are placed and are accessable by the "SET" command.
;
(DEFUN C:AWELD (/ OLDERROR ORTH LYR SCL P1 P2 WELDTYP A1 P3 TP1 TP2 TXTSTY)
    ;
    ;---------------------------------
    ;   Set Enviorment Information
    ;---------------------------------
    ;
    (SETVAR "CMDECHO" 0)
    (SETQ OLDERROR *ERROR* *ERROR* WELDERROR)
    (SETQ ORTH (GETVAR "ORTHOMODE"))
    (SETQ TXTSTY (GETVAR "TEXTSTYLE"))
    (SETVAR "ORTHOMODE" 0)
    (SETQ SCL (GETVAR "DIMSCALE"))
    (SETQ LYR (GETVAR "CLAYER"))
    (SETQ MRR (GETVAR "MIRRTEXT"))
    (SETVAR "MIRRTEXT" 0)
    ;
    ;----------------------------------------------------
    ;   Setting Layer Preliminary Information
    ;----------------------------------------------------
    ;
    (SETQ LR1 (TBLSEARCH "LAYER" "WELD_SYM"))
    (IF (= LR1 nil)
        (COMMAND "LAYER" "NEW" "WELD_SYM" "COLOR" "BLUE" "WELD_SYM" "SET" "WELD_SYM" "")
        (COMMAND "LAYER" "SET" "WELD_SYM" "")
    )   
    ;
    ;------------------------------------------
    ;   Select Points and Symbol Information
    ;------------------------------------------
    ;
    (PROMPT "\nSelect weld joint <Return to exit>")
    (WHILE (SETQ P1 (GETPOINT))
        (SETQ P2 (GETPOINT P1 "\nNext point"))
        ;
        ;-----------------------------------------------------------
        ;   Loop to re-initialize Weld Symbol Placement Procedure
        ;-----------------------------------------------------------
        ;
        (IF (= WELDTYP nil)
            (WSET)
            (DSET)
        )   
        (IF (OR (<= (ANGLE P1 P2) (DTR 90)) (>= (ANGLE P1 P2) (DTR 270)))
            (SETQ A1 0)
            (SETQ A1 (DTR 180))
        )
        (SETQ P3 (POLAR P2 A1 (* SCL 0.60)))
        ;
        ;-----------------------------------------------------------
        ;   Sets text placement points
        ;-----------------------------------------------------------
        ;
        (IF (= 0 A1)
            (PROGN
                (SETQ TP1 (POLAR P2 A1 (* SCL 0.25)))
                (SETQ TP2 (POLAR P2 A1 (* SCL 0.95)))
            )
            (PROGN
                (SETQ TP1 (POLAR P2 A1 (* SCL 0.95)))
                (SETQ TP2 (POLAR P2 A1 (* SCL 0.25)))
            )
        )   
        (SETQ TP1 (POLAR TP1 (DTR 90) (* SCL 0.15)))       
        (SETQ TP2 (POLAR TP2 (DTR 90) (* SCL 0.15)))     
        (COMMAND "PLINE" P1 "W" 0 (* SCL 0.0469) (POLAR P1 (ANGLE P1 P2) (* SCL 0.125)) "W" 0 0 P2 (POLAR P2 A1 (* SCL 1.20)) "")
        ;
        ;-------------------------------------------------
        ;   "All Around symbol" information if required
        ;-------------------------------------------------
        ;
        (IF (= ALLR "Y")   
            (COMMAND "CIRCLE" P2 (* SCL 0.09))
        )
        ;
        ;-------------------------------------------------
        ;   Invokes program to draw selected weld type
        ;-------------------------------------------------
        ;
        (EVAL (READ (READ WELDTYP)))
        (IF (= (CDR (ASSOC 40 (TBLSEARCH "STYLE" TXTSTY))) 0)
            (PROGN
                (COMMAND "TEXT" "J" "MC" TP1 (* SCL 0.094) 0 WELDSIZE)
                (COMMAND "TEXT" "J" "MC" TP2 (* SCL 0.094) 0 PITCH)
            )
            (PROGN
                (COMMAND "TEXT" "J" "MC" TP1 0 WELDSIZE)
                (COMMAND "TEXT" "J" "MC" TP2 0 PITCH)
            )
        )   
        (IF (= WELDSIDE "This")
            (SETQ QUES "Y")
            (SETQ QUES "N")
        )
        (IF (OR (= WELDSIDE "This") (= WELDSIDE "Both"))
            (COND
                ((/= (READ WELDTYP) "(BAWELD)")(COMMAND "MIRROR" "C" (POLAR TP1 (DTR 90) (* SCL 0.115)) (POLAR TP2 (DTR 270) (* SCL 0.115)) "" P2 (POLAR P2 A1 0.5) QUES))
                ((= (READ WELDTYP) "(BAWELD)")(COMMAND "MIRROR" "C" (POLAR TP1 (DTR 90) (* SCL 0.115)) (POLAR TP2 (DTR 270) (* SCL 0.115)) "R" RBAK "" P2 (POLAR P2 A1 0.5) QUES))
            )
        )
        ;
        ;--------------------------------------------
        ;   "Field symbol" information if required
        ;--------------------------------------------
        ;
        (IF (= FIELDW "Y")
            (FLAG)
        )   
        :
        ;
        (NOTES2)
        ;
        ;--------------------------------------------
        ;   Loop to restart weld symbol placement
        ;--------------------------------------------
        ;
        (PROMPT "\nSelect weld joint <Return to exit>")
    )
    ;
    ;-------------------
    ;   Exit Procedure
    ;-------------------
    ;
    (SETVAR "ORTHOMODE" ORTH)
    (SETVAR "MIRRTEXT" MRR)
    (COMMAND "LAYER" "SET" LYR "")
    (SETQ *ERROR* OLDERROR)
    (PRINC)   
)
;
;--------------------------------------------
;   Procedure to set defaults
;--------------------------------------------
;
(DEFUN WSET ()
    (PROMPT "\nSelect weld type")
    (SETQ WELDTYP (GETSTRING (MENUCMD "I=WELDS")(MENUCMD "I=*")))
    (IF (= (READ WELDTYP) "(BAWELD)")
        (PROGN
            (PROMPT "\nSelect other weld type")
            (SETQ WELDTYP2 (GETSTRING (MENUCMD "I=WELDS")(MENUCMD "I=*")))
        )
    )
    (INITGET "Other Both This")
    (COND ((= WELDSIDE nil)(SETQ WS1 "Other" WS2 "Both" WS3 "This"))
        ((= WELDSIDE "This")(SETQ WS1 "Other" WS2 "Both" WS3 "This"))
        ((= WELDSIDE "Both")(SETQ WS1 "Other" WS2 "This" WS3 "Both"))
        ((= WELDSIDE "Other")(SETQ WS1 "This" WS2 "Both" WS3 "Other"))
    )     
    (IF (= (READ WELDTYP) "(BAWELD)")
        (PROGN
            (IF (= WS3 "Both")
                (SETQ WS3 "This")
            )
            (SETQ WELDSIDE (GETKWORD (STRCAT "\nWeld on which side?: " WS1 "/<" WS3 "> ")))
        )
        (SETQ WELDSIDE (GETKWORD (STRCAT "\nWeld on which side?: " WS1 "/" WS2 "/<" WS3 "> ")))
    )
    (IF (= WELDSIDE nil)
        (SETQ WELDSIDE WS3)
    )
    (IF (OR (= nil WELDSIZE)(= WELDSIZE ""))
        (SETQ WELDSIZE (GETSTRING "Weld fillet size: "))
        (PROGN
            (SETQ WSIZE WELDSIZE)
            (SETQ WELDSIZE (GETSTRING (STRCAT "Weld fillet size: <" WELDSIZE "> ")))
            (COND ((= WELDSIZE "") (SETQ WELDSIZE WSIZE))((= WELDSIZE "0")(SETQ WELDSIZE "")))
        )   
    )   
    (IF (OR (= nil PITCH)(= PITCH ""))
        (SETQ PITCH (GETSTRING "Length-Pitch of weld: "))
        (PROGN
            (SETQ PTCH PITCH)
            (SETQ PITCH (GETSTRING (STRCAT "Length-Pitch of weld: <" PITCH "> ")))
            (COND ((= PITCH "") (SETQ PITCH PTCH))((= PITCH "0")(SETQ PITCH "")))
        )   
    )       
    (INITGET "Y N")
    (COND ((= ALLR nil) (SETQ ALLR1 "Y" ALLR2 "N"))
        ((= ALLR "Y") (SETQ ALLR1 "Y" ALLR2 "N"))
        ((= ALLR "N") (SETQ ALLR1 "N" ALLR2 "Y"))
    )     
    (SETQ ALLR (GETKWORD (STRCAT "Weld all around?: <" ALLR1 ">/" ALLR2 " ")))
    (IF (= ALLR nil)
        (SETQ ALLR ALLR1)
    )       
    (INITGET "Y N")
    (COND ((= FIELDW nil)(SETQ FIELDW1 "Y" FIELDW2 "N"))
        ((= FIELDW "Y")(SETQ FIELDW1 "N" FIELDW2 "Y"))
        ((= FIELDW "N")(SETQ FIELDW1 "Y" FIELDW2 "N"))
    )     
    (SETQ FIELDW (GETKWORD (STRCAT "Weld in the field?: " FIELDW1 "/<" FIELDW2 "> ")))
    (IF (= FIELDW nil)
        (SETQ FIELDW FIELDW2)
    )   
    (NOTES)
)       
;
;----------------------------------------------------------
;   Displays defaults and prompts whether to reset or not
;----------------------------------------------------------
;
(DEFUN DSET ()
    (COND
        ((= (READ WELDTYP) "(SQWELD)")(SETQ WLDTYP "Square"))
        ((= (READ WELDTYP) "(UWELD)")(SETQ WLDTYP "\"U\""))
        ((= (READ WELDTYP) "(JWELD)")(SETQ WLDTYP "\"J\""))
        ((= (READ WELDTYP) "(VWELD)")(SETQ WLDTYP "\"V\""))
        ((= (READ WELDTYP) "(BWELD)")(SETQ WLDTYP "Bevel"))
        ((= (READ WELDTYP) "(FLVWELD)")(SETQ WLDTYP "Flare \"V\""))
        ((= (READ WELDTYP) "(FLBWELD)")(SETQ WLDTYP "Flare Bevel"))
        ((= (READ WELDTYP) "(FILWELD)")(SETQ WLDTYP "Fillet"))
        ((= (READ WELDTYP) "(SURWELD)")(SETQ WLDTYP "Surfacing"))
        ((= (READ WELDTYP) "(FLEWELD)")(SETQ WLDTYP "Flange Edge"))
        ((= (READ WELDTYP) "(FLCWELD)")(SETQ WLDTYP "Flange Corner"))
        ((= (READ WELDTYP) "(PLWELD)")(SETQ WLDTYP "Plug or Slot"))
        ((= (READ WELDTYP) "(BAWELD)")(SETQ WLDTYP "Back"))
    )   
    (PROMPT (STRCAT "\n\nWeld type: " WLDTYP))
    (PROMPT (STRCAT "\nSide to weld: " WELDSIDE))
    (PROMPT (STRCAT "\nWeld fillet size: " WELDSIZE))
    (PROMPT (STRCAT "\nLength-Pitch of weld: " PITCH))
    (PROMPT (STRCAT "\nWeld all around?: " ALLR))
    (PROMPT (STRCAT "\nWeld in the field?: " FIELDW))
    (IF (/= NOTE1 "")
        (PROGN
            (SETQ DPASS 1)
            (REPEAT RPT
                (PROMPT (STRCAT "\nNote " (ITOA DPASS) ": " (EVAL (READ (STRCAT "NOTE" (ITOA DPASS))))))
                (SETQ DPASS (1+ DPASS))
            )   
        )
        (PROMPT "\nNotes:")
    )   
    (INITGET "Y N")
    (SETQ ANS (GETKWORD "\nDo you want to change anything? Y or <N> "))
    (IF (= ANS nil)
        (SETQ ANS "N")
    )   
    (IF (= ANS "Y")
        (WSET)
    )
)   
;
;--------------------------------------------
;   Error handler
;--------------------------------------------
;
(DEFUN WELDERROR (MSG)
    (SETVAR "ORTHOMODE" ORTH)
    (SETVAR "MIRRTEXT" MRR)
    (COMMAND "LAYER" "SET" LYR "")
    (SETQ *ERROR* OLDERROR)
    (PRINC)
)
;

;***********************************
;   Square Weld Symbol
;***********************************

(DEFUN SQWELD ()
    (COMMAND "LINE" (POLAR P3 0 (* SCL 0.06)) (POLAR (GETVAR "LASTPOINT") (DTR 90) (* SCL 0.25)) "")
    (COMMAND "LINE" (POLAR P3 (DTR 180) (* SCL 0.06)) (POLAR (GETVAR "LASTPOINT") (DTR 90) (* SCL 0.25)) "")
)
;
;*********************************
;   "U" Weld Symbol
;*********************************
;
(DEFUN UWELD (/ UPT)
    (SETQ UPT (POLAR P3 (DTR 90) (* SCL 0.13)))
    (COMMAND "LINE" P3 UPT "")
    (COMMAND "ARC" (POLAR UPT (DTR 45) (* SCL 0.16970563)) UPT (POLAR UPT (DTR 135) (* SCL 0.16970563)))
)
;
;*********************************
;   "J" Weld Symbol OTHER Side
;*********************************
;
(DEFUN JWELD (/ JPT)
    (SETQ JPT (POLAR P3 (DTR 90) (* SCL 0.25)))
    (COMMAND "LINE" P3 JPT "")
    (COMMAND "ARC" (POLAR P3 (DTR 90) (* SCL 0.13)) "C" JPT (POLAR JPT 0 (* SCL 0.12)))
)
;
;*********************************
;   "V" Weld Symbol
;*********************************
;
(DEFUN VWELD ()
    (COMMAND "LINE" P3 (POLAR P3 (DTR 45) (* SCL 0.28284271)) "")
    (COMMAND "LINE" P3 (POLAR P3 (DTR 135) (* SCL 0.28284271)) "")
)
;
;*********************************
;   Bevel Weld Symbol
;*********************************
;
(DEFUN BWELD ()
    (COMMAND "LINE" P3 (POLAR P3 (DTR 45) (* SCL 0.28284271)) "")
    (COMMAND "LINE" P3 (POLAR P3 (DTR 90) (* SCL 0.20)) "")
)
;
;************************************
;   Flare-V Weld Symbol
;************************************
;
(DEFUN FLVWELD ()
    (COMMAND "ARC" "C" (POLAR P3 0 (* SCL 0.18)) (POLAR (GETVAR "LASTPOINT") (DTR 90) (* SCL 0.12)) (POLAR P3 0 (* SCL 0.06)))
    (COMMAND "ARC" (POLAR P3 (DTR 180) (* SCL 0.06)) "C" (POLAR P3 (DTR 180) (* SCL 0.18)) (POLAR (GETVAR "LASTPOINT") (DTR 90) (* SCL 0.12)))
)
;
;****************************************
;   Flare Bevel Weld Symbol
;****************************************
;
(DEFUN FLBWELD ()
    (COMMAND "ARC" "C" (POLAR P3 0 (* SCL 0.18)) (POLAR (GETVAR "LASTPOINT") (DTR 90) (* SCL 0.12)) (POLAR P3 0 (* SCL 0.06)))
    (COMMAND "LINE" (POLAR P3 (DTR 180) (* SCL 0.06)) (POLAR (GETVAR "LASTPOINT") (DTR 90) (* SCL 0.12)) "")
)
;
;************************************
;   Fillet Weld Symbol
;************************************
;
(DEFUN FILWELD ()
    (COMMAND "LINE" (POLAR P3 (DTR 180) (* SCL 0.10)) (POLAR (GETVAR "LASTPOINT") (DTR 90) (* SCL 0.20)) (POLAR P3 0 (* SCL 0.10)) "")
)
;
;*************************
;   Surface Weld Symbol
;*************************
;
(DEFUN SURWELD ()
    (COMMAND "ARC" (POLAR P3 0 (* SCL 0.12)) "C" (POLAR P3 0 (* SCL 0.06)) P3)
    (COMMAND "ARC" P3 "C" (POLAR P3 (DTR 180) (* SCL 0.06)) (POLAR P3 (DTR 180) (* SCL 0.12)))
)
;
;***************************************
;   Flange Edge Weld Symbol
;***************************************
;
(DEFUN FLEWELD ()
    (COMMAND "ARC" (POLAR P3 (DTR 180) (* SCL 0.18)) "C" (POLAR (GETVAR "LASTPOINT") (DTR 90) (* SCL 0.12)) (POLAR (GETVAR "LASTPOINT") 0 (* SCL 0.12)))
    (COMMAND "LINE" (GETVAR "LASTPOINT") (POLAR (GETVAR "LASTPOINT") (DTR 90) (* SCL 0.13)) "")
    (COMMAND "LINE" (POLAR (GETVAR "LASTPOINT") 0 (* SCL 0.12)) (POLAR (GETVAR "LASTPOINT") (DTR 270) (* SCL 0.13)) "")
    (COMMAND "ARC" (GETVAR "LASTPOINT") "C" (POLAR (GETVAR "LASTPOINT") 0 (* SCL 0.12)) (POLAR P3 0 (* SCL 0.18)))
)
;
;***************************************
;   Flange Corner Weld Symbol
;***************************************
;
(DEFUN FLCWELD ()
    (COMMAND "LINE" (POLAR P3 (DTR 180) (* SCL 0.06)) (POLAR (GETVAR "LASTPOINT") (DTR 90) (* SCL 0.25)) "")
    (COMMAND "LINE" (POLAR (GETVAR "LASTPOINT") 0 (* SCL 0.12)) (POLAR (GETVAR "LASTPOINT") (DTR 270) (* SCL 0.13)) "")
    (COMMAND "ARC" (GETVAR "LASTPOINT") "C" (POLAR (GETVAR "LASTPOINT") 0 (* SCL 0.12)) (POLAR P3 0 (* SCL 0.18)))
)
;
;********************************
;   Plug Weld Symbol
;********************************
;
(DEFUN PLWELD ()
    (COMMAND "LINE" (POLAR P3 (DTR 180) (* SCL 0.25)) (POLAR (GETVAR "LASTPOINT") (DTR 90) (* SCL 0.25)) (POLAR (GETVAR "LASTPOINT") 0 (* SCL 0.50)) (POLAR P3 0 (* SCL 0.25)) "")
)
;
;*************************************
;   Backing  Weld Symbol
;*************************************
;
(DEFUN BAWELD ()
    (IF (= WELDSIDE "This")
        (COMMAND "ARC" "C" P3 (POLAR P3 0 (* SCL 0.06)) (POLAR P3 (DTR 180) (* SCL 0.06)))
        (COMMAND "ARC" "C" P3 (POLAR P3 (DTR 180) (* SCL 0.06)) (POLAR P3 0 (* SCL 0.06)))
    )
    (SETQ RBAK (ENTLAST))
    (EVAL (READ (READ WELDTYP2)))
)
;
;--------------------------------------------
;   "Field symbol" information if required
;--------------------------------------------
;
(DEFUN FLAG (/ FPT)
    (SETQ FPT (POLAR P2 (DTR 90) (* SCL 0.315)))
    (SETQ FPT (POLAR FPT A1 (* SCL 0.20)))
    (COMMAND "LINE" P2 (POLAR P2 (DTR 90) (* SCL 0.375)) "")
    (COMMAND "SOLID" (GETVAR "LASTPOINT") FPT (POLAR P2 (DTR 90) (* SCL 0.255)) "")
    (COMMAND)
)
;
;--------------------------------------------
;   Converts degrees to radians
;--------------------------------------------
;
(DEFUN DTR (ANG)(* PI (/ ANG 180.0)))
;
;
;
(DEFUN NOTES ()
    (SETQ PASS 1)
    (SETQ PTEST 1)
    (WHILE (<= PTEST 3)
        (SETQ TXT1 (GETSTRING T (STRCAT "Enter Note" (ITOA PASS) " (Return to Exit): ")))
        (EVAL (READ (STRCAT "(SETQ NOTE" (ITOA PASS) " " (CHR 34) TXT1 (CHR 34) ")")))
        (IF (/= (EVAL (READ (STRCAT "NOTE" (ITOA PASS)))) "")
            (SETQ PASS (1+ PASS) PTEST (1+ PTEST))
            (SETQ PTEST 4)
        )
    )
)
;
;
(DEFUN NOTES2 ()   
    (SETQ TXTPT (POLAR P2 A1 (* SCL 1.30)))
    (SETQ TAILPT (POLAR P2 A1 (* SCL 1.20)))
    (SETQ RPT (1- PASS))
    (IF (/= NOTE1 "")                                             
        (PROGN
            (COND
                ((= RPT 1)(SETQ TXTPT1 TXTPT))
                ((= RPT 2)(SETQ TXTPT (POLAR TXTPT A1 (* SCL 0.0625)))(SETQ TXTPT1 (POLAR TXTPT (DTR 90) (* SCL 0.0781))))         
                ((= RPT 3)(SETQ TXTPT (POLAR TXTPT A1 (* SCL 0.125)))(SETQ TXTPT1 (POLAR TXTPT (DTR 90) (* SCL 0.15625))))         
            )
            (SETQ PASS 1)
            (IF (= A1 0)
                (PROGN
                    (REPEAT RPT
                        (IF (= (CDR (ASSOC 40 (TBLSEARCH "STYLE" TXTSTY))) 0)
                            (COMMAND "TEXT" "J" "ML" TXTPT1 (* SCL 0.094) 0 (EVAL (READ (STRCAT "NOTE" (ITOA PASS)))))
                            (COMMAND "TEXT" "J" "ML" TXTPT1 0 (EVAL (READ (STRCAT "NOTE" (ITOA PASS)))))
                        )
                        (SETQ PASS (1+ PASS))
                        (SETQ TXTPT1 (POLAR TXTPT1 (DTR 270) (* SCL 0.15625)))
                    )
                )
                (PROGN
                    (REPEAT RPT
                        (IF (= (CDR (ASSOC 40 (TBLSEARCH "STYLE" TXTSTY))) 0)
                            (COMMAND "TEXT" "J" "MR" TXTPT1 (* SCL 0.094) 0 (EVAL (READ (STRCAT "NOTE" (ITOA PASS)))))
                            (COMMAND "TEXT" "J" "MR" TXTPT1 0 (EVAL (READ (STRCAT "NOTE" (ITOA PASS)))))
                        )
                        (SETQ PASS (1+ PASS))
                        (SETQ TXTPT1 (POLAR TXTPT1 (DTR 270) (* SCL 0.15625)))
                    )   
                )   
            )
            (IF (= A1 0)
                (COMMAND ".LINE" TAILPT (POLAR TAILPT (DTR 45) (* SCL 0.2828)) "" "LINE" TAILPT (POLAR TAILPT (DTR -45) (* SCL 0.2828)) "")
                (COMMAND ".LINE" TAILPT (POLAR TAILPT (DTR 135) (* SCL 0.2828)) "" "LINE" TAILPT (POLAR TAILPT (DTR -135) (* SCL 0.2828)) "")
            )
        )
    )
)

It comes with a slide and icon library, I'd post it in a zip but I can't find the pond...  :-(

Crank

  • Water Moccasin
  • Posts: 1503
Re: Weld Symbols
« Reply #4 on: September 20, 2005, 01:09:57 PM »
Lilly Pond can be found at http://www.theswamp.org/lilly_pond/.

I see you're still using 2005, but this is really something for dynamic blocks.
Vault Professional 2023     +     AEC Collection

deegeecees

  • Guest
Re: Weld Symbols
« Reply #5 on: September 20, 2005, 02:01:13 PM »
Alrightee then, here's the zip ----------------> http://www.theswamp.org/lilly_pond/deegeecees/aweld.zip

deegeecees

  • Guest
Re: Weld Symbols
« Reply #6 on: January 25, 2006, 11:17:09 AM »
*bump*

CAB

  • Global Moderator
  • Seagull
  • Posts: 10401
Re: Weld Symbols
« Reply #7 on: January 30, 2006, 10:20:40 AM »
I moved the thread thinking you would get more help here.

What's wrong with the routine as it is now?
I've reached the age where the happy hour is a nap. (°¿°)
Windows 10 core i7 4790k 4Ghz 32GB GTX 970
Please support this web site.

deegeecees

  • Guest
Re: Weld Symbols
« Reply #8 on: January 30, 2006, 10:52:50 AM »
When I throw this in a menu, I get an error:

Code: [Select]
**WELDS
[Weld Type]
[AWELD(SQWELD)]"(SQWELD)"
[AWELD(UWELD)]"(UWELD)"
[AWELD(JWELD)]"(JWELD)"
[AWELD(VWELD)]"(VWELD)"
[AWELD(BWELD)]"(BWELD)"
[AWELD(FLVWELD)]"(FLVWELD)"
[AWELD(FLBWELD)]"(FLBWELD)"
[AWELD(FILWELD)]"(FILWELD)"
[AWELD(SURWELD)]"(SURWELD)"
[AWELD(FLEWELD)]"(FLEWELD)"
[AWELD(FLCWELD)]"(FLCWELD)"
[AWELD(PLWELD)]"(PLWELD)"
[AWELD(BAWELD)]"(BAWELD)"
[ Exit]^C^C^C

And I'm just too "swamped" lateley to take the time to figure it out.

CAB

  • Global Moderator
  • Seagull
  • Posts: 10401
Re: Weld Symbols
« Reply #9 on: January 30, 2006, 11:30:02 AM »
I need some spare time to look into the routine but this is giving me a problem
((= (READ WELDTYP) "(SQWELD)")(SETQ WLDTYP "Square"))

not sure what the intent was here using READ.

I'll look into it later today unless some else does.
I've reached the age where the happy hour is a nap. (°¿°)
Windows 10 core i7 4790k 4Ghz 32GB GTX 970
Please support this web site.

t-bear

  • Guest
Re: Weld Symbols
« Reply #10 on: January 30, 2006, 11:33:43 AM »
As you know, I'm no lisper.  Problem I'm having is the slide library is blank....in the acad path etc...saved in the same folder as all my lisp routines.  curiouser and curiouser....

deegeecees

  • Guest
Re: Weld Symbols
« Reply #11 on: January 30, 2006, 11:40:44 AM »
Yes Mr T I get that too. I believe the slides are called through a menu file, but the syntax isn't correct.

Thanks for looking into it CAB.

CAB

  • Global Moderator
  • Seagull
  • Posts: 10401
Re: Weld Symbols
« Reply #12 on: January 30, 2006, 12:26:37 PM »
Place this
Code: [Select]
**IMAGE_3DOBJECTS
[3D Objects]
[acad(Box3d,Box3d)]^C^C_ai_box
[acad(Pyramid,Pyramid)]^C^C_ai_pyramid
[acad(Wedge,Wedge)]^C^C_ai_wedge
[acad(Dome,Dome)]^C^C_ai_dome
[acad(Sphere,Sphere)]^C^C_ai_sphere
[acad(Cone,Cone)]^C^C_ai_cone
[acad(Torus,Torus)]^C^C_ai_torus
[acad(Dish,Dish)]^C^C_ai_dish
[acad(Mesh,Mesh)]^C^C_ai_mesh


Under the
***IMAGE

section in the ACAD.mnu file

Then delete the ACAD.mnc & ACAD.mnr files


Restart ACAD & it should work for you.
I've reached the age where the happy hour is a nap. (°¿°)
Windows 10 core i7 4790k 4Ghz 32GB GTX 970
Please support this web site.

CAB

  • Global Moderator
  • Seagull
  • Posts: 10401
Re: Weld Symbols
« Reply #13 on: January 30, 2006, 12:28:15 PM »
Ooops, I forgot I modified the lisp file, see attached.

I've reached the age where the happy hour is a nap. (°¿°)
Windows 10 core i7 4790k 4Ghz 32GB GTX 970
Please support this web site.

delium55

  • Guest
Re: Weld Symbols
« Reply #14 on: January 30, 2006, 01:38:06 PM »
Try and test this, work fine here.

François

Rename 1735c.txt for 1735c.slb

deegeecees

  • Guest
Re: Weld Symbols
« Reply #15 on: January 30, 2006, 02:00:56 PM »
Try and test this, work fine here.

François

Rename 1735c.txt for 1735c.slb

I like that one much better, thanks Francois!

meco3hp

  • Guest
Re: Weld Symbols
« Reply #16 on: February 27, 2008, 11:10:14 AM »
Hello,
      I found this thread in a search for "weld symbols".
I downloaded it and got it to load, but like most that posted to this thread, the slide library didn't have anything in it. CAB had a change to the acad.mnu, but I did a search for the acad.mnu and can't find it. Any help? I'm using acad 2006 vanilla.

Thanks!
Richard

CAB

  • Global Moderator
  • Seagull
  • Posts: 10401
Re: Weld Symbols
« Reply #17 on: February 27, 2008, 11:47:32 AM »
Copy these files and try this other routine.
http://www.theswamp.org/index.php?topic=6909.msg109181#msg109181
I've reached the age where the happy hour is a nap. (°¿°)
Windows 10 core i7 4790k 4Ghz 32GB GTX 970
Please support this web site.

meco3hp

  • Guest
Re: Weld Symbols
« Reply #18 on: February 27, 2008, 11:58:16 AM »
Hello,
       I tried that and got the following error;

ERROR! FILE NOT FOUND: WELD.DCL

Thanks!
Richard

CAB

  • Global Moderator
  • Seagull
  • Posts: 10401
Re: Weld Symbols
« Reply #19 on: February 27, 2008, 12:34:47 PM »
That file must be placed in the ACAD search path.

PS,  rename the dcl file to "WELD.DCL"
« Last Edit: February 27, 2008, 12:38:05 PM by CAB »
I've reached the age where the happy hour is a nap. (°¿°)
Windows 10 core i7 4790k 4Ghz 32GB GTX 970
Please support this web site.

Theo

  • Guest
Re: Weld Symbols
« Reply #20 on: August 29, 2014, 08:24:14 PM »
Mr. Cab,
I cannot get access to a slide and icon library. Please provide me with those files, so I can try to run the AWELD.LSP

Thank you,
Theodorus Winata
twinata@shaw.ca

andy_lee

  • Newt
  • Posts: 147
Re: Weld Symbols
« Reply #21 on: August 29, 2014, 10:53:21 PM »
where is the WELDS.SLB ?
andy.
Best regards.

Kerry

  • Mesozoic relic
  • Seagull
  • Posts: 11654
  • class keyThumper<T>:ILazy<T>
Re: Weld Symbols
« Reply #22 on: August 29, 2014, 11:06:35 PM »
As CAB has indicated,

http://www.theswamp.org/index.php?topic=6909.msg109181#msg109181

rename Tip1735b.dcl to WELD.DCL

also,
rename Tip1735c.txt to WELD.SLB
« Last Edit: August 29, 2014, 11:09:45 PM by Kerry »
kdub, kdub_nz in other timelines.
Perfection is not optional.
Everything will work just as you expect it to, unless your expectations are incorrect.
Discipline: None at all.

andy_lee

  • Newt
  • Posts: 147
Re: Weld Symbols
« Reply #23 on: August 30, 2014, 03:12:40 AM »
As CAB has indicated,

http://www.theswamp.org/index.php?topic=6909.msg109181#msg109181

rename Tip1735b.dcl to WELD.DCL

also,
rename Tip1735c.txt to WELD.SLB


Thanks kerry.
Code: [Select]
;------------------------------------------------------------------------
;                    AWELD  Ver. 3.1
;         
;          Welding Synbol Placement Procedure
;
;         By Eric Howard [76424,1036] 11-18-92
;
;------------------------------------------------------------------------

I mean this  lisp lack of SLB files .
andy.
Best regards.

Kerry

  • Mesozoic relic
  • Seagull
  • Posts: 11654
  • class keyThumper<T>:ILazy<T>
Re: Weld Symbols
« Reply #24 on: August 30, 2014, 04:28:53 AM »
I have no idea :|
Perhaps someone who was involved with the thread will be able to assist you.

kdub, kdub_nz in other timelines.
Perfection is not optional.
Everything will work just as you expect it to, unless your expectations are incorrect.
Discipline: None at all.

CAB

  • Global Moderator
  • Seagull
  • Posts: 10401
Re: Weld Symbols
« Reply #25 on: August 30, 2014, 11:00:44 AM »
Wow this is an old one.
I've reached the age where the happy hour is a nap. (°¿°)
Windows 10 core i7 4790k 4Ghz 32GB GTX 970
Please support this web site.

andy_lee

  • Newt
  • Posts: 147
Re: Weld Symbols
« Reply #26 on: August 31, 2014, 10:58:06 PM »
Wow this is an old one.

Thank you CAB, and Thanks Kerry.
andy.
Best regards.

Theo

  • Guest
Re: Weld Symbols
« Reply #27 on: September 02, 2014, 03:05:16 PM »
About Aweld.lsp
Missing slb file and the routine does'nt work.

Regards,
Theo

CAB

  • Global Moderator
  • Seagull
  • Posts: 10401
Re: Weld Symbols
« Reply #28 on: September 02, 2014, 03:39:57 PM »
Did you try version 4? The slide are in the zip file. I have not run the routine.
I've reached the age where the happy hour is a nap. (°¿°)
Windows 10 core i7 4790k 4Ghz 32GB GTX 970
Please support this web site.