Topic: catch the objects of an exploded group

[domenicomaria]

I need to catch all the objects that were member of an exploded group . . .

Does somebody know a simple way to get this ?

(defun C:K ( / ent-lst x-el x-en)
   (setq x-el (LM:entlast (entlast) ) )
   (setq x-en (entsel "\nselect GROUP to EXPLODE :") )
   (vl-cmdf "ungroup" x-en)
   (setq ent-lst (LM:entnexttoend x-el) )
)

(setq ent-lst (LM:entnexttoend x-el) ) does not work !

[Lee Mac]

Ungrouping is not the same action as exploding - it does not add new entities to the drawing database; you should instead examine the members of the group prior to ungrouping.

[domenicomaria]

it does not add new entities to the drawing database

I supposed that . . .

[domenicomaria]

you should instead examine the members of the group prior to ungrouping.

Does somebody know a simple way to get this ?
"simple" means not elegant, but working ! 

[tombu]

Why not as Lee sugusted use code like

Code: [Select]

(setq ss(ssget))
to select the group which puts all the group entities into a selection set?

Maybe if you posted what code you're working on someone here would offer a simple elegant solution.

[domenicomaria]

Code - Auto/Visual Lisp: [Select]

1. (defun :GROUP-GET-DATA (e / l r )
2.    (if
3.       (and
4.          (setq l (entget e ) )
5.          (setq r (assoc 330 l) )
6.          (setq r (entget (cdr r) ) )
7.          (= (cdr (assoc 0 r ) ) "GROUP")
8.       )
9.       r
10.    )
11. )
12.  
13.  
14. (defun :M-ASSOC (code l)
15.    (mapcar
16.       (function cdr)
17.       (vl-remove-if-not
18.          (function (lambda (i / code)   (= (car i) code) ) )
19.          l
20.       )
21.    )
22. )
23.  
24. (defun c:XG ( / grp-data grp-ss x-en )
25.    (and
26.       (setq x-en (entsel "\nselect GROUP to EXPLODE :") )  
27.       (setq grp-data (:GROUP-GET-DATA (car x-en) ) )
28.       (setq grp-ss (ssadd) )
29.       (foreach en (:M-ASSOC 340 grp-data)  (setq grp-ss (ssadd en grp-ss) ) )
30.       (vl-cmdf "ungroup" (car x-en) )
31.       (vl-cmdf "select" grp-ss "")
32.    )
33.    grp-ss
34. )
35.  

it seems to work . . .

[Marc'Antonio Alessi]

Only an example from tombu suggestion:

Code: [Select]

(defun C:XG2 ( / SelSet)
   (princ "\nSelect GROUP to EXPLODE: ")
   (and
     (setq SelSet (ssget))
     (vl-cmdf "_.UNGROUP" (ssname SelSet 0))
     (vl-cmdf "_.SELECT" SelSet "")
   )
)

[domenicomaria]

(defun C:XG2 ( / SelSet)
   (princ "\nSelect GROUP to EXPLODE: ")
   (and
     (setq SelSet (ssget))
     (vl-cmdf "_.UNGROUP" (ssname SelSet 0))
     (vl-cmdf "_.SELECT" SelSet "")
   )
)

e si ...

[ronjonp]

Maybe this too:

Code - Auto/Visual Lisp: [Select]

1. (defun c:foo (/ d e s)
2.   (if (and (setq e (car (entsel)))
3.            (setq d (cdr (assoc 330 (entget e))))
4.            (= "GROUP" (cdr (assoc 0 (entget d))))
5.       )
6.     (progn (setq s (ssadd))
7.            (foreach x (entget d) (and (= 340 (car x)) (setq s (ssadd (cdr x) s))))
8.            (sssetfirst nil s)
9.            (entdel d)
10.     )
11.   )
12.   (princ)
13. )

*localized 's'

[domenicomaria]

Maybe this too:

Code - Auto/Visual Lisp: [Select]

1. (defun c:foo (/ d e)
2.   (if (and (setq e (car (entsel)))
3.            (setq d (cdr (assoc 330 (entget e))))
4.            (= "GROUP" (cdr (assoc 0 (entget d))))
5.       )
6.     (progn (setq s (ssadd))
7.            (foreach x (entget d) (and (= 340 (car x)) (setq s (ssadd (cdr x) s))))
8.            (sssetfirst nil s)
9.            (entdel d)
10.     )
11.   )
12.   (princ)
13. )

very nice and interesting !

[domenicomaria]

ronjonp thank you.

Maybe for somebody it is obvious, but . . .
. . .
this means that
(entdel d)
deletes the group definition
but doesn't delete the entities contained in the group !

In other words, it explodes the group.

Right ?

[ronjonp]

ronjonp thank you.

Maybe for somebody it is obvious, but . . .
. . .
this means that
(entdel d)
deletes the group definition
but doesn't delete the entities contained in the group !

In other words, it explodes the group.

Right ?

Yes  .. well it deletes the group the entities are contained in.