Topic: Select viewports in frozen layers

[w64bit]

For locking viewports I am using these lines in a script:

Code: [Select]

(foreach tab (layoutlist) (setvar 'CTAB tab)
(command "-VPORTS" "L" "ON" "ALL" ""))
but the viewports having the layer frozen cannot be selected with "ALL".
How can I complete the code so the viewports having the layer frozen to be in the selection and to be locked?

.....

I think I solve it:

Code: [Select]

(foreach tab (layoutlist) (setvar 'CTAB tab)
(if (setq vp (ssget "X" (list '(0 . "VIEWPORT") (cons 410 (getvar "CTAB")))))(command "-VPORTS" "L" "ON" vp "")))


[mhupp]

This is what i use
https://forums.autodesk.com/t5/autocad-forum/locking-viewports/td-p/5389601

They are missing this

Code: [Select]

(defun SSVPLock ( ss lock / i )
  (vl-load-com)
  (if ss
    (repeat (setq i (sslength ss))
      (vla-put-displaylocked (vlax-ename->vla-object (ssname ss (setq i (1- i)))) lock) t
    )
  )
)

[ronjonp]

And another:

Code - Auto/Visual Lisp: [Select]

1. (defun lockallviewports (/ vps)
2.   (if (setq vps (ssget "_X" '((0 . "VIEWPORT") (-4 . "!=") (69 . 1))))
3.     (foreach x (mapcar 'cadr (ssnamex vps))
4.       (vl-catch-all-apply 'vlax-put (list (vlax-ename->vla-object x) 'displaylocked -1))
5.     )
6.   )
7.   (princ)
8. )
9. (lockallviewports)

[framednlv]

and...

Code: [Select]

(command "-layer" "th" "*" "")
(foreach tab (layoutlist) (setvar 'CTAB tab)
(command "-VPORTS" "L" "ON" "ALL" ""))
(command "layerp")

[w64bit]

Thank you all very much.