Topic: folder network write permission...

[Andrea]

Hi all,..

I would like to know if it is possible in LISP to know if the current user have
some write permission in a specific folder..

for the moment i use this...

Code: [Select]

(setq filetemp (open (strcat setupfolder "\\" DEPARTEMENT "\\test.txt") "w"))
(close filetemp)
(if (findfile (strcat setupfolder "\\" SDC_DEPARTEMENT "\\test.txt"))
  (progn.....
but work only for who have write permission....

 

[ElpanovEvgeniy]

Try so:

Code: [Select]

(vl-file-copy
  (strcat setupfolder "\\" DEPARTEMENT "\\test.txt")
  (strcat (getenv "tmp") "\\test.txt")
) ;_  vl-file-copy

(setq filetemp (open (strcat (getenv "tmp") "\\test.txt") "w"))
(close filetemp)

[MP]

Quick and dirty --

Code: [Select]

(defun IsFolderWriteable ( foldername )
    (and
        (vl-file-directory-p foldername)
        (   (lambda ( tempfilename / handle )
                (if (setq handle (open tempfilename "w"))  
                    (progn
                        (close handle)
                        (vl-file-delete tempfilename)
                        t
                    )
                )
            )
            (vl-filename-mktemp "yaqada" foldername ".yep")
        )    
    )
)

[Andrea]

Try so:

Code: [Select]

(vl-file-copy
  (strcat setupfolder "\\" DEPARTEMENT "\\test.txt")
  (strcat (getenv "tmp") "\\test.txt")
) ;_  vl-file-copy

(setq filetemp (open (strcat (getenv "tmp") "\\test.txt") "w"))
(close filetemp)

thanks...ElpanovEvgeniy

But If I understand your code..
You copy the test.txt file from network to local...and than see if we can open from there !!?
hmm...not realy what i need...

But you give me some hint...

Code: [Select]

(setq filetemp (strcat setupfolder "\\" DEPARTEMENT "\\test.txt"))
(setq Fre (vl-file-copy currentexistingfile filetemp))
 
(if Fre
  (progn
  (vl-file-delete filetemp).....
Thanks...

I have lurn another think....again...

[MP]

Another dick and quirty just for fun --

Code: [Select]

(defun IsFolderWriteable ( foldername )
    (and
        (vl-file-directory-p foldername)
        (   (lambda ( fso / result )
                (setq result
                    (zerop
                        (logand 1
                            (vlax-get
                                (vlax-invoke fso 'GetFolder foldername)
                                'Attributes
                            )
                        )
                    )
                )   
                (vlax-release-object fso)
                result
            )
            (vla-getinterfaceobject
                (vlax-get-acad-object)
                "Scripting.FileSystemObject"
            )
        )   
    )
)

[MP]

Edit: added missing local declaration.

I believe that first version may cause a memory leak because the implied folder object is not formally released. I'm leaving it intact for conversation sake.

Here's a variant that does formal cleanup --

Code: [Select]

(defun IsFolderWriteable ( foldername )
    (and
        (vl-file-directory-p foldername)
        (   (lambda ( / fso folder result )
                (setq result
                    (zerop
                        (logand 1
                            (vlax-get
                                (setq folder
                                    (vlax-invoke
                                        (setq fso
                                            (vla-getinterfaceobject
                                                (vlax-get-acad-object)
                                                "Scripting.FileSystemObject"
                                            )
                                        )   
                                       'GetFolder
                                        foldername
                                    )
                                )
                                'Attributes
                            )   
                        )
                    )
                )
                (vlax-release-object folder)
                (vlax-release-object fso)
                result
            )
        )
    )
)

[Sdoman]

Code: [Select]

(defun IsFolderWriteable ( foldername )
    (and
        (vl-file-directory-p foldername)
        (   (lambda ( / fso folder result )
        ....


Nice function MP.  I am curious however, as to why you used Lambda in this situation?  Typically, I see it used as an argument to Mapcar or Apply.

[MP]

Nice function MP.  I am curious however, as to why you used Lambda in this situation?  Typically, I see it used as an argument to Mapcar or Apply.

1.	One could use progn, but the parent code would have to declare the locals -- not necessarily a bad thing, but more and more I try to utilize discrete blocks of code / logic.
2.	Down the road if one wished to extract that portion of the code to use as a separate function it's already formed (self contained) as such.
3.	It's clean to me in an inexplicable way, but I fully admit -- I'm kinda funny that way.

:loco:

Thanks Steve.

[Sdoman]

1.	One could use progn, but the parent code would have to declare the locals -- not necessarily a bad thing, but more and more I try to utilize discrete blocks of code / logic.
2.	Down the road if one wished to extract that portion of the code to use as a separate function it's already formed (self contained) as such.
3.	It's clean to me in an inexplicable way, but I fully admit -- I'm kinda funny that way.

I see the wisdom now.   Very creative usage.  Thanks for the lesson.

[MP]

Thank you Steve -- very generous comments.