Author Topic: Open Google Earth (Read 6585 times)

Marc'Antonio Alessi · « **Reply #15 on:** April 10, 2018, 04:57:48 AM »

Quote from: dgpuertas on April 10, 2018, 04:50:05 AM

Thanks a lot, but seems that google earch api is gone in new versions......

Maybe this can help: http://www.cruisersforum.com/forums/f121/google-earth-api-gone-144392.html

Thanks Marco.

NICK_VNV: in that case (as Marco):

Code: [Select]
$ (findfile "C:\\Program Files\\Google\\Google Earth Pro\\client\\earthps.dll") nil _$ (findfile "C:\\Program Files\\Google\\Google Earth Pro\\client\\googleearth.exe") "C:\\Program Files\\Google\\Google Earth Pro\\client\\googleearth.exe" $ (vlax-import-type-library :tlb-filename "C:\\Program Files\\Google\\Google Earth Pro\\client\\googleearth.exe" :methods-prefix "vlg-" :properties-prefix "vlg-" :constants-prefix "gec-" ) ; error: tipo de argumento erróneo: VLA-OBJECT nil

Maybe uninstall the last version and install older is the solution.

Thanks everybody and sorry about my english.

me too:
$ (vlax-import-type-library :tlb-filename "C:\\Program Files\\Google\\Google Earth Pro\\client\\googleearth.exe" :methods-prefix "vlg-" :properties-prefix "vlg-" :constants-prefix "gec-")
; error: tipo de argumento erróneo: VLA-OBJECT nil

NICK_VNV · « **Reply #16 on:** April 10, 2018, 05:32:45 AM »

I am using Google Earth Pro 7.3.1.4507 (32-bit) and everything works fine. What version do you have?

Marc'Antonio Alessi · « **Reply #17 on:** April 10, 2018, 07:40:27 AM »

Quote from: NICK_VNV on April 10, 2018, 05:32:45 AM

I am using Google Earth Pro 7.3.1.4507 (32-bit) and everything works fine. What version do you have?

I am using Google Earth Pro 7.3.1.4507 (64-bit)

NICK_VNV · « **Reply #18 on:** April 10, 2018, 08:10:07 AM »

Quote from: Marc'Antonio Alessi on April 10, 2018, 07:40:27 AM

Quote from: NICK_VNV on April 10, 2018, 05:32:45 AM
I am using Google Earth Pro 7.3.1.4507 (32-bit) and everything works fine. What version do you have?
I am using Google Earth Pro 7.3.1.4507 (64-bit)

I have uninstalled 32bit version and installed 64 bit version. Now I have the same problem.
It seems we need to use 32bit version.

p.s.
Yep I've reverted back to 32bit and it works fine again.

dgpuertas · « **Reply #19 on:** April 10, 2018, 08:17:08 AM »

My version
Google Earth Pro
7.3.1.4507 (64-bit)

but, can i install 32bit software in a 64bit computer?

NICK_VNV · « **Reply #20 on:** April 10, 2018, 08:18:02 AM »

Quote from: dgpuertas on April 10, 2018, 08:17:08 AM

My version
Google Earth Pro
7.3.1.4507 (64-bit)

but, can i install 32bit software in a 64bit computer?

Ofcourse

Marc'Antonio Alessi · « **Reply #21 on:** April 10, 2018, 09:06:07 AM »

Quote from: NICK_VNV on April 10, 2018, 08:18:02 AM

Quote from: dgpuertas on April 10, 2018, 08:17:08 AM
My version
Google Earth Pro
7.3.1.4507 (64-bit)

but, can i install 32bit software in a 64bit computer?
Ofcourse

Thanks

rkmcswain · « **Reply #22 on:** April 10, 2018, 10:20:36 AM »

Quote from: NICK_VNV

I have uninstalled 32bit version and installed 64 bit version. Now I have the same problem.
It seems we need to use 32bit version.

p.s.
Yep I've reverted back to 32bit and it works fine again.

Good to know. It seems that Plex.Earth suffers from the same issue, must have 32-bit version of GE installed.

https://plexscape.zendesk.com/hc/en-us/articles/216073463-Communication-with-Google-Earth-Issue?mobile_site=true

