Topic: Attribute Change text (value) based on Attribute Tag - Lisp

[AVCAD]

Hey all,

I am trying to make a lisp to run to allow me to change a Attribute value Based on the TAG. I want anything with the attribute tag to be changed to a set value like XXX. This is kind of a reset for all blocks in a drawing. We use a certain TAG to list out what rooms the device is in. And when coping from drawing to drawing we have to remember to change these...I would like to reset anything in the drawing to a default value (XXX) and then i can use find replace to set it to the correct value.

Any one have something like this or know how to make it work? I have tried -ATTEDIT but it only does 1 object at a time and i want to do the entire drawing.

Thanks in Advance!

[Lee Mac]

Consider the following simple code -

Code - Auto/Visual Lisp: [Select]

1. (defun c:battedit ( / blk tag val )
2.     (setq blk (strcase (getstring t "\nSpecify optional block filter <*>: "))
3.           tag (strcase (getstring "\nSpecify optional tag filter <*>: "))
4.           val (getstring t "\nSpecify new attribute value <blank>: ")
5.     )
6.     (if (= "" blk) (setq blk "*"))
7.     (if (= "" tag) (setq tag "*"))
8.     (vlax-for def (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
9.         (if (= :vlax-false (vla-get-isxref def))
10.             (vlax-for obj def
11.                 (if (and (= "AcDbBlockReference" (vla-get-objectname obj))
12.                          (wcmatch (blockname obj) blk)
13.                          (= :vlax-true (vla-get-hasattributes obj))
14.                          (vlax-write-enabled-p obj)
15.                     )
16.                     (foreach att (vlax-invoke obj 'getattributes)
17.                         (if (and (wcmatch (strcase (vla-get-tagstring att)) tag)
18.                                  (vlax-write-enabled-p att)
19.                             )
20.                             (vla-put-textstring att val)
21.                         )
22.                     )
23.                 )
24.             )
25.         )
26.     )
27.     (princ)
28. )
29.  
30. (defun blockname ( obj )
31.     (if (vlax-property-available-p obj 'effectivename)
32.         (defun blockname ( obj ) (strcase (vla-get-effectivename obj)))
33.         (defun blockname ( obj ) (strcase (vla-get-name obj)))
34.     )
35.     (blockname obj)
36. )
37.  
38. (vl-load-com) (princ)

Note that this will operate on all blocks (primary & nested) within all drawing layouts.

[AVCAD]

Lee mac! works perfectly for what I need. Thank you very much!

[Lee Mac]

You're most welcome, happy to help! 

[AVCAD]

Is there a way to use this to find blocks that have a attribute but is blank? I would like to reset the blank ones to some thing like xxx so i can find them.

Problem is when we have blocks that have blank attributes it messes up some routines we have, that rely on these attributes.

What is above works great for mass changing everything, again any way to make this work with attributes that are blank to reset them to a defined state?

Thanks again!

[Lee Mac]

Is there a way to use this to find blocks that have a attribute but is blank? I would like to reset the blank ones to some thing like xxx so i can find them.

Try the following -

Code - Auto/Visual Lisp: [Select]

1. (defun c:battedit ( / blk tag val vft )
2.     (setq blk (strcase (getstring t "\nSpecify optional block filter <*>: "))
3.           tag (strcase (getstring "\nSpecify optional tag filter <*>: "))
4.           vft (strcase (getstring t "\nSpecify optional value filter (type SPACE for blank values) <*>: "))
5.           val (getstring t "\nSpecify new attribute value <blank>: ")
6.     )
7.     (if (= "" blk) (setq blk "*"))
8.     (if (= "" tag) (setq tag "*"))
9.     (if (= "" vft) (setq vft "*") (setq vft (vl-string-trim " " vft)))
10.     (vlax-for def (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
11.         (if (= :vlax-false (vla-get-isxref def))
12.             (vlax-for obj def
13.                 (if (and (= "AcDbBlockReference" (vla-get-objectname obj))
14.                          (wcmatch (blockname obj) blk)
15.                          (= :vlax-true (vla-get-hasattributes obj))
16.                          (vlax-write-enabled-p obj)
17.                     )
18.                     (foreach att (vlax-invoke obj 'getattributes)
19.                         (if (and (wcmatch (strcase (vla-get-tagstring  att)) tag)
20.                                  (wcmatch (strcase (vla-get-textstring att)) vft)
21.                                  (vlax-write-enabled-p att)
22.                             )
23.                             (vla-put-textstring att val)
24.                         )
25.                     )
26.                 )
27.             )
28.         )
29.     )
30.     (princ)
31. )
32.  
33. (defun blockname ( obj )
34.     (if (vlax-property-available-p obj 'effectivename)
35.         (defun blockname ( obj ) (strcase (vla-get-effectivename obj)))
36.         (defun blockname ( obj ) (strcase (vla-get-name obj)))
37.     )
38.     (blockname obj)
39. )
40.  
41. (vl-load-com) (princ)

Type a space at the attribute value filter to target blank attribute values.

[AVCAD]

Thanks LeeMAC, Works as needed. Thank you much...one day I will be able to do this alone...lol