Topic: send mail with VLisp

[domenicomaria]

send mail with VLisp ...

is it possible ?

I found something in theswamp, but:

(setq oa-obj (vlax-get-or-create-object "Outlook.Application"))   >   NIL !

why?

[PKENEWELL]

Here is Some Code by Alan J. Thomson from the forum. I don't remember the where original posting was:

Code - Auto/Visual Lisp: [Select]

1. ;; =========ENTER the Email Addresses Here as Strings!=================!
2. (setq *IT-Email* "someITguy@somecompany.com"
3.       *CC-Email* "myAddress@MyCompany"
4.       *MsgString* "This is a Test Message."
5. )
6. ;;=====================================================================
7.  
8.  
9. (defun c:CRGhelp (/ _catch cc file outlook email sf si ni)
10.   ;; Using Outlook, eMail selected object(s) in a temporary DWG file
11.   ;; Many thanks to Ron Perez (ronjonp) for the Outlook example (http://www.theswamp.org/index.php?topic=26953.msg324794#msg324794)
12.   ;; Alan J. Thompson, 03.28.11
13.  
14.   (vl-load-com)
15.  
16.   (defun _catch (f a) (not (vl-catch-all-error-p (vl-catch-all-apply f a))))
17.  
18.   (alert "After you choose your parts. Remember to send the file from outlook")
19.  
20.   (if
21.     (and
22.       (or (ssget "_I") (prompt "\nSelect object(s) to eMail: ") (ssget))
23.       (setq file (vl-filename-mktemp "" nil ".dwg") test (princ (strcat "\n" file)))
24.       (_catch 'vla-WBlock
25.               (list (cond (*AcadDoc*)
26.                           ((setq *AcadDoc* (vla-get-activedocument (vlax-get-acad-object))))
27.                     )
28.                     file
29.                     (vla-get-activeselectionset *AcadDoc*)
30.               )
31.       )
32.       (setq outlook (vlax-get-or-create-object "Outlook.Application")
33.             sf (vl-catch-all-apply 'vlax-invoke (list (setq ns (vlax-invoke outlook 'GetNameSpace "MAPI")) 'GetDefaultFolder 5))
34.             si (vl-catch-all-apply 'vlax-get (list (vlax-get sf 'items) 'count))
35.       )
36.       (setq email (vlax-invoke-method outlook 'CreateItem 0))
37.       (_catch 'vlax-put (list email 'Subject (strcat "Autocad help: " (vl-filename-base file) ".dwg")))
38.       (_catch 'vlax-invoke (list (vlax-get email 'Attachments) 'Add file))
39.       (_catch 'vlax-invoke (list (vlax-get email 'Recipients) 'Add *IT-Email*))
40.       (setq cc (vl-catch-all-apply 'vlax-invoke (list (vlax-get email 'Recipients) 'Add *CC-Email*)))
41.       (_catch 'vlax-put (list cc 'Type 2))
42.       (_catch 'vlax-put (list email 'Body *MsgString*))
43.     )
44.      (progn (princ "\nOutlook active...")
45.             (princ)
46.             (vlax-invoke email 'Display :vlax-true)
47.             (if (= (vl-catch-all-apply 'vlax-get (list email 'Sent)) :vlax-true)
48.                (vl-file-delete file)
49.                (progn
50.                    (if (= (setq ni (vl-catch-all-apply 'vlax-get (list (vlax-get sf 'items) 'count))) si)
51.                        (vl-file-delete file); No email was added to Sent Items - go ahead and delete.
52.                    )
53.                )
54.             )
55.      )
56.   )
57.   (foreach x (list sf ns email outlook) (and x (vlax-release-object x)))
58.   (princ)
59. )
60.  

[domenicomaria]

yes ...
but my problem is :

(setq outlook (vlax-get-or-create-object "Outlook.Application") )   >  NIL  ! ! !

[PKENEWELL]

yes ...
but my problem is :

(setq outlook (vlax-get-or-create-object "Outlook.Application") )   >  NIL  ! ! !

Is a local Outlook Installed, or are you using the web version? The above method won't work if you are just using Outlook through your browser.

[domenicomaria]

Is a local Outlook Installed?

Yes

[Lonnie]

Don't know if it helps but this worked for me.

https://www.theswamp.org/index.php?topic=55486.0;all

[PKENEWELL]

Is a local Outlook Installed?

Yes

Maybe try changing the string to "Outlook.Application.16"? Otherwise I am not sure what's going on.

[It's Alive!]

Could it be that Outlook is still 32 bit, haven't use outlook in like forever?

[kozmos]

if your email can be sent via curl, then you can use vlisp to call curl doing it. no outlook is needed

[domenicomaria]

if your email can be sent via curl, then you can use vlisp to call curl doing it. no outlook is needed

How do you do ?
can you give me an example?

[domenicomaria]

Maybe try changing the string to "Outlook.Application.16"? Otherwise I am not sure what's going on.

(setq outlook (vlax-get-or-create-object "Outlook.Application.16")) > nil

[domenicomaria]

Could it be that Outlook is still 32 bit, haven't use outlook in like forever?

I have always only used GMail

if I search for "outlook"
I get "outlook(new)" which is probably just a web app...

[EWCAD]

Non Visual solution but this is a bit of code I wrote to attach printed PDF's to an email with a subject and recipient in outlook. It just calls outlook.exe and uses the command line arguments built into it. They have pretty good documentation regarding the different arguments you can use. You would want to obviously replace the variables I'm using in the strcat to whatever suits your needs.

Code: [Select]

(setq outlook "C:\\Program Files (x86)\\Microsoft Office\\root\\Office16\\OUTLOOK.EXE") ;Change to YOUR Outlook installation directory
(startapp (strcat (chr 34) outlook (chr 34) "/c ipm.note /a " (chr 34) trgfile (chr 34) "/m "(chr 34) "mailto:" recipient "?subject=" customer " - " (strcat dwgname rev#) "&body="(chr 34)))
This won't automatically hit send, but it will open the email and fill out all the fields or attach files so that all you have to do manually is click 1 button.

[domenicomaria]

everything is solved...!
Outlook simply wasn't installed on the PC!
 

I apologize ...
but the PC where I work is not mine
and they assured me that the entire Office package was installed!

And I didn't even check!