Topic: How to draw a line or a polyline with Foreach function

[Coder]

Hello everybody .

I stock with this part of code , I want to use foreach function to draw a line or polyline .

Code: [Select]

(setq pnts '((11 34.614 7.48336 0.0) (11 18.7203 7.48336 0.0) (11 14.9239 12.8179 0.0) (11 7.42747 12.8179 0.0)))

(foreach p pnts
  (command "_.line" ......
           ......

Thanks in advance

[David Bethel]

There are tons of way to accomplish this

Assuming that you want to strip the 11 off of the front end of each atom:

Code: [Select]

  (while (> (length pnts) 1)
         (command "_.LINE" (cdr (nth 0 pnts)) (cdr (nth 1 pnts)) "")
         (setq pnts (cdr pnts)))

And that you don't mind destroying the list 'pnts....
-David

[CAB]

Here is another way to consider:

Code: [Select]

(defun makelines (lst lay / lastpt newlines)
  (foreach pt lst
    (setq pt (cdr pt))                  ; strip 11
    (if lastpt
      (setq newlines
             (cons
               (entmakex
                 (list (cons 0 "LINE")  ;***
                       (cons 6 "BYLAYER")
                       (cons 8 lay)
                       (cons 10 pt)     ;***
                       (cons 11 lastpt) ;***
                       (cons 39 0.0)
                       (cons 62 256)
                       (cons 210 (list 0.0 0.0 1.0))
                 )
               )
               newlines
             )
      )
    )
    (setq lastpt pt)
  )
  newlines
)

Code: [Select]

(setq pnts '((11 34.614 7.48336 0.0) (11 18.7203 7.48336 0.0) (11 14.9239 12.8179 0.0) (11 7.42747 12.8179 0.0)))
(makelines pnts "0")
(<Entity name: 7ee8b608> <Entity name: 7ee8b600> <Entity name: 7ee8b5f8>)

[Coder]

Thank you , both are working great .

Will it be possible with MLINE and POLYLINE ?

Appreciated a lot .

[irneb]

Thank you , both are working great .

Will it be possible with MLINE and POLYLINE ?

Appreciated a lot .

Well, that should be quite simple. For a pline you could go with:

Code: [Select]

(defun makeplines (lst / )
  (command "_.PLINE")
  (foreach pt lst
    (command "_None" pt)
  )
)I tested your list like this:

Code: [Select]

(setq pnts '((11 34.614 7.48336 0.0) (11 18.7203 7.48336 0.0) (11 14.9239 12.8179 0.0) (11 7.42747 12.8179 0.0)))
(makeplines (mapcar 'cdr pnts))Note the "_None" object snap to allow it to work even if you've got running object snaps turned on. IMO it's a better idea than to temporarily set SnapMode, otherwise you need extra error traps and such.

But  ... I'd advise going with CAB's idea of creating the line/pline programatically, instead of through a command call. It allows for more options and generally runs faster. How to accomplish that for an MLine might be a bit complex though.

[HofCAD]

Thank you , both are working great .

Will it be possible with MLINE and POLYLINE ?

Appreciated a lot .

Code: [Select]

(defun MakePlines (Pnts Lay Close / Z)
  (if (setq Z (cadddr (car Pnts)))
    Z
    (setq Z 0)
  )
  (entmakex
    (append (list '(0 . "LWPOLYLINE")
  '(100 . "AcDbEntity")
  '(100 . "AcDbPolyline")
  (cons 8 Lay)
  (cons 90 (length Pnts))
  (cons 38 Z)
  (cons 70 Close);;;0 = open 1 = closed
    )
    (mapcar (function (lambda (p) (cons 10 (cdr p))))
    Pnts
    )
    )
  )
  (princ)
)

Code: [Select]

(setq Pnts '((11 34.614 7.48336 0.0) (11 18.7203 7.48336 0.0) (11 14.9239 12.8179 0.0) (11 7.42747 12.8179 0.0)))
(makePlines Pnts "0" 0)
Regards HofCAD CSI

[VVA]

Other  Entmake Functions  cadtutor and Entmake Function swamp

[Lee Mac]

Another quick example:

Code: [Select]

(defun _makepline ( lst )
    (entmakex
        (append
            (list
                (cons 0 "LWPOLYLINE")
                (cons 100 "AcDbEntity")
                (cons 100 "AcDbPolyline")
                (cons 90 (length lst))
                (cons 70 0)
            )
            (mapcar '(lambda ( p ) (cons 10 (cdr p))) lst)
        )
    )
)

Code: [Select]

(_makepline pnts)
You might find this thread of benefit.

[Andrea]

some other way....

Code: [Select]



(setq ptlist '((0.0 0.0)(10.0 0.0)(10.0 10.0)(20.0 10.0)))


;;EXAMPLE 1
(command "pline")
(mapcar '(lambda (x)
   (command x)
   )
ptlist)
(command "")


   

;;EXAMPLE 2
(command "_.pline")
(foreach pt PtList
 (command pt)
)
(command "")



;;EXAMPLE 3
   (apply 'command
    (append
       '(".pline")
        ptlist
       '("")
    )
)


[alanjt]

For the LINE portion:

Code: [Select]

(defun _lines (lst)
  (mapcar '(lambda (a b) (entmakex (list '(0 . "LINE") (cons 10 a) (cons 11 b))))
          lst
          (cdr lst)
  )
)

[CAB]

Very clever Alan. 

[irneb]

Yep! Never thought of doing that. I'd have made some global variable (or rather local to surrounding defun), then setq'd from inside the lambda. Alan's is much neater!

[alanjt]

 

Code: [Select]

(defun _linesClosed (lst)
  (mapcar '(lambda (a b) (entmakex (list '(0 . "LINE") (cons 10 a) (cons 11 b))))
          lst
          (append (cdr lst) (list (car lst)))
  )
)

[ElpanovEvgeniy]

Code: [Select]

(defun _linesClosed (lst)
  (mapcar '(lambda (a b) (entmakex (list '(0 . "LINE") (cons 10 a) (cons 11 b))))
          lst
          (append (cdr lst) (list (car lst)))
  )
)

I recommend:

Code: [Select]

(defun _linesClosed (lst)
  (mapcar '(lambda (a b) (entmakex (list '(0 . "LINE") (cons 10 a) (cons 11 b))))
          (cons (last lst) lst)
          lst
  )
)

[alanjt]

Code: [Select]

(defun _linesClosed (lst)
  (mapcar '(lambda (a b) (entmakex (list '(0 . "LINE") (cons 10 a) (cons 11 b))))
          lst
          (append (cdr lst) (list (car lst)))
  )
)

I recommend:

Code: [Select]

(defun _linesClosed (lst)
  (mapcar '(lambda (a b) (entmakex (list '(0 . "LINE") (cons 10 a) (cons 11 b))))
          (cons (last lst) lst)
          lst
  )
)

nice