Topic: list of elevations or Z values

[drumbald]

:-)I want to draw a line across contours and have it give a list of elevations or Z values of each contour line it comes in contact with

If anyone has any suggestions please let me know

[Jeff_M]

Are these contours shown by polylines or Aec_contour objects from LDD or Civil3d?

[drumbald]

I want it to read both

We get drawings from a lot of different sources

[T.Willey]

Just thinking out loud, but could you use ssget with the fence feature?  Then cycle through the objects in the select set, and get the values for the items you want, and discard the others?

Tim

[Jeff_M]

That's what I used, Tim......

Code: [Select]

(defun c:listZs (/ elevs ent fnc idx lin linobj lin_lst obj ss)
  (if (and (setq lin (ssget ":S" '((0 . "LINE"))))
   (setq lin (ssname lin 0))
   (setq lin_lst (entget lin))
   (setq fnc (list (cdr (assoc 10 lin_lst))(cdr (assoc 11 lin_lst))))
   (setq ss (ssget "F"
   fnc    
   '((0 . "*POLYLINE,*CONTOUR"))
   ))
   )
    (progn
      (setq idx -1
    linobj (vlax-ename->vla-object lin)
    )
      (while (setq ent (ssname ss (setq idx (1+ idx))))
(setq obj (vlax-ename->vla-object ent))
(if (or (vl-string-search "LW" (cdr (assoc 0 (entget ent))))
(vl-string-search "CONTOUR" (cdr (assoc 0 (entget ent))))
)
  (setq elevs (cons (vla-get-elevation obj) elevs))
  (progn
    ;;since this is for contours, an equal Z is assumed for the plines....
    ;;we'll check the first & last Z to verify
    (setq coords (vlax-get obj 'coordinates))
    (if (= (caddr coords) (last coords))
      (setq elevs (cons (caddr coords) elevs))
      )
    )
  )
)
      )
    )
  (princ "\nLine crosses these contours: ")
  (foreach x elevs
    (princ (strcat "\n" (rtos x 2 1)))
    )
  (princ)
  )


[T.Willey]

That's what I used, Tim......

  I must be getting better at this code thing now!

[Joe Burke]

Hi Tim and Jeff,

Just a reminder. The fence method will miss dashed objects when the fence passes over a dash gap. Something to consider in any case, but especially here since contours are often dashed.

Either temporarily change dashed layers to continuous, or change ltscale to a small number, before ssget "F".

[drumbald]

This is doing what I wanted

Thank you

My next step is to have it draw lines at the intersection of the contour line and the line the distance of the elevation and rotate them perpendicular to the original line.

When its done it will give me a simple ground section