Topic: Highlighting the line

[paulmcz]

Is there a way that the line selected for this line of code would get highlighted on the screen and stay highlighted?

(setq a (car (entsel "\n Select line: ")))

Thanks, Paul.

[LE]

Look for the function REDRAW

(redraw a 3)

[Andrea]

Code: [Select]

(setq a (car (entsel "\n Select line: ")))
(vl-cmdf "_select" a "")
(setq b (ssget "_P"))
(sssetfirst nil b)
(alert "line selected")

[LE]

Code: [Select]

(setq a (car (entsel "\n Select line: ")))
(vl-cmdf "_select" a "")
(setq b (ssget "_P"))
(sssetfirst nil b)
(alert "line selected")

The function redraw is designed for the purpose of highlight an entity, the other form is to use (vlax-highlight obj :vlax-true)

[paulmcz]

You guys are the best!
(redraw a 3)
did the trick.

Thanks,
Paul.

[paulmcz]

Here is, what I was working on, when I needed the highlighting resolved. For someone who does a lot of converting to polylines and joining, it could come handy as it saves you a few clicks.

[Fatty]

Hi Paul

I did try to go another way
Maybe this likes you:

Code: [Select]

(defun c:tsx (/ a b closed_flag en flag i ss)
  (setq a nil
b nil
  )
  (setvar "pickfirst" 0);to clear previous selset
  (setvar "cmdecho" 0)

  (if
    (setq ss (ssget '((0 . "LINE,ARC,LWPOLYLINE")))
  i  -1
    )
     (progn
       (while (setq en (ssname ss (setq i (1+ i))))
(if (eq (cdr (assoc 0 (entget en))) "LWPOLYLINE")
   (setq flag t)
   nil
)
(if (= (cdr (assoc 70 (entget en))) 1)
   (setq closed_flag t)
   nil
)
       )
     )
  )
  (if (not closed_flag)
    (progn
      (if flag

(command "pedit" ss "j" ss "" "")
(command "pedit" ss "y" "j" ss "" "")
      )
    )
    (alert "\n You can't join anything with closed polyline!")
  )
  (setvar "cmdecho" 1)
  (setvar "pickfirst" 1)
  (princ)
)

Thank you

Fatty

[paulmcz]

Hi Fatty,
Very nice.
One more click saved!
Would you know, how to make it display, "x segments added to polyline", on the command line when the function finishes?
Paul.

[MP]

Here's a way to deal with selection sets.

Code: [Select]

(defun ssredraw ( ss mode / i )
    (if (eq 'pickset (type ss))
        (repeat (setq i (sslength ss))
            (redraw
                (ssname ss (setq i (1- i)))
                mode
            )
        )
    )
)
;;  hide 'em

(ssredraw ss 2)

;;  show 'em

(ssredraw ss 1)

;;  highlight

(ssredraw ss 3)

;;  unhighlight

(ssredraw ss 4)

[paulmcz]

Selection in response to 'ssget' always gets highlited, it's the 'entsel' that for some reason doesn't trigger it. Then, one sometimes needs to deal with it somehow.

This good to know.
Thanks MP.

[MP]

Selection in response to 'ssget' always gets highlited ...

Careful Paul, depends on the highlight variable setting --

e.g.

(setvar "highlight" 0)

(ssget)

(setvar "highlight" 1)

(ssget)

[paulmcz]

That's true, absolutely!