Topic: During Loading and Closing a DWG

[MSTG007]

Does anyone know how to setup Autocad Once an individual drawing opens in Autocad it will perform a command. (I have a lisp that will Display Plot Styles which I would like to turn on). But when I close a drawing (It will run the command to turn off Display Plot Styles). hopefully that makes some sense.
Thanks for your thoughts!

[ronjonp]

Without using reactors, I'd think it would be as simple as this:

Code: [Select]



(if (wcmatch (strcase (getenv "username")) "*")
  (progn (command "_.undefine" "_.close")
(defun c:close nil (yourfunctiontoresetplotstyles) (command "_.close"))
  )
)

[MSTG007]

Ok. I am going to play dumb again. Curious; how does this work and where would i place this?

[ronjonp]

I'd put it wherever you are loading your lisp routines from (acad.lsp *.mnl .. etc.).
As far as how it works, all it does is redefine the close command to run your routine before the "close" command. 

[MSTG007]

lol you will like this; i usually appload it.

[ronjonp]

Why don't you post the code you're using and we can get this sorted.

[MSTG007]

Please see the below code.

Code: [Select]

(defun DPS_Post ()
  (setvar "cmdecho" 0)
  (command "_.regenall")
  (setvar "cmdecho" 1)
  (princ)
)
;-------------------------------------------------------
(defun c:DPSON ()
  (rm:displayplotstyles t nil)
  (BGWhite)
  (DPS_Post)
)
;-------------------------------------------------------
(defun c:DPSONALL ()
  (rm:displayplotstyles t t)
  (BGWhite)
  (DPS_Post)
)
;-------------------------------------------------------
(defun c:DPSOFF ()
  (rm:displayplotstyles nil nil)
  (BGBlack)
  (DPS_Post)
)
;-------------------------------------------------------
(defun c:DPSOFFALL ()
  (rm:displayplotstyles nil t)
  (BGBlack)
  (DPS_Post)
)
;-------------------------------------------------------
;
;
(defun rm:displayplotstyles (bshow ball / acapp acdoc layouts layout bvshow)
(princ "\n...Display plotstyles ")
(vl-load-com)
(setq acdoc (vla-get-ActiveDocument (vlax-get-acad-object)))

(setq layouts (vla-get-layouts acdoc))
(setq bvshow (if bshow :vlax-true :vlax-false))
(princ (if bshow "ON" "OFF"))
(cond
(ball
(vlax-for layout layouts
(if (/= (vla-get-name layout) "Model")
(vla-put-ShowPlotStyles layout bvshow))
)
(princ " in all layouts.\n")
)
(T (setq layout (vla-get-ActiveLayout acdoc))
(vla-put-ShowPlotStyles layout bvshow)
(princ " in current layout.\n")
)
)
(prin1)
)


; Set the background in model and paper space to white
(defun BGWhite ()
  (vl-load-com)
  (setq disp (vla-get-display (vla-get-preferences (vlax-get-acad-object))))
  (vla-put-GraphicsWinLayoutBackgrndColor disp 16777215)
)

; Set the background in model and paper space to black
(defun BGBlack  ()
  (vl-load-com)
  (setq disp (vla-get-display (vla-get-preferences (vlax-get-acad-object))))
  (vla-put-GraphicsWinLayoutBackgrndColor disp 0)
)
;---------------------------------------------- ---------
(princ (strcat "\n...DisplayPlotStyles is loaded || DPSON, DPSONALL, DPSOFF, DPSOFFALL...\n"))
(prin1)
;--------------------------------------------- ----------

Would like to have the Display plot Styles on at Start of Drawing. Then Do Not Show Display plot Styles when I exit a Drawing.

[ronjonp]

Give this a try. I consolidated some of your previous code .. hope you don't mind .

Code: [Select]

(defun c:dpson () (rm:displayplotstyles t nil))
(defun c:dpsonall () (rm:displayplotstyles t t))
(defun c:dpsoff () (rm:displayplotstyles nil nil))
(defun c:dpsoffall () (rm:displayplotstyles nil t))


(defun rm:displayplotstyles (bshow ball / acdoc bvshow disp layout layouts)
  (princ "\n...Display plotstyles ")
  (vl-load-com)
  (setq acdoc (vla-get-activedocument (vlax-get-acad-object)))
  (setq layouts (vla-get-layouts acdoc))
  (setq disp (vla-get-display (vla-get-preferences (vlax-get-acad-object))))
  (setq   bvshow (if bshow
       :vlax-true
       :vlax-false
          )
  )
  (princ (if bshow
      (progn (or *editor-reactor-close*
            (setq *editor-reactor-close*
              (vlr-editor-reactor nil '((:vlr-beginclose . resetplotstyles)))
            )
        )
        (defun resetplotstyles (a b) (alert "foo") (rm:displayplotstyles nil t) (princ))
        (vla-put-graphicswinlayoutbackgrndcolor disp 16777215)
        "ON"
      )
      (progn (vla-put-graphicswinlayoutbackgrndcolor disp 0) "OFF")
    )
  )
  (if ball
    (progn (vlax-for layout layouts
        (if (/= (vla-get-name layout) "Model")
          (vla-put-showplotstyles layout bvshow)
        )
      )
      (princ " in all layouts.\n")
    )
    (progn (vla-put-showplotstyles (vla-get-activelayout acdoc) bvshow)
      (princ " in current layout.\n")
    )
  )
  (vla-regen acdoc acallviewports)
  (prin1)
)
(princ (strcat "\n...DisplayPlotStyles is loaded || DPSON, DPSONALL, DPSOFF, DPSOFFALL...\n"))
(prin1)

[MSTG007]

I like what you did; its clean and makes sense. But my mind is not working properly for monday. :ugly:, I have Civil3D 2013 X64; where do i place this code? lol

[dgorsman]

Trying to run LISP while drawings are closing is tricky, especially if it takes some time (e.g. regeneration is called).  LISP doesn't stop the drawing from trying to close, but since there is something still happening AutoCAD throws an error.

[ronjonp]

I like what you did; its clean and makes sense. But my mind is not working properly for monday. :ugly: , I have Civil3D 2013 X64; where do i place this code? lol

Just load it how you were loading it before.

[MSTG007]

lol you will like this; i usually appload it.

I have loaded it in my AppLoad.

I opened a drawing with the Plot Styles Display On.

I closed the drawing and saved it;

Reopened the drawing and Plot Styles Display On is still on.

Or If i trun it off manually it and reopen it; the drawing still has it turned off.

Again, i wonder if i am doing something wrong. Which I could be. (I am good at that).

[ronjonp]

I'm getting mixed results with the reactor. IMO .. a simpler approach to reset the plotstyles would be to run (c:dpsoffall) on drawing startup.

Copy the code above again and give it a try. I just forced all the layouts to reset and it seems to be working.

[MSTG007]

Which would mean? Sorry.

[ronjonp]

Which would mean? Sorry.

I'm not sure what you mean ?