Topic: bounding box along direction

[domenicomaria]

I need to know the red size in the second attached image.
Without rotating anything !
Is it possible ?

[Marc'Antonio Alessi]

Rotate UCS?

[ribarm]

Rotate UCS and apply this routine to get BBox, then extract only width (red line)...

[VovKa]

build a list of coordinates (curves must be approximated)
then either rotate every point around the common center or project them on a red line
then find min and max

some helper functions https://www.theswamp.org/index.php?topic=37319.msg423645#msg423645

[domenicomaria]

Rotate UCS and apply this routine to get BBox, then extract only width (red line)...

Thank you Ribarm!
Works !
But I was hoping for a mathematical solution. . .
Because this routine does a number of very spectacular things,
while I'm looking for something that can't be seen,
that makes calculations "in secret" ...

But I realize that it is a very complicated thing!

I have to try to do something only for lines, circles and arcs...
It shouldn't be hard...

[domenicomaria]

build a list of coordinates (curves must be approximated)
then either rotate every point around the common center or project them on a red line
then find min and max

some helper functions https://www.theswamp.org/index.php?topic=37319.msg423645#msg423645

VovKa you have allways great ideas ...
I will give it a try !
Grazie.
Ciao

[It's Alive!]

If that’s a polyline, made to represent an object, you can store a direction in XData when it’s created.
Then, you can get the direction at a later time, even if it’s been rotated 

[dexus]

I tried to make an example by projecting the lines onto the line and getting the min and max. (like VovKa suggested)
It uses the code from http://www.lee-mac.com/entitytopointlist.html to make the pointlist.

Code - Auto/Visual Lisp: [Select]

1. (defun c:bbang (/ pl lin pts)
2.   (and
3.     (setq pl (car (entsel "\nSelect polyline: ")))
4.     (setq pts (LM:ent->pts pl 50.0)) ; Get point list
5.     (setq line (car (entsel "\nSelect angle line: ")))
6.     (setq line (entget line))
7.     (setq line (list (cdr (assoc 10 line)) (cdr (assoc 11 line)))) ; Start and end point
8.     (setq line (cons (mapcar '- (cadr line) (car line)) line)) ; Add relative point
9.     (setq pts (mapcar (function (lambda (pt) (caddr (trans (mapcar '- pt (cadr line)) 0 (car line))))) pts)) ; get distances on line
10.     (princ "\nDistance on line: ") (princ (- (apply 'max pts) (apply 'min pts))) ; Subtract shortest from longest to get the distance
11.   )
12.   (princ)
13. )

[domenicomaria]

@Dexus

It works very well !

it's enough for what I need !

that's exactly what vovKa suggested !

it's not perfect,
(because it doesn't analyze curves but only segments),
but for what I have to do,
it's fine.

Thank you all.

[domenicomaria]

@Dexus
. . . your modified version has a little problem . . .

[dexus]

@Dexus
. . . your modified version has a little problem . . .

It was missing a bracket, should work now. 

[Marc'Antonio Alessi]

Please post your sample DWG. > Edit...

Code: [Select]

(defun c:test (/ ent line llp urp )
    (and
        (setq ent (car (entsel "\nSelect polyline: ")))
        (setq line (car (entsel "\nSelect angle line: ")))
        (progn
            (command "_.UCS" "_ENTITY" line)           
            (gc:UcsBoundingBox ent 'llp 'urp)
            (command "_.rectangle" "_non" llp "_non" urp)
            (command "_.UCS" "_P")           
        )
    )
    (princ)
)
;; gc:UcsBoundingBox by Gile
;; Returns the UCS coordinates of the object bounding box about current UCS
;;
;; Arguments
;; obj: an entity (ENAME or VLA-OBJCET)
;; _OutputMinPtSym: a quoted symbol (output)
;; _OutputMaxPtSym: a quoted symbol (output)


(defun gc:UcsBoundingBox ( obj _OutputMinPtSym _OutputMaxPtSym )
    (and (= (type obj) 'ename)
         (setq obj (vlax-ename->vla-object obj))
    )
    (vla-transformby obj (vlax-tmatrix (gc:TMatrixFromTo 1 0)))
    (vla-getboundingbox obj _OutputMinPtSym _OutputMaxPtSym)
    (vla-transformby obj (vlax-tmatrix (gc:TMatrixFromTo 0 1)))
    (set _OutputMinPtSym (vlax-safearray->list (eval _OutputMinPtSym)))
    (set _OutputMaxPtSym (vlax-safearray->list (eval _OutputMaxPtSym)))
)


;; gc:TMatrixFromTo by Gile
;; Returns the 4X4 transformation matrix from a coordinate system to an other one
;;
;; Arguments
;; from to: same arguments as for the 'trans' function


(defun gc:TMatrixFromTo ( from to )
    (append
        (mapcar
            (function
                (lambda   ( v o )
                    (append (trans v from to t) (list o))
                )
            )
           '(
                (1.0 0.0 0.0)
                (0.0 1.0 0.0)
                (0.0 0.0 1.0)
            )
            (trans '(0.0 0.0 0.0) to from)
        )
       '((0.0 0.0 0.0 1.0))
    )
)

[domenicomaria]

Please post your sample DWG.

[Marc'Antonio Alessi]

Please post your sample DWG.

[VovKa]

it's not perfect,
(because it doesn't analyze curves but only segments),

LM:ent->pts builds approximations for curves, so it's better than you think

[domenicomaria]

it's not perfect,
(because it doesn't analyze curves but only segments),

LM:ent->pts builds approximations for curves, so it's better than you think

... curves converted into segments ...
I have seen the point list that it makes...
and I have seen how It works (very well)
... however It Is an approximation ...
 however it Is more than enough, for what i need

[domenicomaria]

Please post your sample DWG.

how did you do ? as dexus ?

[Marc'Antonio Alessi]

See replay #1 and #11... 

[Stefan]

Here is an exact solution for polylines.
It is a mathematical solution, no entity is changed at all.

Code - Auto/Visual Lisp: [Select]

1. (defun _rot (p a)
2.   (list
3.     (- (* (car p) (cos a)) (* (cadr p) (sin a)))
4.     (+ (* (car p) (sin a)) (* (cadr p) (cos a)))
5.   )
6. )
7.  
8. (defun _m2p (a b) (mapcar '(lambda (a b) (/ (+ a b) 2.0)) a b))
9.  
10. (defun _pline_rotated_bb (e u / a b c d m o p r s a1 a2)
11.   (setq a (vlax-curve-getstartparam e)
12.         b (vlax-curve-getendparam e)
13.   )
14.   (while (<= a b)
15.     (setq p (vlax-curve-getpointatparam e a)
16.           r (_rot p (- u))
17.           a1 (if a1 (mapcar 'min a1 r) r)
18.           a2 (if a2 (mapcar 'max a2 r) r)
19.           s (vlax-curve-getsecondderiv e a)
20.           d (distance '(0.0 0.0) s)
21.     )
22.     (if
23.       (> d 0.0)
24.       (progn
25.         (setq o (polar
26.                   (setq m (vlax-curve-getpointatparam e (+ a 0.5)))
27.                   (angle m (_m2p p (vlax-curve-getpointatparam e (rem (1+ a) b))))
28.                   d
29.                 )
30.         )
31.         (foreach x '(0.0 0.5 1.0 1.5)
32.           (setq p (polar o (+ u (* x pi)) d))
33.           (if
34.             (and
35.               (setq c (vlax-curve-getparamatpoint e p))
36.               (< a c (1+ a))
37.             )
38.             (setq r (_rot p (- u))
39.                   a1 (mapcar 'min a1 r)
40.                   a2 (mapcar 'max a2 r)
41.             )
42.           )
43.         )
44.       )
45.     )
46.     (setq a (1+ a))
47.   )
48.   (list
49.     (_rot a1 u)
50.     (_rot (list (car a2) (cadr a1)) u)
51.     (_rot a2 u)
52.     (_rot (list (car a1) (cadr a2)) u)
53.   )
54. )
55.  
56. (defun c:test ( / *error* e u bb)
57. ;;;  (setq *error* (err))
58.   (if
59.     (and
60.       (setq e (ssget "_+.:S" '((0 . "*POLYLINE"))))
61.       (setq u (getangle "\nSpecify rotation angle: "))
62.       (setq bb (_pline_rotated_bb (ssname e 0) u))
63.     )
64.     (entmakex
65.       (append
66.        '(
67.           (0 . "LWPOLYLINE")
68.           (100 . "AcDbEntity")
69.           (100 . "AcDbPolyline")
70.           (90 . 4)
71.           (70 . 1)
72.         )
73.         (mapcar
74.          '(lambda (p)
75.             (cons 10 p)
76.           )
77.           bb
78.         )
79.       )
80.     )
81.   )
82. ;;;  (*error* nil)
83.   (princ)
84. )

[domenicomaria]

See replay #1 and #11... 

Marco, I apologize.
I didn't really notice the answer #11 ! 

Bravo.
Very interesting !

[domenicomaria]

@DEXUS

Here is an exact solution for polylines.
It is a mathematical solution, no entity is changed at all.

It works perfectly !

you are very good !

[domenicomaria]

See replay #1 and #11... 

. . . and your code works also with line, circle, arc, ellipse . . .
. . . while fails with spline, insert . . .

[dexus]

@DEXUS

Here is an exact solution for polylines.
It is a mathematical solution, no entity is changed at all.

It works perfectly !

you are very good !

I would love to take credit, but it should be @Stefan

[ribarm]

I think Stefan will fail if reference entity is INSERT...
I've included all that's possible in my BBox.lsp... It'll try even with nested inserts that overlap each other...

[domenicomaria]

@ Dexus and Stefan !

I would love to take credit, but it should be @Stefan

I'm always very distracted ! 

Stefan, YOU you are very good !

[domenicomaria]

I think Stefan will fail if reference entity is INSERT...
I've included all that's possible in my BBox.lsp... It'll try even with nested inserts that overlap each other...

The code of Stefan is only for polylines ...

[Stefan]

Thanks. My wife would disagree
But she knows nothing about lisp

[ribarm]

I've just tried my BBox.lsp and it fails with INSERTs too... I've fixed it only not to exit with error and I think that it explodes blocks if it runs on them, so be careful with *.lsp... But for curves it should work well and in 3d UCS... HTH., M.R.

[xdcad]

I think Stefan will fail if reference entity is INSERT...
I've included all that's possible in my BBox.lsp... It'll try even with nested inserts that overlap each other...

The code of Stefan is only for polylines ...

Code - Auto/Visual Lisp: [Select]

1. (defun c:tt ()
2.   (if (setq ss (xdrx-ssget "\nSelect Draw Boundingbox Objects<Quit>:"))
3.     (progn
4.       (while (setq e (xdrx-entsel
5.                        "\nPick a Direction Line<Quit>:"
6.                        '((0 . "*polyline,line"))
7.                      )
8.              )
9.         (setq xdir (xdrx-getpropertyvalue (car e) "firstderiv" (cadr e))
10.               box  (xdrx-entity-box ss xdir)
11.         )
12.         (xdrx-polyline-make (xdrx-points-ucs2wcs box) t)
13.         (xdrx-setpropertyvalue (entlast) "color" (xdrx-math-rand 1 220))
14.       )
15.     )
16.   )
17.   (princ)
18. )

[domenicomaria]

anyway, when there is a solid hatch, there are allways problems...
... but it doesn't depend from your great xdrx-entity-box function ...
which maybe should be called xdrx-ss-box

[domenicomaria]

but it also fails when there are blocks that are not uniformly scaled
(even if they do not contain solid hatches)...

[xdcad]

but it also fails when there are blocks that are not uniformly scaled
(even if they do not contain solid hatches)...

Pls Upload a DWG that encounters problems。

[xdcad]

anyway, when there is a solid hatch, there are allways problems...
... but it doesn't depend from your great xdrx-entity-box function ...
which maybe should be called xdrx-ss-box

In order not to classify so many names, they are all classified as entity.
Entity can handle a single entity, but also supports tables or selection sets of multiple entities.

If it is called ss, will the same problem still occur when only one is processed?

[domenicomaria]

Pls Upload a DWG that encounters problems。

[domenicomaria]

If it is called ss, will the same problem still occur when only one is processed ?

No.
It will be a selection set that contains only 1 entity.

a rule could be that
when a function processes only 1 entity name,
its name has to contain the word "entity",
while if it processes a selection set,
its name must contain the word "ss" or "sset" . . .

. . .
however this is not a big problem
. . .

[xdcad]

but it also fails when there are blocks that are not uniformly scaled
(even if they do not contain solid hatches)...

Solved, it is a problem that has always existed in AUTOCAD itself, that is, there is a deviation in the SPLINE bounding box.
Ordinary SPLINE, API has been solved,
However, in the block, the method of finding the bounding box is to use ARX's AcDbSpatialFilter::queryBounds(...) method, but there is still a problem.

Now I use my own method to process SPLINE in Block separately.

The API has been updated, please try downloading it again.

[domenicomaria]

yes, with splines contained in a not uniformly scaled insert, works ...

but still not, with a solid hatch !

[xdcad]

yes, with splines contained in a not uniformly scaled insert, works ...

but still not, with a solid hatch !

That's because your HATCH has a border, and the grip points of the border SPLINE are all within the range, and the data is stored in the HATCH object.
So that's all it takes, the result is correct.