Topic: Equivalent to the VBA Split function in Vlisp

[Amsterdammed]

Hello everybody,

Has somebody somewhere a lisp that does the same  as the split function in VBA, splitting a sting into parts at  a defined delimiter?

I would really like not to invent the wheel again.

Thanks in advance

Bernd

[Jürg Menzi]

Try this one:

Code: [Select]

;
; == Function MeString2List
; Converts a string to a list.
; Arguments [Type]:
;   Stg = String [STR]
;   Del = Delimiter pattern [STR]
; Return [Type]:
;   > Converted string [LIST]
;   > False if string empty
; Notes:
;   None
;
(defun MeString2List (Stg Del / DelLgt StrPos TmpLst TmpStr)
 (if (not (eq Stg ""))
  (progn
   (setq TmpStr Stg
         DelLgt (1+ (strlen Del))
   )
   (while (setq StrPos (vl-string-search Del TmpStr))
    (setq TmpLst (cons (substr TmpStr 1 StrPos) TmpLst)
          TmpStr (substr TmpStr (+ StrPos DelLgt))
    )
   )
   (setq TmpLst (cons TmpStr TmpLst))
   (reverse TmpLst)
  )
 )
)

[CAB]

Not sure what you are asking for?
http://www.theswamp.org/phpBB2/viewtopic.php?p=11118#11118

[CAB]

Looks like Jürg got there first.

[Amsterdammed]

Thanks Jürg and Cab

I changed my mind and thought i must be able to do this myself

Code: [Select]


(defun split ( str del / nlist i )

  (While  (setq i(vl-string-position (ascii del) str))
    (setq nlist(append nlist (list (substr str 1 i)))
          str (substr str (+ i  2)))
    )
  (setq nlist (append nlist (list  str )))
       

)

Bernd