Topic: Xref Image thru Lisp

[GDF]

I'm looking to xref an image thru a lisp routine. Any ideas?

(setvar "filedia" 0)
(setenv "XLOADPATH" (getvar "dwgprefix"))

name of image  "Front Elevation.png"
(command "-xref"...

I have tried XATTACH, IMAGEATTACH...with no luck.

[ronjonp]

Set FILEDIA to 0 then use IMAGEATTACH.

[GDF]

Thanks

I tried that and get this message...

[GDF]

Ok, this works...but I'm looking to do it without opening any dialog boxes.

(defun C:TEST ()
  (setvar "ctab" "A0-0 COVER")
  (setvar "filedia" 0)
  (setenv "XLOADPATH" (getvar "dwgprefix"))
  (command "IMAGEATTACH" "Front Elevation.png")
  (princ))

[GDF]

This is the best I can do...

Code: [Select]


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; Xref Images Function ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun C:Images ()
  (setvar "ctab" "A0-0 COVER")
  (setvar "filedia" 0)
  (setenv "XLOADPATH" (getvar "dwgprefix"))
  (initget 1 "V A F")
  (setq tmp (getkword "\n* Xref Images: [V]icinity map   [A]erial image   [F]ront elevation *"))
  (if (not tmp)
    (setq tmp "P"))
  (cond ((= "V" tmp) (command "IMAGEATTACH" "Vicinity Map.png"))
        ((= "A" tmp) (command "IMAGEATTACH" "Aerial Image.png"))
        ((= "F" tmp) (command "IMAGEATTACH" "Front Elevation.png")))
  (setvar "filedia" 1)
  (princ))



[T.Willey]

Gary,

Look at the method 'AddRaster'.

Code - Text: [Select]

1. (setq doc (vla-get-ActiveDocument (vlax-get-Acad-Object)))
2. (setq spc (vla-get-ModelSpace doc))
3. (vlax-invoke spc 'AddRaster <path> (getpoint) 1. 0.)
4.  

[MP]

No time to play but here's a little snip ...

Code: [Select]

(setq
    owner           (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
    imageName       "c:\\legit_path\\legit_file_name.cal"
    insertionPoint '(0.0 0.0 0.0)
    scalefactor     1.0
    rotationAngle   0.0
)

(vlax-invoke owner 'AddRaster imageName insertionPoint scalefactor rotationAngle)

[ronjonp]

And some more food for thought

Code - Auto/Visual Lisp: [Select]

1.  
2. (defun c:images (/ d f i p)
3.   (cond
4.     ((vl-position "A0-0 COVER" (mapcar 'strcase (layoutlist)))
5.      (setq d (vla-get-activedocument (vlax-get-acad-object)))
6.      (setvar 'ctab "A0-0 COVER")
7.      (setvar 'filedia 0)
8.      (initget 0 "V A F")
9.      (setq i (cond ((getkword "\nXref Images[Vicinity Map/Aerial image/Front elevation] <V>: "))
10.                    ("V")
11.              )
12.      )
13.      (if
14.        (and
15.          (findfile (setq f (strcat (getvar 'dwgprefix)
16.                                    (car (vl-remove-if-not
17.                                           '(lambda (x) (wcmatch x (strcat i "*")))
18.                                           '("Vicinity Map.png" "Aerial Image.png" "Front Elevation.png")
19.                                         )
20.                                    )
21.                            )
22.                    )
23.          )
24.          (setq p (getpoint "\nPick a point to place image: "))
25.        )
26.         (vlax-invoke (vla-get-paperspace d) 'addraster f p 1. 0.)
27.         (print (strcat f " NOT FOUND!!!"))
28.      )
29.      (setvar 'filedia 1)
30.     )
31.     (alert "Tab 'A0-0 COVER' DOES NOT EXIST!")
32.   )
33.   (princ)
34. )
35. (vl-load-com)

[GDF]

Thanks
As soon as I get home I’ll try them out

[GDF]

Ron, your routine works like mine. I would like to set the image without the dialog box...Setting the insertion point, scale etc thru lisp.

Tim and MP, your routine works, but the image is not displaying.

[ronjonp]

I think Tim and MP's code is not working for you because you're inserting on a paperspace tab and their examples are using modelspace.

[ronjonp]

Ron, your routine works like mine. I would like to set the image without the dialog box...Setting the insertion point, scale etc thru lisp.
...

Updated above to use addraster.

[GDF]

Slapping my face now...

[GDF]

Ron, what is spc

(vlax-invoke (vla-get-paperspace spc) 'addraster f p 1. 0.)

[ronjonp]

Ron, what is spc

(vlax-invoke (vla-get-paperspace spc) 'addraster f p 1. 0.)

Oops. .. updated above.