Topic: Update drawings in a directory

[aicm]

Hi -- for the first time,
We have a lisp routine that updates all the drawings in a directory to the current version of ACAD.  We now run the routine, which worked in the past, and it crashes with a DOS window appearing that says:
"The system can not find the specified  path"

Could someone take a look at this for us and correct whatever is going wrong.
We know zip about lisp ... been meaning to learn but the work load here is such that finding the time to do the studying is next to impossible.

Using ACAD 2006
Thanks,
Larry

Code: [Select]


;;
;; BCONVERT.LSP
;;
;; Performs a Drawing Open, ZOOM Extents and Save on an entire Directory
;;
;; Note: This utility leaves behind 3 scratch files in the target Directory:
;;
;;  Convertst.scr
;;  Temp.dwg
;;  Temp.txt
;;
;; These 3 scratch files may be deleted after processing is complete
;;
;; TO USE:
;; Setup target Directory on local HDD containing ONLY drawings to convert
;; Launch AutoCAD
;; Set SDI sysvar to 1
;; Type (load "bconvert.lsp")
;; Type BCD
;;  Respond to prompts, navigate to target Directory and select first listed drawing
;;  Processing will be automatic
;; Set SDI sysvar to 0
;; Close AutoCAD
;;
 
(setq *process "")
 
;;
;; MAIN ROUTINE
;;
(defun C:BCD (/ afile)
  (alert "This routine does a zoom extents on an entire directory. Click OK to continue.")
  (setq afile (getfiled (strcat "Select the first file of the directory "
             "to be processed") "" "DWG" 0))
  (if afile
    (bprocess (strp_path afile))
      (alert "You must select the first file of the directory to be processed. Conversion halted.")
  )
)
 
;;
;; Core processing
;;
  (defun bprocess(listpath / tempfile filelist scrfile fp file)
    (setq tempfile (strcat listpath "temp.dwg"))
    (if (findfile tempfile)
      (command "_SAVE" tempfile "y")
      (command "_SAVE" tempfile)
    )
    (setq filelist (get_file_list listpath "DWG"))  ; Build list of drawings to process
    (setq scrfile (strcat listpath "convertst.scr"))  ; Begin building processing script
    (setq fp (open scrfile "w"))
    (foreach file filelist     ; Add each drawing to script
      (write-line (strcat "OPEN " "\"" listpath file "\"") fp) ; OPEN
      (write-line (strcat "Zoom") fp)   ; ZOOM...
      (write-line (strcat "E") fp)    ; ...EXTENTS
      (write-line (strcat *process "_QSAVE") fp)  ; SAVE
    )
    (close fp)
    (command "_SCRIPT" scrfile)   ; Run the script
    (princ)
  )
 
