Topic: confused on the name of ATTDYNBLOCKREF,please help

[snddd2000]

now i have a block list as below
((-1 . <图元名: 7efc0300>) (0 . "INSERT") (5 . "B9B8") (102 . "{ACAD_XDICTIONARY") (360 . <图元名: 7ed09318>) (102 . "}") (330 . <图元名: 7efa9cf8>) (100 . "AcDbEntity") (67 . 0) (410 . "Model") (8 . "细实线") (100 . "AcDbBlockReference") (66 . 1) (2 . "*U661") (10 3672.0 784.0 0.0) (41 . 8.0) (42 . 8.0) (43 . 8.0) (50 . 0.0) (70 . 0) (71 . 0) (44 . 0.0) (45 . 0.0) (210 0.0 0.0 1.0))

the  (2 . "*U661") should be the name ,but when i defined this block the name is "qq",not "*U661"
why? confuesd long time
thanks
please help me!
my english is not good
 

[Tharwat]

I guess this would give the real name of it .

Code: [Select]

(setq ss (ssget "_+.:S" '((0 . "INSERT"))))
(setq BlkName (vla-get-effectivename  (vlax-ename->vla-object (ssname ss 0))))

Regards,

Tharwat

[snddd2000]

the real name ? means what?

thanks

[Tharwat]

Your Block name before going to become a Dynamic Block

Try the codes and you will find it out .

this block the name is "qq",not "*U661"

[snddd2000]

when i copy this block to another dwg.
the *U661 would be changed ,and the "qq"  not changed.
press ctrl+1 the name "qq" in the list of properties

[snddd2000]

yes the block is Dynamic Block
Dynamic Block name must like this?

thanks

[Jeff H]

You do understand with dynamic blocks anytime you change a dynamic property it will create a anonymous block?

[snddd2000]

thanks a lot
it works

one question
(setq ss (ssget "_+.:S" '((0 . "INSERT"))))
why add "_+.:" before :S? 

[Tharwat]

thanks a lot
it works

one question
(setq ss (ssget "_+.:S" '((0 . "INSERT"))))
why add "_+.:" before :S? 

Because the ssget function is multi-selection set and to add "_+.:S" would force it for single selection set only ( one selection set).

Good luck.

[snddd2000]

You do understand with dynamic blocks anytime you change a dynamic property it will create a anonymous block?

but why select two diffrent block ,the name is same?

命令: (vlax-get-property (vlax-ename->vla-object  (car (entsel))) 'name)

选择对象: "*U661"

命令: (vlax-get-property (vlax-ename->vla-object  (car (entsel))) 'name)

选择对象: "*U661"

[snddd2000]

thanks a lot
it works

one question
(setq ss (ssget "_+.:S" '((0 . "INSERT"))))
why add "_+." before :S? 

Because the ssget function is multi-selection set and to add "_+.:S" would force it for single selection set only ( one selection set).

Good luck.

how can i filter this name block by ssget?
thanks

[pBe]

right after this: (as tharwats suggestion)

Code: [Select]

(setq ss (ssget "_+.:S" '((0 . "INSERT"))))
Before you processed the block, run this as a test for block name

Code: [Select]

(setq BlkName (vla-get-effectivename  (vlax-ename->vla-object (ssname ss 0))))
it will you give you name of the block for your test/cond
(if (eq BlkName "qq") (.... <----- test
But if you're going to select on screen as the example suggest, you dont really need to do this as you already know you're selecting the correct block, but if you have the need for the blockname then you should run the test.

Now if you select the entire database using "_X" (meaning no prompt for selection on the screen)

Code: [Select]

(setq ss (ssget "_X" '((0 . "INSERT")(2 . "*U*,qq"))))Then you need to run it through the test before you worked on the block

That is just how Dynamic Block behaves (Autodesk needs to do something about this I guess), converting it to an anonymous name

Hope this helps

[snddd2000]

right after this: (as tharwats suggestion)

Code: [Select]

(setq ss (ssget "_+.:S" '((0 . "INSERT"))))
Before you processed the block, run this as a test for block name

Code: [Select]

(setq BlkName (vla-get-effectivename  (vlax-ename->vla-object (ssname ss 0))))
it will you give you name of the block for your test/cond
(if (eq BlkName "qq") (.... <----- test
But if you're going to select on screen as the example suggest, you dont really need to do this as you already know you're selecting the correct block, but if you have the need for the blockname then you should run the test.

Now if you select the entire database using "_X" (meaning no prompt for selection on the screen)

Code: [Select]

(setq ss (ssget "_X" '((0 . "INSERT")(2 . "*U*,qq"))))Then you need to run it through the test before you worked on the block

That is just how Dynamic Block behaves (Autodesk needs to do something about this I guess), converting it to an anonymous name

Hope this helps

thanks a lot but this (setq ss (ssget "_X" '((0 . "INSERT")(2 . "*U*,qq")))) does not work
canot select any blocks,
now i use below way to do

Code: [Select]

(setq ss1 (ssget '((0 . "INSERT"))) )
(setq count  (sslength ss1)
      n       0
      n1      0
      zl1     0
      zzl1    0
)
(repeat count
 (if (/= "qq" (vla-get-effectivename (vlax-ename->vla-object (ssname ss1 n))))
  (progn
    (ssdel (ssname ss1 n) ss1)
    (setq n (1- n))
  )
 )
 (setq n (1+ n))
)
i do not know any better way.

thanks all

[pBe]

oops my bad

Code: [Select]

(setq ss (ssget "_X" '((0 . "INSERT")(2 . "*U*,qq"))))
Should be

Code: [Select]

(setq ss (ssget "_X" '((0 . "INSERT")(2 . "`*U*,qq"))))or

Code: [Select]

(setq ss (ssget  '((0 . "INSERT")(2 . "`*U*,qq"))))
But anyway, i see you got it figured out

[snddd2000]

oops my bad

Code: [Select]

(setq ss (ssget "_X" '((0 . "INSERT")(2 . "*U*,qq"))))
Should be

Code: [Select]

(setq ss (ssget "_X" '((0 . "INSERT")(2 . "`*U*,qq"))))
But anyway, i see you got it figured out

Great, it is right , i like your way
thank you very much

[Tharwat]

oops my bad

Code: [Select]

(setq ss (ssget "_X" '((0 . "INSERT")(2 . "*U*,qq"))))
Should be

Code: [Select]

(setq ss (ssget "_X" '((0 . "INSERT")(2 . "`*U*,qq"))))or

Code: [Select]

(setq ss (ssget  '((0 . "INSERT")(2 . "`*U*,qq"))))
But anyway, i see you got it figured out

I think the  (2 . "`*U*,qq") would select all dynamic blocks without considering the name of the main block which

is (qq) and which is added to it as a filtration system .

That's what I got while testing it.

[snddd2000]

oops my bad

Code: [Select]

(setq ss (ssget "_X" '((0 . "INSERT")(2 . "*U*,qq"))))
Should be

Code: [Select]

(setq ss (ssget "_X" '((0 . "INSERT")(2 . "`*U*,qq"))))or

Code: [Select]

(setq ss (ssget  '((0 . "INSERT")(2 . "`*U*,qq"))))
But anyway, i see you got it figured out

I think the  (2 . "`*U*,qq") would select all dynamic blocks without considering the name of the main block which

is (qq) and which is added to it as a filtration system .

That's what I got while testing it.

yes,thank your testing
i found it also.
if this .dwg only have one kind of dynamic block, it is ok.
if not ,as now i am still use fun(if (/= ...)) in code to ssdel the ent.
Do you have better way to filter the block just use ssget?

[Lee Mac]

Another method:

Code: [Select]

(defun test ( block )
  (ssget
    (list
      (cons 0 "INSERT")
      (cons 2
        (
          (lambda ( s )
            (foreach anon (LM:AnonymousInstancesof block)
              (setq s (strcat s ",`" anon))
            )
            s
          )
          block
        )
      )
    )
  )
)

(defun LM:AnonymousInstancesof ( block / def rec nme ref lst )
  (while (setq def (tblnext "BLOCK" (null def)))
    (if (= 1 (logand 1 (cdr (assoc 70 def))))
      (progn
        (setq rec
          (entget
            (cdr
              (assoc 330
                (entget
                  (tblobjname "BLOCK" (setq nme (cdr (assoc 2 def))))
                )
              )
            )
          )
        )
        (while (setq ref (assoc 331 rec))
          (if
            (and
              (eq block (vla-get-effectivename (vlax-ename->vla-object (cdr ref))))
              (not (member nme lst))
            )
            (setq lst (cons nme lst))
          )
          (setq rec (cdr (member (assoc 331 rec) rec)))
        )
      )
    )
  )
  (reverse lst)
)

Code: [Select]

(test "qq")

[snddd2000]

Another method:

Code: [Select]

(defun test ( block )
  (ssget
    (list
      (cons 0 "INSERT")
      (cons 2
        (
          (lambda ( s )
            (foreach anon (LM:AnonymousInstancesof block)
              (setq s (strcat s ",`" anon))
            )
            s
          )
          block
        )
      )
    )
  )
)

(defun LM:AnonymousInstancesof ( block / def rec nme ref lst )
  (while (setq def (tblnext "BLOCK" (null def)))
    (if (= 1 (logand 1 (cdr (assoc 70 def))))
      (progn
        (setq rec
          (entget
            (cdr
              (assoc 330
                (entget
                  (tblobjname "BLOCK" (setq nme (cdr (assoc 2 def))))
                )
              )
            )
          )
        )
        (while (setq ref (assoc 331 rec))
          (if
            (and
              (eq block (vla-get-effectivename (vlax-ename->vla-object (cdr ref))))
              (not (member nme lst))
            )
            (setq lst (cons nme lst))
          )
          (setq rec (cdr (member (assoc 331 rec) rec)))
        )
      )
    )
  )
  (reverse lst)
)

Code: [Select]

(test "qq")

lee Mac
I’ve read a lot of your code at here,
thank your code.

[Lee Mac]

You're welcome 

Enjoy 

[snddd2000]

Another method:

Code: [Select]

(defun test ( block )
  (ssget
    (list
      (cons 0 "INSERT")
      (cons 2
        (
          (lambda ( s )
            (foreach anon (LM:AnonymousInstancesof block)
              (setq s (strcat s ",`" anon))
            )
            s
          )
          block
        )
      )
    )
  )
)

(defun LM:AnonymousInstancesof ( block / def rec nme ref lst )
  (while (setq def (tblnext "BLOCK" (null def)))
    (if (= 1 (logand 1 (cdr (assoc 70 def))))
      (progn
        (setq rec
          (entget
            (cdr
              (assoc 330
                (entget
                  (tblobjname "BLOCK" (setq nme (cdr (assoc 2 def))))
                )
              )
            )
          )
        )
        (while (setq ref (assoc 331 rec))
          (if
            (and
              (eq block (vla-get-effectivename (vlax-ename->vla-object (cdr ref))))
              (not (member nme lst))
            )
            (setq lst (cons nme lst))
          )
          (setq rec (cdr (member (assoc 331 rec) rec)))
        )
      )
    )
  )
  (reverse lst)
)

Code: [Select]

(test "qq")

something error
sometimes,it is ok,sometimes error msg is :ActiveX 服务器返回错误: 未知名称: EffectiveName
could you tell me why? thanks a lots

[Lee Mac]

The code will only work on versions in which the EffectiveName property is available. A check could be included for this property, but surely, if the property is not available, dynamic blocks are also not available meaning the code is redundant anyway?

Code: [Select]

(defun test ( block )
  (ssget
    (list
      (cons 0 "INSERT")
      (cons 2
        (
          (lambda ( s )
            (foreach anon (LM:AnonymousInstancesof block)
              (setq s (strcat s ",`" anon))
            )
            s
          )
          block
        )
      )
    )
  )
)

(defun LM:AnonymousInstancesof ( block / def rec nme ref lst )
  (while (setq def (tblnext "BLOCK" (null def)))
    (if (= 1 (logand 1 (cdr (assoc 70 def))))
      (progn
        (setq rec
          (entget
            (cdr
              (assoc 330
                (entget
                  (tblobjname "BLOCK" (setq nme (cdr (assoc 2 def))))
                )
              )
            )
          )
        )
        (while (setq ref (assoc 331 rec))
          (if
            (and
              (eq block
                (
                  (lambda ( obj )
                    (vlax-get-property obj
                      (if (vlax-property-available-p obj 'effectivename)
                        'effectivename
                        'name
                      )
                    )
                  )
                  (vlax-ename->vla-object (cdr ref))
                )
              )
              (not (member nme lst))
            )
            (setq lst (cons nme lst))
          )
          (setq rec (cdr (member (assoc 331 rec) rec)))
        )
      )
    )
  )
  (reverse lst)
)

[snddd2000]

thank your reply
but i still do not know why,
now, i open a newdrawing,this drawing is blank, i key the command, it works
then i copy a part of drawings from the drawing the command does not work, the command works also,
but when i copy all of the drawing to the new drawing, the command does not work.
something make the command error, i still can not find it.

[snddd2000]

i find a reason , when the drawing include a table (R17.0), the command does not work.
any way can solute this?

[snddd2000]

(defun LM:AnonymousInstancesof (block / def rec nme ref lst)
  (while (setq def (tblnext "BLOCK" (null def)))
    (if   (= 1 (logand 1 (cdr (assoc 70 def))))
      (progn
   (setq rec
          (entget
       (cdr
         (assoc 330
           (entget
             (tblobjname "BLOCK" (setq nme (cdr (assoc 2 def))))
           )
         )
       )
          )
   )
   (while (setq ref (assoc 331 rec))
     (if (= "INSERT"
       (cdr (assoc 0 (entget (cdr ref))));_add this to filter out table.
         )
       (if
         (and
      (eq block
          (vla-get-effectivename
            (vlax-ename->vla-object (cdr ref))
          )
      )
      (not (member nme lst))
         )
          (setq lst (cons nme lst))
       )
     )
     (setq rec (cdr (member (assoc 331 rec) rec)))
   )
      )
    )
  )
  (reverse lst)
)