d2010 · « **Reply #23 on:** August 08, 2022, 01:20:53 PM »

Quote from: dgpuertas on April 10, 2018, 08:17:08 AM

Google Earth Pro
7.3.1.4507 (64-bit)
But, can i install 32bit software in a 64bit computer?

Sure, but your AcadVer but an exactly version-type with GoogleEarth.

Code: [Select]

//Eg1. Autocad2014.exe version x86 and GoogleEarth.x86
//Eg2. Autocad2014,exe version x64 == GoogleEarth.x64

Other solution/s check>your WindowsRegistry with
"Spy Search and Destroy.exe"
"Windoc.exe from NortonUtitiles", because "winRegistry for 'COM" contain damage-informations.
"Check the virus Attack with BitDefender.exe":

It's Alive! · « **Reply #24 on:** August 08, 2022, 10:12:48 PM »

there's a web version too

MSTG007 · « **Reply #25 on:** August 15, 2022, 07:52:13 AM »

Where or how did you find about Google Earth within CAD? lol. Thats pretty neat.

CodeDing · « **Reply #26 on:** August 15, 2022, 01:26:50 PM »

MSTG007,

Quote from: MSTG007 on August 15, 2022, 07:52:13 AM

Where or how did you find about Google Earth within CAD? lol. Thats pretty neat.

..."Google Earth within CAD" might be a little deceptive. It's just a web page. Probably using the Javascript API!

Source:
https://help.autodesk.com/view/OARX/2022/ENU/?guid=adsk_jsdev_autocad_javascript_api_about

To Test:
Save this as html document..

Code: [Select]

<html>
   <head>
       <title>Some Title</title>
       <script type="text/javascript" src="https://df-prod.autocad360.com/jsapi/v3/Autodesk.AutoCAD.js ">
       </script>
       <script type="text/javascript">

           function myFunction() {
             Acad.Application.addDocWindow("Another Title", "https://www.theswamp.org/index.php?topic=54086.msg611080#msg611080");
           }

           myFunction();

       </script>
   </head>

   <body>

   </body>
</html>

...then run code to execute your html...

Code: [Select]

(command "_.WEBLOAD" "l" "c:\\users\\me\\desktop\\myWebDocument.html")
Best,
~DD

CodeDing · « **Reply #27 on:** August 15, 2022, 01:34:42 PM »

To maintain the integrity of OP's original question though, last year I posted a routine to do just what was requested:

Code - Auto/Visual Lisp: [Select]

