Topic: Identifing the visibility state a nested entity is associated with

[cadpoobah]

All,

I'd like to generate a report of the entities nested within a block and know if each entity is associated with a visibility state. Can anyone tell me how to determine that info?

Thanks!

Chris

[kpblc]

I thinck you have to check block reference (not by EffectiveName, but just Name) and going through all subentities check - are they visible or not.

[cadpoobah]

Thanks, @kpblc.

You are correct; this would be for references. Similar to AutoCAD's LIST command, the user would be prompted to select a block reference. The report would be specific to the selected block.

[Lee Mac]

The following function should return a list of entities visible for each visibility state for a given dynamic block:

Code - Auto/Visual Lisp: [Select]

1. ;; Visibility State Entities  -  Lee Mac
2. ;; Returns an association list of visibility states and the entities visible for each state
3. ;; blk - [str] Dynamic block name
4.  
5. (defun LM:vsentities ( blk / ent enx rtn ste tmp vis )
6.     (if
7.         (and
8.             (setq ent (tblobjname "block" blk))
9.             (setq ent (cdr (assoc 330 (entget ent))))
10.             (setq enx (member '(102 . "{ACAD_XDICTIONARY") (entget ent)))
11.             (setq ent (cdr (assoc 360 enx)))
12.             (setq vis
13.                 (vl-some
14.                    '(lambda ( x )
15.                         (if (and (= 360 (car x)) (= "BLOCKVISIBILITYPARAMETER" (cdr (assoc 0 (entget (cdr x))))))
16.                             (cdr x)
17.                         )
18.                     )
19.                     (dictsearch ent "ACAD_ENHANCEDBLOCK")
20.                 )
21.             )
22.         )
23.         (foreach itm (entget vis)
24.             (cond
25.                 (   (= 303 (car itm))
26.                     (if (and ste tmp) (setq rtn (cons (cons ste (reverse tmp)) rtn)))
27.                     (setq ste (cdr itm)
28.                           tmp nil
29.                     )
30.                 )
31.                 (   (= 332 (car itm))
32.                     (setq tmp (cons (cdr itm) tmp))
33.                 )
34.             )
35.         )
36.     )
37.     (reverse (if (and ste tmp) (cons (cons ste (reverse tmp)) rtn) rtn))      
38. )

For example:

Code - Auto/Visual Lisp: [Select]

1. _$ (LM:vsentities "MyDynamicBlock")
2.  
3. (
4.     ("State 0" <Entity name: 7ffff7104d0> <Entity name: 7ffff7104e0>)
5.     ("State 1" <Entity name: 7ffff7104d0> <Entity name: 7ffff7104e0> <Entity name: 7ffff7104f0>)
6.     ("State 2" <Entity name: 7ffff7104d0> <Entity name: 7ffff7104e0> <Entity name: 7ffff7104f0> <Entity name: 7ffff710500>)
7.     ("State 3" <Entity name: 7ffff7106b0>)
8. )

[cadpoobah]

Thanks, Lee. That's perfect. I can tweak from there.

You continue to amaze, man. Your code is always 'spot on' and super clean.

[roy_043]

Isn't Lee's code for block definitions instead of references? Or am I missing something?

[cadpoobah]

You're right, @roy_043. For now, I'm using it as a general block definition ("what's inside this block") reporting tool. I'll eventually need a reference version as well.

[Lee Mac]

Thanks cadpoobah, glad it helps.
Thank you also for your compliments for my code, I appreciate it.

The 'block reference' version is actually a lot easier, since you can simply query the contents of the anonymous block definition generated based on the current dynamic parameter values of the block and return the visible entities in the definition:

Code - Auto/Visual Lisp: [Select]

1. (defun blockrefentities ( ent / enx rtn )
2.     (if (setq ent (tblobjname "block" (cdr (assoc 2 (entget ent)))))
3.         (while (setq ent (entnext ent))
4.             (if (/= 1 (cdr (assoc 60 (entget ent)))) (setq rtn (cons ent rtn)))
5.         )
6.     )
7.     (reverse rtn)
8. )

The active visibility state can be ascertained using this function.