Topic: List blocks containing objects with Z>0

[w64bit]

I am using this code to check if a drawing has Z>0.

Code: [Select]

(if (and (/= (caddr (getvar "EXTMAX")) -1E+20)
      (or (> (abs (caddr (getvar "EXTMIN"))) 0)
          (> (abs (caddr (getvar "EXTMAX"))) 0)))
(alert "Drawing is 3D !"))
How I can get in addition, in an alert window or in command line, a list with all blocks containing objects with Z>0?

[kpblc]

Without any checking

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun t1 (/ is-block-with-3d res temp)
3.   (defun is-block-with-3d (block-def / f mi ma)
4.     (vlax-for ent block-def
5.       (if (not f)
6.         (progn
7.           (if (not (vl-catch-all-apply
8.                      (function (lambda ()
9.                                  (vla-getboundingbox ent 'mi 'ma)
10.                                  (setq mi (vlax-safearray->list mi)
11.                                        ma (vlax-safearray->list ma)
12.                                  ) ;_ end of setq
13.                                ) ;_ end of lambda
14.                      ) ;_ end of function
15.                    ) ;_ end of vl-catch-all-apply
16.               ) ;_ end of not
17.             (setq f (apply (function and) (mapcar (function (lambda (x) (equal (caddr x) 0 1e-9))) (list mi ma))))
18.           ) ;_ end of if
19.         ) ;_ end of progn
20.       ) ;_ end of if
21.     ) ;_ end of vlax-for
22.     f
23.   ) ;_ end of defun
24.   (vlax-for blk-def (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
25.     (if (setq temp (is-block-with-3d blk-def))
26.       (setq res (cons (vla-get-name temp) res))
27.     ) ;_ end of if
28.   ) ;_ end of vlax-for
29.   (if res
30.     (princ (strcat "\nThese blocks has 3d geom:"
31.                    (mapcar (function (lambda (x) (strcat "\n\t" x))) (vl-sort res (function <)))
32.            ) ;_ end of strcat
33.     ) ;_ end of princ
34.   ) ;_ end of if
35.   (princ)
36. ) ;_ end of defun

[w64bit]

Tried with the file attached. No message.

[kpblc]

Try this

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun t1 (/ is-block-with-3d res)
3.   (defun is-block-with-3d (block-def / f mi ma)
4.     (vlax-for ent block-def
5.       (if (not f)
6.         (progn
7.           (if (not (vl-catch-all-error-p
8.                      (vl-catch-all-apply
9.                        (function (lambda ()
10.                                    (vla-getboundingbox ent 'mi 'ma)
11.                                    (setq mi (vlax-safearray->list mi)
12.                                          ma (vlax-safearray->list ma)
13.                                    ) ;_ end of setq
14.                                  ) ;_ end of lambda
15.                        ) ;_ end of function
16.                      ) ;_ end of vl-catch-all-apply
17.                    ) ;_ end of vl-catch-all-error-p
18.               ) ;_ end of not
19. ;; modified. Thanks to ribarm
20.             (setq f (apply (function or) (mapcar (function (lambda (x) (not (equal (caddr x) 0 1e-9)))) (list mi ma))))
21.           ) ;_ end of if
22.         ) ;_ end of progn
23.       ) ;_ end of if
24.     ) ;_ end of vlax-for
25.     f
26.   ) ;_ end of defun
27.   (vlax-for blk-def (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object)))
28.     (if (is-block-with-3d blk-def)
29.       (setq res (cons (vla-get-name blk-def) res))
30.     ) ;_ end of if
31.   ) ;_ end of vlax-for
32.   (if res
33.     (princ (strcat "\nThese blocks has 3d geom:"
34.                    (apply (function strcat)
35.                           (mapcar (function (lambda (x) (strcat "\n\t" x))) (vl-sort res (function <)))
36.                    ) ;_ end of apply
37.            ) ;_ end of strcat
38.     ) ;_ end of princ
39.   ) ;_ end of if
40.   (princ)
41. ) ;_ end of defun

[roy_043]

There is a not missing on line 19.

[kpblc]

Ok, fine, you're right. Right now threre is a midnight, I can't create any kind of code. Could you corrent it please?

[ribarm]

  (defun is-block-with-3d (block-def / f mi ma)
    (vlax-for ent block-def
      (if (not f)
        (progn
          (if (not (vl-catch-all-error-p
                     (vl-catch-all-apply
                       (function (lambda ()
                                   (vla-getboundingbox ent 'mi 'ma)
                                   (setq mi (vlax-safearray->list mi)
                                         ma (vlax-safearray->list ma)
                                   ) ;_ end of setq
                                 ) ;_ end of lambda
                       ) ;_ end of function
                     ) ;_ end of vl-catch-all-apply
                   ) ;_ end of vl-catch-all-error-p
              ) ;_ end of not
            (setq f (apply (function or) (mapcar (function (lambda (x) (not (equal (caddr x) 0 1e-9)))) (list mi ma))))
          ) ;_ end of if
        ) ;_ end of progn
      ) ;_ end of if
    ) ;_ end of vlax-for
    f
  ) ;_ end of defun

[kpblc]

Thank you. Code modified.
Sorry, I forgot about this thread.

[w64bit]

Thank you. It's working but it did not list all the blocks' names, only reports IS-BLOCK-WITH-3D for the whole DWG.

[kpblc]

Use t1 function from https://www.theswamp.org/index.php?topic=56854.msg605407#msg605407

[w64bit]

Thank you.
I have to pay more attention.

[w64bit]

One question.
Is it possible to have the list of blocks in alert window instead of command line?

[kpblc]

Replace princ to alert

[w64bit]

Excellent. Thank you.