(defun c:EARTH ( / *error* GeoMarker PT->LL errMsg earthPath ptMid ptLL strKML fName f)
;; Opens Google Earth. If dwg is Geo-Located, attempts to open at user-specified location.
  ;; Helper Function(s)
  ;; Error handler
  (defun *error* (msg / )
    (if (not (member msg '("Function cancelled" "quit / exit abort")))
      (princ (strcat "\nError: " msg))
    );if
    (princ)
  );error defun
  (defun GeoMarker ( / ) ;; Creates arbitrary GeoMarker, returns ename
    (entmakex '((0 . "POSITIONMARKER") (100 . "AcDbEntity") (100 . "AcDbGeoPositionMarker") (90 . 0) (10 0.0 0.0 0.0) (40 . 1.0)
               (1 . "") (40 . 0.5) (290 . 0) (280 . 0) (290 . 1) (101 . "Embedded Object") (100 . "AcDbEntity") (100 . "AcDbMText")
               (10 0.1 0.1 0.0) (40 . 1.0) (1 . "") (210 0.0 0.0 1.0) (11 1.0 0.0 0.0) (42 . 9761.9) (43 . 6666.67)))
  );GeoMarker defun
  (defun PT->LL (pt / e luprec return) ;; Returns Longitude & Latitude of point provided
    (if (setq e (GeoMarker))
      (progn
        (setq e (vlax-ename->vla-object e))
        (vlax-put-property
          e
          'Position
          (vlax-make-variant (vlax-safearray-fill (vlax-make-safearray vlax-vbdouble '(0 . 2)) pt))
        );vlax
        (setq luprec (getvar 'LUPREC))
        (setvar 'LUPREC 8)
        (setq return
          (mapcar
            'atof
            (list (vla-get-Longitude e) (vla-get-Latitude e) "0.")
          );mapcar
        );setq
        (setvar 'LUPREC luprec)
        (vla-delete e)
        return
      );progn
    );if
  );PT->LL defun
  ;; Initial checks
  (cond
    ((not (setq earthPath (vl-registry-read "HKEY_LOCAL_MACHINE\\SOFTWARE\\Google\\Google Earth Pro" "InstallLocation")))
      (setq errMsg "\nCould not locate Google Earth application.")
    );cond 1
    ((not (eq "Model" (getvar 'CTAB))) (setq errMsg "\nMust be in Model space to select location."))
    ((eq "" (getvar 'CGEOCS)) (setq errMsg "\nDrawing is not Geo-Located."))
  );cond
  (if earthPath (setq earthPath (strcat earthPath "googleearth.exe")))
  ;; Open Earth now if path found and error found, or test for other error.
  (cond
    ((and earthPath errMsg) (startapp earthPath) (prompt errMsg) (exit))
    (errMsg (prompt errMsg) (alert errMsg) (exit))
  );cond
  (prompt "\nPreparing to open location in Google Earth...")
  ;; User-selected or arbitrary mid point of project data
  (setq ptMid
    (cond ((getpoint "\nSelect Point or (Enter) for default: "))
          ((getvar 'VIEWCTR))
    );cond
  );setq
  ;; Transform to Lat Long
  (setq ptLL (PT->LL ptMid))
  (print ptLL)
  ;string for KML file
  (if *earth_marker_count*
    (setq *earth_marker_count* (1+ *earth_marker_count*))
    (setq *earth_marker_count* 1)
  );if
  (setq strKML
    (strcat
      "<?xml version=\"1.0\" encoding=\"UTF-8\"?>"
      "<kml xmlns=\"http://www.opengis.net/kml/2.2\" xmlns:gx=\"http://www.google.com/kml/ext/2.2\" xmlns:kml=\"http://www.opengis.net/kml/2.2\" xmlns:atom=\"http://www.w3.org/2005/Atom\">"
      "  <Placemark>"
      "    <name>" (getvar 'DWGNAME) " (" (itoa *earth_marker_count*) ")</name>"
      "    <Point>"
      "      <coordinates>" (rtos (car ptLL) 2 7) "," (rtos (cadr ptLL) 2 7) ",0</coordinates>"
      "    </Point>"
      "  </Placemark>"
      "</kml>"
    );strcat
  );setq
  ;; Write string to KML file
  (setq fName (vl-filename-mktemp "C3D" nil ".kml"))
  (write-line strKML (setq f (open fName "w")))
  (close f)
  ;; Open KML in Google Earth
  (startapp earthPath fName)
  (prompt "\nEARTH Complete.")
  (princ)
);defun
 

Sauce:
https://forums.autodesk.com/t5/civil-3d-customization/google-earth-command-in-autocad/td-p/10598071

Best,
~DD

It's Alive! · « **Reply #28 on:** August 16, 2022, 02:59:54 AM »

Quote from: CodeDing on August 15, 2022, 01:26:50 PM

MSTG007,

Quote from: MSTG007 on August 15, 2022, 07:52:13 AM
Where or how did you find about Google Earth within CAD? lol. Thats pretty neat.
..."Google Earth within CAD" might be a little deceptive. It's just a web page. Probably using the Javascript API!

yeah AutoCAD has a built in web browser, as you found, I used C++ function acedAddHTMLDocWindow(TITLE, URL)
surprised its not in lisp

News:

Author Topic: Open Google Earth (Read 6585 times)

Marc'Antonio Alessi

Re: Open Google Earth

NICK_VNV

Re: Open Google Earth

Marc'Antonio Alessi

Re: Open Google Earth

NICK_VNV

Re: Open Google Earth

dgpuertas

Re: Open Google Earth

NICK_VNV

Re: Open Google Earth

Marc'Antonio Alessi

Re: Open Google Earth

rkmcswain

Re: Open Google Earth

d2010

Re: Open Google Earth

It's Alive!

Re: Open Google Earth

MSTG007

Re: Open Google Earth

CodeDing

Re: Open Google Earth

CodeDing

Re: Open Google Earth

It's Alive!

Re: Open Google Earth