;;
;; Return file list in listpath directory with extention ext
;;
  (defun get_file_list (listpath ext / listfile fp fileline linelen
                     startnum filelist scr file extention filename c)
    (setq listfile "temp.txt")
    (setq listfile (strcat listpath listfile))
    (setq fp (open listfile "w"))
    (write-line "File list for this directory:" fp)
    (close fp)
    (setq filelist '())
    (setq scr (strcat "dir " listpath " > " listfile))
    (command "_shell" scr)
    (command "_delay" 2000)
    (setq fp (open listfile "r"))
    (while (setq fileline (read-line fp))
      (setq linelen (strlen fileline))
      (setq startnum 40) 
      (if (= (substr fileline startnum 1) ":")
        (setq startnum 45) 
      )
      (if (> linelen (+ startnum 3))
        (progn
          (setq file (substr fileline startnum (1+ (- linelen startnum))))
          (setq extention (substr file (- (strlen file) 2) 3))
          (if (= (strcase extention) (strcase ext))
            (setq filelist (append filelist (list file)))
          )
        )
      )
    )
    (close fp)
    (setq filelist filelist)
  )
 
;;
;; Process the drawing file name
;;
  (defun strp_name (full_str / count full_count not_found)
    (if full_str
      (progn
        (setq count (strlen full_str))
        (setq full_count count)
        (setq not_found T)
        (while not_found
          (if
            (or
              (= (substr full_str count 1) "\\")
              (= (substr full_str count 1) "/")
            )
              (setq not_found nil)
              (setq count (- count 1))
          )
        )
        (substr full_str (1+ count)  (- full_count 1) )
      )
      (eval "")
    )
  )
 
;;
;; Strip the path information from the file name
;;
  (defun strp_path(fullname / path name)
    (setq name (strp_name fullname))
    (setq path (substr fullname 1 (- (strlen fullname) (strlen name))))
  )
 
(princ)



[pmvliet]

Are you taking older versions and then brinigng them to the 2k4, 2k5 and 2k6 format?
If this is true, then Autodesk has a batch convertor. Not trying to ignore your lisp, just saying there are other methods readily available. There is always the fact that maybe you can download or install any other software...

Pieter

[Arizona]

It has been a very long time since I have done any lisp, but where is listpath actually being defined?

[aicm]

Are you taking older versions and then bringing them to the 2k4, 2k5 and 2k6 format?
If this is true, then Autodesk has a batch converter. Not trying to ignore your lisp, just saying there are other methods readily available. There is always the fact that maybe you can download or install any other software...

Pieter

Pieter,
I want to thank you for your response and will look into this alternative immediately.
Larry

[Andrea]

You can also take a look to BLP 1.0 (Batch Lisp Processor)

here

[hudster]

From my very basic understanding of lisp, all I can see this routine does is writes a scrpt file for all files in a directory, zooms to extents and then saves the file.

Wouldn't it be just as easy to write a script like this,

Code: [Select]

;;;script file to zoom extents and save
zoom
extents
qsave
;;;end of script
Then run it on a directory using either AutoCADs own script program, or EZscript, oh annd EZscript can also run lisp routines on files as well.

This would have the added bonus of not leaving any files behind when it's finished.

Or have I missed something?

[deegeecees]

This may be a big bite to chew on but, have you looked into ObjectDBX? You can "poke" into AutoCAD drawings without opening them, or without AutoCAD if you use it in a VB app.

[MP]

Sorry, I'm swamped this morning as much as I'd like to pour a bunch of info into this thread. What I'd say about object dbx is just be mendful that said technology screws up the alignment of modified text / attribute entites.

One way to fix said aberration (without resorting to an object arx solution) is to batch open them after you complete all your dbx processing (not via object dbx) and do a simple entupd on all the affected entities and then a save. Unfortunately this does away with your plans to do all this without actually opening them up.

[deegeecees]

OK, here's the easy way:

Make sure AutoCAD is set to save in the version you require, then run this...

Code: [Select]

;batch_anything.lsp
;Created by P.R. Donnelly
;Date: Sept of 2002
;Description: Batch Process
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;start prog

(DEFUN C:batch_anything ()

;;;;;;;;;;;;;;;;;;;;;;;;;Select directory to be processed

(setq dfil (getfiled "Select ONE FILE In The Directory You Want To Batch Process" "p:/" "dwg" 0))
(setq wutdir (vl-filename-directory dfil))
(setq wutfiles (vl-directory-files wutdir "*.dwg"))

(setq scrfile (open "c:\\scrfile.scr" "w"))
(close scrfile)
(setq scrfile (open "c:\\scrfile.scr" "a"))

(foreach n wutfiles
(setq n2 (strcat "\""wutdir "\\" n "\""))
(setq n2 (vl-string-translate "\\" "\\" n2))
(setq scrline (strcat "open" " " n2 " " " "qsave" " " "close"));;;;;;;COMMANDS FOR BATCH GO HERE
(write-line scrline scrfile)
(princ)
)

(close scrfile)
(command "script" "c:\\scrfile")

(princ "\n***Batch complete.***")
(princ)


);;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;DEFUN
This will create a file called scrfile.scr on your C:\ drive, delete after use if you want.

[Arizona]

I have a vba program that does what you want. If you will pm me I will send it to you. You will need to change (I'll show you where) the version it is saving to. Also I have never tested this on newer releases of Acad although I see nothing in it that wouldn't run under 2004 - 2006.

[Fatty]

Hi -- for the first time,
We have a lisp routine that updates all the drawings in a directory to the current version of ACAD.  We now run the routine, which worked in the past, and it crashes with a DOS window appearing that says:
"The system can not find the specified  path"

Could someone take a look at this for us and correct whatever is going wrong.
We know zip about lisp ... been meaning to learn but the work load here is such that finding the time to do the studying is next to impossible.

Hi Larry

If you need rewrite this lisp try this one

(tested in A2005)

Thank you

f.

[code
;; BASED ON BCONVERT.LSP

;; MAIN ROUTINE
(prompt "\n\t***\tType BCD to run batch file operation.\t***\n")

(defun C:BCD (/ afile file_list strp_path)
  (alert "This routine does a zoom extents on an entire directory. Click OK to continue.")
  (setq afile (getfiled (strcat "Select the first DWG file in folder "
             "to be processed") "" "DWG" 0))
  (setvar "filedia" 0)
  (setvar "cmdecho" 0)
  (if afile
    (bprocess afile )
      (alert "You must select any dwg file of the directory \n
      to be processed. Conversion halted.")
  )
      (setvar "filedia" 1)
    (setvar "cmdecho" 1)
  (princ)
)

;; Core processing
  (defun bprocess (afile / file_list scrfile fp file)

      (setq strp_path (strcat (vl-filename-directory afile) "\\"))
;;;    (setq tempfile (strcat strp_path "temp.dwg"))
;;;    (if (findfile tempfile)
;;;      (command "_SAVE" tempfile "y")
;;;      (command "_SAVE" tempfile)
;;;    );=>Why?
  (setq file_list (vl-directory-files strp_path "*.dwg"))
  (setq file_list (mapcar (function (lambda (x) (strcat strp_path x))) file_list))
    (setq scrfile (strcat strp_path "convertst.scr"))  ; Begin building processing script
    (setq fp (open scrfile "w"))
    (princ (strcat "CMDECHO" " " "0" "\n") fp)
    (princ (strcat "ATTDIA" " " "0" "\n") fp)
    (foreach file file_list     ; Add each drawing to script
      (write-line (strcat "_OPEN " "\"" file "\"") fp) ; OPEN
      (write-line (strcat "_ZOOM" " " "_E") fp)   ; ZOOM...E
      (write-line (strcat "_QSAVE\n" " " "_CLOSE") fp)  ; SAVE&CLOSE

)
 
(princ (strcat "CMDECHO" " " "1" "\n") fp)
(princ (strcat "ATTDIA" " " "1" "\n") fp)

    (close fp)
    (alert "Be patience...now is load script")
    (command "_DELAY" 1500)
    (command "_SCRIPT" scrfile)   ; Run the script

    (princ)
  )

Code: [Select]

[deegeecees]

AICM,

Let us know how things turn out.

Deeg

[aicm]

Hi Larry
If you need rewrite this lisp try this one
(tested in A2005)
Thank you

f.

[code
;; BASED ON BCONVERT.LSP
.........

Fatty,
This one is a winner.......... fantastic ......... now I just heed to study how you did this.
Looks like I'm going to have to stay up at nights with Stig's LISP course and Kenny's Afra LISP downloads and get my ar$e in gear and lean this stuff.

We can't thank you enough for taking the time to help.
Larry

PS.
I tried this one first and will take the other suggestions for a spin later today or tonight.

Thank you all again
Larry

[pmvliet]

This just proves the fact that there are a gazzilion ways to accomplish the same thing...
Some very simple, some very complex but I guess that all depends on your knowledge....

Pieter

[deegeecees]

Make sure you change this:

Code: [Select]

    ...(close fp)
    (alert "Be patience...now is load script")
    (command "_DELAY" 1500)
    (command "_SCRIPT" scrfile)   ; Run the script

    (princ)
To this:

Code: [Select]

    ...(close fp)
    (alert "ALL YOUR BASE ARE BELONG TO US")
    (command "_DELAY" 1500)
    (command "_SCRIPT" scrfile)   ; Run the script

    (princ)
It'll make all the difference. 

[aicm]

Code: [Select]

    ...(close fp)
    (alert "ALL YOUR BASE ARE BELONG TO US")
    (command "_DELAY" 1500)
    (command "_SCRIPT" scrfile)   ; Run the script

    (princ)

I could think of more things to put there......

Like:
"Courtesy of The Swamp" 

among other choices .   

[deegeecees]

Not a bad choice at all, my freind.

[Fatty]

Fatty,
This one is a winner.......... fantastic ......... now I just heed to study how you did this.
Looks like I'm going to have to stay up at nights with Stig's LISP course and Kenny's Afra LISP downloads and get my ar$e in gear and lean this stuff.

We can't thank you enough for taking the time to help.
Larry

PS.
I tried this one first and will take the other suggestions for a spin later today or tonight.

Thank you all again
Larry

Hi Larry
Glad if it work for you
BTW, if you don't pleased first routine, try another one:
(tested in A2005 only)

Code: [Select]

(prompt "\n\t\t****\tType BN to run batch file operation\t****\n")

(defun C:BN  (/ acad_app acad_docs acapp adoc bad_files file_list
      fnames other_file path pick_file sld_name x)
  (vl-load-com)
  (or acapp
      (setq acapp (vlax-get-acad-object)
    )
      )

  (or adoc
      (setq adoc
     (vla-get-activedocument
       acapp
       )
    )
      )

  (setq pick_file
(getfiled "Select any of DWG-files : >>>"
   (getvar "dwgprefix")
   "dwg"
   16))
  (setq path (strcat (vl-filename-directory pick_file) "\\"))
  (setq fnames (vl-directory-files path "*.dwg"))
  (setq file_list (acad_strlsort
    (mapcar (function (lambda (x) (strcat path x))) fnames)))
  (setvar "filedia" 0)
  (setvar "cmdecho" 0)
  (setvar "sdi" 0)

  (setq acad_app (vlax-create-object "Autocad.Application"))
  (if acad_app
    (progn
      (vlax-put-property acad_app "Visible" :vlax-true)
      (setq acad_docs (vla-get-Documents acad_app)
    bad_files '()
    )
      (foreach file  file_list
(if
  (not
    (vl-catch-all-error-p
      (setq other_file
     (vl-catch-all-apply 'vla-open (list acad_docs file)))))
   (progn
     (vla-zoomextents (vla-get-application other_file))
     (vla-close other_file :vlax-true)
     (vlax-release-object other_file)
     )
   (progn
     (setq bad_files (append bad_files (list file))
   )
     )
   )
)
      (vl-catch-all-apply
(function (lambda ()
    (vlax-invoke-method acad_app "Quit")
    )))
      (mapcar (function (lambda (x)
  (if
    (and x
(not (vlax-object-released-p x)))
     (vl-catch-all-apply
       (function (lambda ()
   (vlax-release-object x))))
     )
  ))
      (list other_file acad_docs acad_app)
      )
      (setq other_file
     nil
    acad_docs nil
    acad_app nil
    )
      )
    )

  (alert (strcat "There are not processed : \n"
"\t" (itoa (length bad_files))
" files"))
  (gc)
  (princ)
  )


[aicm]

Hi Larry
Glad if it work for you
BTW, if you don't pleased first routine, try another one:
(tested in A2005 only)

Fatty,   
For some reason addressing you with this name is disconcerting to me ..... my issue I guess.
Anyway....

This is another winner.  DING .... DING     
One thing I did notice is that most of these routines change some of the current system variables.
Is there a section of code that could be inserted to save the variables and then re-set them to their initial values after the program has run? 
For example:  Filedia is one of them.

This is not a big issue but just something I noticed.
Thank you for taking the time to help
Larry & all the guys in the studio.

[Fatty]

Is there a section of code that could be inserted to save the variables and then re-set them to their initial values after the program has run? 
For example:  Filedia is one of them.

Hi Larry
Good question

This is correct observation, here it is possible to use
by all the known trick: at the start the program
to define (setq oldfiledia (getvar "filedia")) etc.
and at the end of the program to restore (setvar "filedia" oldfiledia)
BTW in this routine you can use any another function instead of or with
(vla-zoomextents (vla-get-application other_file)) i.e. something like this:
(set-layer other_file "LayerName" "LayerColor" "LayerLType")) etc.
or command i.e. (command "mslide" other_file_short_name)
or batch plot etc.
Let play with it and you will know new possibility of this routine
(No warranty)

Thank you

Code: [Select]


(defun set-lay (cdoc l_name lt_name col / alrs alts nl tbl tblt tmp tmp1)
  (setq alrs (vla-get-layers cdoc)
alts (vla-get-linetypes cdoc)
tbl  (vlax-for l_item  alrs
       (setq tmp (cons (vla-get-name l_item) tmp)))
tblt  (vlax-for lt_item  alts
       (setq tmp1 (cons (vla-get-name lt_item) tmp1)))
)
  (if (not (member lt_name tblt))
    (vla-load alts (strcase lt_name) "acadiso.lin"));or acad.lin
  (if (member l_name tbl)
    (progn
      (if (/= (vla-get-name (vla-get-activelayer cdoc)) l_name)
(setq nl (vla-put-activelayer cdoc (vla-add alrs l_name)))
(setq nl (vla-get-activelayer cdoc))
)
      (vla-put-color nl col)
      (vla-put-linetype nl lt_name)
      )
    (progn
      (setq nl (vla-add alrs l_name))
      (vla-put-activelayer cdoc nl)
      (vla-put-color nl col)
      (vla-put-linetype nl lt_name)
      )
    )
  (if (/= (vlax-variant-value
    (vla-getvariable cdoc "CECOLOR"))
  "BYLAYER")
    (vla-setvariable cdoc "CECOLOR" "BYLAYER")
    )
  (if (= (vla-get-layeron nl) :vlax-false)
    (vla-put-layeron nl :vlax-true)
    )
  (if (= (vla-get-freeze nl) :vlax-true)
    (vla-put-freeze nl :vlax-false)
    )
  (if (= (vla-get-lock nl) :vlax-true)
    (vla-put-lock nl :vlax-false)
    )
  (princ)
  )



(prompt
  "\n\t\t****\tType BL to run batch file operation\t****\n")

(defun C:BL  (/ acad_app acad_docs acapp adoc bad_files batch-err
      file_list fnames oldcmd older oldfil oldsdi other_file path pick_file x)

  (defun batch-err  (msg)
  (if (not (member msg '("console break"
"Function cancelled"
"quit / exit abort")))
    (princ (strcat "\nError: " msg)))
  (if (and acad_app
(not (vlax-object-released-p acad_app))
(vlax-read-enabled-p acad_app)   
(vlax-write-enabled-p acad_app))
    (progn
    (vlax-release-object acad_app)
    (setq acad_app nil)))
    (setq *error* older)
    (setvar "filedia" oldfil)
    (setvar "cmdecho" oldcmd)
    (setvar "sdi" oldsdi)
    (gc)
    (princ)
    )
 
 
  (vl-load-com)
  (setq older *error*
*error* batch-err)
 
  (or acapp
      (setq acapp (vlax-get-acad-object)
    )
      )

  (or adoc
      (setq adoc
     (vla-get-activedocument
       acapp
       )
    )
      )

  (setq pick_file
(getfiled "Select any of DWG-files : >>>"
   (getvar "dwgprefix")
   "dwg"
   16))
  (setq path (strcat (vl-filename-directory pick_file) "\\"))
  (setq fnames (vl-directory-files path "*.dwg"))
  (setq file_list (acad_strlsort
    (mapcar (function (lambda (x) (strcat path x))) fnames)))
  (setq oldfil (getvar "filedia"))
  (setq oldcmd (getvar "cmdecho"))
  (setq oldsdi (getvar "sdi"))
  (setvar "filedia" 0)
  (setvar "cmdecho" 0)
  (setvar "sdi" 0)

  (setq acad_app (vlax-create-object "Autocad.Application"))
  (if acad_app
    (progn
      (vlax-put-property acad_app "Visible" :vlax-true)
      (setq acad_docs (vla-get-documents acad_app)
    bad_files (list)
    )
      (foreach file  file_list
(if
  (not
    (vl-catch-all-error-p
      (setq other_file
     (vl-catch-all-apply 'vla-open (list acad_docs file)))))
   (progn
     (vla-zoomextents (vla-get-application other_file));or comment this string
     (set-lay other_file "TEST_BATCH_LAYER#1" "Phantom2" "160")
     (set-lay other_file "TEST_BATCH_LAYER#2" "ZigZag" acred)
     (vla-close other_file :vlax-true)
     (vlax-release-object other_file)
     )
   (progn
     (setq bad_files (append bad_files (list file))
   )
     )
   )
)
      (vl-catch-all-apply
(function (lambda ()
    (vlax-invoke-method acad_app "Quit")
    )))
      (mapcar (function (lambda (x)
  (if
    (and x
(not (vlax-object-released-p x)))
     (vl-catch-all-apply
       (function (lambda ()
   (vlax-release-object x))))
     )
  ))
      (list other_file acad_docs acad_app)
      )
      (setq other_file
     nil
    acad_docs nil
    acad_app nil
    )
      )
    )

  (alert (strcat "There are not processed : \n"
"\t"
(itoa (length bad_files))
" files"))
  (setq *error* older)
  (setvar "filedia" oldfil)
  (setvar "cmdecho" oldcmd)
  (setvar "sdi" oldsdi) 
  (gc)
  (princ)
  )

______________________________________________________________
Sorry I don't understand your humor because of phraseological English nuances

Fatty

[aicm]

Hi Larry
Good question

This is correct observation, here it is possible to use
by all the known trick: at the start the program
to define (setq oldfiledia (getvar "filedia")) etc.
and at the end of the program to restore (setvar "filedia" oldfiledia)
BTW in this routine you can use any another function instead of or with
(vla-zoomextents (vla-get-application other_file)) i.e. something like this:
(set-layer other_file "LayerName" "LayerColor" "LayerLType")) etc.
or command i.e. (command "mslide" other_file_short_name)
or batch plot etc.
Let play with it and you will know new possibility of this routine
(No warranty)
Thank you

This has turned out to be the first time I have really taken the time to understand what is going on with lisp.  It is a wonderful experience and just might be something I can become interested in doing myself [with a lot more study].

Sorry I don't understand your humor because of phraseological English nuances
Fatty

It's has to do with the American hangup up on being over weight.  Too much commercial concentration on having "a model" physique.  Really not worth mentioning now that I start to explain what I was alluding to. 

Thanks for the short lesson on setting variables.  I realize, to you gurus on this site, it seems rather elementary.
Looks like I'll be spending a lot more time wandering around here ....... learning.

[Fatty]

It's has to do with the American hangup up on being over weight.  Too much commercial concentration on having "a model" physique.  Really not worth mentioning now that I start to explain what I was alluding to. 

Thanks for the short lesson on setting variables.  I realize, to you gurus on this site, it seems rather elementary.
Looks like I'll be spending a lot more time wandering around here ....... learning.

Hi Larry

Are you welcome but..

Sorry I'm again wrote wrong expression:
change all strings like this:
(vla-put-color nl col)
on:
(vla-put-color (vla-item alrs l_name) col)

Happy computing :kewl:

Fatty