Topic: Changing XLINE appearance

[gmyroup]

Is there any way to change the appearance of an XLINE (contruction Line)?  I'd like to change the color and linetype to make construction lines more obvious.

[Keith™]

different layer?
a reactor to change them?

what are your constraints?

[TimSpangler]

I have mine come in on a non-plotting layer that is Magenta.

[JCTER]

You change 'em like you do any other object.

You can select all the xlines in the drawing using QSELECT, if they need put on a different layer after the fact.

[Krushert]

Are you talking construction lines for a vertical?   

[Andrea]

there's mine...

maybe it could help..

Code: [Select]

;; XLINES and RAY on DEFPOINTS LAYER
;; By: Andrea Andreetti 2008-08-20


(vl-load-com)
; (getLayers t)  = All Layers included XREF Layers
; (getLayers nil)  = All Layers EXCLUDED XREF Layers
(defun getlayers (xref / bav doc blk)
  (setq bav nil)
  (setq doc (vla-get-activedocument (vlax-get-acad-object)))
  (vlax-for blk (vla-get-layers doc)
    (if xref
      (setq bav (append bav (list (strcase (vla-get-name blk)))))
      (if (not (vl-string-search "|" (vla-get-name blk)))
        (setq bav (append bav (list (strcase (vla-get-name blk)))))
      )
    )
  )
  bav
)





(defun *XlineReactor_S* (call-reactor sci / layers Lname adoc Layers Nlayer xline)
(setq curLayer (getvar "CLAYER"))
(setq Lname "DEFPOINTS")
(setq adoc (vla-get-activedocument (vlax-get-acad-object)))
  (if (member (strcase (car sci)) '("XLINE" "RAY"))
    (progn
(if (not (member Lname (getlayers nil)))
  (progn
    (setq Layers (vla-get-layers adoc))
    (setq Nlayer (vla-add Layers Lname))
    ;(vla-put-color Nlayer 5)
    ;(vla-put-linetype Nlayer "Dashed2")
    ;.....etc..
  )
)
(setq xline (vla-item (vla-get-layers adoc) Lname))
(vla-put-activelayer adoc xline)
)))
 






(defun *XlineReactor_E* (call-reactor sci / adoc clayer vlclayer)
(setq adoc (vla-get-activedocument (vlax-get-acad-object)))
  (if (member (strcase (car sci)) '("XLINE" "RAY"))
    (progn
      (setq vlclayer (vla-item (vla-get-layers adoc) curLayer))
      (vla-put-activelayer adoc vlclayer)
    )
  )
)






;;REACTOR SECTION
(if XlineReactor_S
    (progn (vlr-remove XlineReactor_S)
           (setq XlineReacto_S nil)
    )
  )
  (setq XlineReactor_S
         (vlr-command-reactor nil
                              '((:vlr-commandWillStart . *XlineReactor_S*))
         )
  )


(if XlineReactor_E
    (progn (vlr-remove XlineReactor_E)
           (setq XlineReacto_E nil)
    )
  )
  (setq XlineReactor_E
         (vlr-command-reactor nil
                              '((:vlr-commandEnded . *XlineReactor_E*))
         )
  )

(if XlineReactor_C
    (progn (vlr-remove XlineReactor_C)
           (setq XlineReacto_C nil)
    )
  )
  (setq XlineReactor_C
         (vlr-command-reactor nil
                              '((:vlr-commandCancelled . *XlineReactor_E*))
         )
  )





[Lee Mac]

Another (a reactor toggle  )

Code: [Select]

(defun c:XLR nil
  ;; © Lee Mac  ~  11.06.10
  (vl-load-com)

  (  (lambda ( data foo1 foo2 / react )       
       (if (setq react
             (vl-some
               (function
                 (lambda ( reactor )
                   (if (eq data (vlr-data reactor)) reactor)
                 )
               )
               (cdar
                 (vlr-reactors :vlr-command-reactor)
               )
             )
           )
         (if (vlr-added-p react)
           (vlr-remove react)
           (vlr-add react)
         )
         (setq react
           (vlr-command-reactor data
             (list
               (cons :vlr-CommandWillStart foo1)
               (cons :vlr-CommandEnded     foo2)
               (cons :vlr-CommandCancelled foo2)
             )
           )
         )
       )
       (princ
         (if (vlr-added-p react)
           "\n** Reactor Activated **"
           "\n** Reactor Deactivated **"
         )
       )
       react
     )
    "XLine-Reactor"
    'XLR:WillStart
    'XLR:Cancelled
  )

  (princ)
)

(defun XLR:WillStart ( reactor args )

  ;;---------------------------------------------------------------;;

  (setq XLineLayer "XLineLayer") ;; <--<< Change this if necessary

  ;;---------------------------------------------------------------;;

  (if (wcmatch (strcase (car args)) "XLINE,RAY")
    (progn
      (setq *clayer* (getvar 'CLAYER))

      (or (tblsearch "LAYER" XLineLayer)
          (entmake (list (cons 0 "LAYER")
                         (cons 100 "AcDbSymbolTableRecord")
                         (cons 100 "AcDbLayerTableRecord")
                         (cons 2 XLineLayer)
                         (cons 70 0))))

      (setvar 'CLAYER XLineLayer)
    )
  )
  (princ)
)

(defun XLR:Cancelled ( reactor args )
  (if (and *clayer* (wcmatch (strcase (car args)) "XLINE,RAY"))
    (progn
      (setvar 'CLAYER *clayer*)
      (setq *clayer* nil)
    )
  )
  (princ)
)

Type 'XLR' to activate the reactor (only once), then 'XLR' again to deactivate