Topic: A long time ago in a lisp file far far away...

[deegeecees]

I once wrote a routine that would keep a pline command running until the user typed an "E" for END or "S" for the selection of a circle to run to the center point of. I have since lost this routine as it was some 10 years ago, can anyone point me in the right direction? I'm thinking it was something to do with "initget".

Aaaaand...

How to explode a block and capture all the exploded entities for layer manipulation.

[daron]

a) dunno... where you put it.


b) (setq block (vla-explode (object to explode)))

Those vla-methods will return a list of your exploded objects. You can collect them the usual way. Beautiful tools they are.

[Jürg Menzi]

(setq block (vla-explode (object to explode)))

Attention, doesn't work anymore with NUS block (Bug since A2k4)

[daron]

No way. Well, don't explode NUS's. Man that sucks. Thanks Jurg. We'll have to keep that in mind.

[deegeecees]

a) dunno... where you put it.

I left it with the company I was working for... oops.

[Jürg Menzi]

Man that sucks.

and it sucks also that we (and others) report this bug to Autodesk and they haven't fix it until now. A2k6 owns still the same rubbish.

[CAB]

I borrowed this from somewhere.
Think Michael Puckett may be the author.

Code: [Select]

;;============================================================
;;  Function to get the absolute last entity in the database
;;  Returns nil is drawing is completely empty
(defun ALE_LastEnt ( / EntNam OutVal)
  (and
    (setq OutVal (entlast)); if there is an entity in drawing
    (while (setq EntNam (entnext OutVal))
      (setq OutVal EntNam)
    )
  )
  OutVal
)
;;============================================================
;;  Function to get new items after EntNam in the database
(defun ALE_Ss-After (EntNam / EntNxt SelSet)
  (cond
    ( (not EntNam) (ssget "_X") ); dwg was empty
    ( (setq EntNxt (entnext EntNam)); get new items
      (setq SelSet (ssadd EntNxt))
      (while (setq EntNxt (entnext EntNxt))
        (if (entget EntNxt) (ssadd EntNxt SelSet))
      )
      SelSet
    )
  )
)
;=========================================================

;;=====================================================================
;;===================  Code to get New objects ========================
;;=====================================================================
(setq elast (ALE_LastEnt)); get last entity in database
(setq newbies (ssadd)) ; create an empty selection set
;;
;; Do your array or paste command
;;
(setq newbies (ALE_Ss-After elast))
;; newbies is a selection set of all items created by your command.
;;=====================================================================

[MP]

Can't take credit for that one Alan. I believe the prefix "ALE_" belongs to my friend Marc'Antonio Alessi. If I recall correctly (was long ago), we penned similar functions in a thread on the desk's news server but his was prettier. But thank you nonetheless.

[CAB]

Good morning MP


deegeecees
Here is a quickie, BUT it doesn't catch the user pressing ENTER
For that you would need to add some more code.

Code: [Select]

(defun getp (/ p1 p2 cmd loop)
  (setq loop t)
  (setq p1 (getpoint "\nPick start of pline."))
  (command "pline" p1)

  (while (and loop
              (not (initget "S E"))
              (setq p2 (getpoint p1 "\nPick piont or enter [E S]. "))
         )
    (cond
      ((= (type p2) 'list)
       (command p2)
       (setq p1 p2)
      )
      (t
       (setq loop nil
             cmd  p2
       )
      )
    )
  )
  (command) ; end pline
  cmd
)

[deegeecees]

Thanks CAB! Thats what I was working towards, and I am very pressed for time.

[CAB]

You're welcome.
Say if you only want to prevent an exit from the Enter Key just add a 1 to the intiget

Code: [Select]

(not (initget 1 "S E"))

[deegeecees]

The "E" is to end the command, and the "S" is for STUBUP as in conduit runs. I'll play around with the code a bit till I get it to work the way I want...    ...press "S" and then prompt for circle selection, use polar, get radii and end pline at that point.