Author Topic: Help with find hatch lisp (Read 4688 times)

PM · « **on:** September 01, 2020, 10:09:54 AM »

Hi i am using this lisp code to find all hatch in model space and paper space and move them in to specific layer.

When i have no hatch in model space and paper space gives me a message "no Hatch " (works fine)

The problem is when i have hatch only in model space or only in parer space gives me this message and stop dont work

Quote

Enter an option [?/Make/Set/New/Rename/ON/OFF/Color/Ltype/LWeight/TRansparency/MATerial/Plot/Freeze/Thaw/LOck/Unlock/stAte/Description/rEconcile/Xref]: HATCH
Invalid option keyword.
; error: Function cancelled

the code is

Code - Auto/Visual Lisp: [Select]

    (defun c:DLHATCH (/ sel1 CLAYER )
;Switch from Layout Tab To Model Tab before stating LISP
    (command "_.Tilemode" 1) ; To model space
   (if  (setq sel1 (ssget "X" '((0 . "HATCH")))) ; SELECT ALL HATCH
(progn
    (setq OLDLAYER (getvar "CLAYER")) ;GET CURRENT LAYER
    (COMMAND "_layer" "_m" "HATCH" "_c" "171" "" "_lw" "0.18" "" "") ;CREATE NEW LAYER
    (setvar "CLAYER" OLDLAYER) ; SET ACTIVE LAYER TO PREVIOUS
    (command "CHPROP" sel1 "" ; CHANGE HATCH LAYER TO NEW LAYER
    "LAYER" "HATCH"
    "")
   (command "_.Tilemode" 0) ;And back to last current layout
 
    (setq sel1 (ssget "X" '((0 . "HATCH")))) ; SELECT ALL HATCH
    (setq OLDLAYER (getvar "CLAYER")) ;GET CURRENT LAYER
    (COMMAND "_layer" "_m" "HATCH" "_c" "171" "" "_lw" "0.18" "" "") ;CREATE NEW LAYER
    (setvar "CLAYER" OLDLAYER) ; SET ACTIVE LAYER TO PREVIOUS
    (command "CHPROP" sel1 "" ; CHANGE HATCH LAYER TO NEW LAYER
    "LAYER" "HATCH"
    "")
)
(alert "no Hatch")
)
;(alert "hatch done")
    );END PROGRAM 
 
 

Can any one fix it? Thanks

Tharwat · « **Reply #1 on:** September 01, 2020, 11:13:22 AM »

Here you go.

Code - Auto/Visual Lisp: [Select]

(defun c:test (/ s i e)
  (or (tblsearch "LAYER" "HATCH")
      (command "_layer" "_m" "HATCH" "_c" "171" "" "_lw" "0.18" "" "")
  )
  (if (setq s (ssget "_X" '((0 . "HATCH"))))
    (repeat (setq i (sslength s))
      (setq i (1- i)
            e (entget (ssname s i))
      )
      (entmod (subst '(8 . "HATCH") (assoc 8 e) e))
    )
  )
  (princ)
)
 

PM · « **Reply #2 on:** September 01, 2020, 04:38:24 PM »

Thank you Tharwat

Tharwat · « **Reply #3 on:** September 02, 2020, 02:58:50 AM »

You're welcome anytime.

d2010 · « **Reply #4 on:** September 02, 2020, 04:43:31 AM »

Quote from: Tharwat on September 02, 2020, 02:58:50 AM

You're welcome anytime.

You see here version_pin15.lsp.

Your enter PinCard of Bank insideLisp=3584..

Code - Auto/Visual Lisp: [Select]

(defun dfn_ent_layernew(resetlayer picksetListorStr / $rr mpl tip sos $rr ii elf mli)
   (setq;|a11472|;
         tip (type resetlayer)
         resetlayer (if (>  resetlayer "") (js_pin15 27723 (list  resetlayer T)) nil)) (setq;|a11542|;
         $rr (if (>  picksetListorStr "") (js_pin15 57009 (list  "_X" (list (cons 0 picksetListorStr)))) picksetListorStr)) (if (and  $rr (not (js_pin15 19597 (list  "LAYER" resetlayer)))) (js_pin15 20576 (list  resetlayer 255 1 ""))) (if (and  $rr (js_pin15 19597 (list  "LAYER" resetlayer))) (progn  (progn (setq;|a11724|;
         ii (- (js_pin15 16941 (list  $rr)) 1)) (while (>= ii 0) (setq;|a11770|;
         elf (js_pin15 53906 (list  (ssname $rr ii)))
         mli (js_pin15 19481 (list  (subst (cons 8 resetlayer) (assoc 8 elf) elf)))) (setq;|a11890|;
         ii (- ii 1)))) (js_pin15 24576 (list  "okai")))) (princ) 
$rr)
 

I compile yourRoutine:-> tothree types of VLisp

(_native, _pin15.lsp, _ldc15).You test this programe with (dfn_ent_layernew (setq targeLayer "HATCH") "HATCH")) or Q2[enter]

Code: [Select]

(defun dfn_ent_layernew(resetlayer picksetListorStr / $rr mpl tip sos $rr ii elf mli)
   (setq;|a11476|;
	 tip (type resetlayer)
	 resetlayer (if (>  resetlayer "") (strcase resetlayer T) nil)) (setq;|a11546|;
	 $rr (if (>  picksetListorStr "") (ssget "_X" (list (cons 0 picksetListorStr))) picksetListorStr)) (if (and  $rr (not (tblsearch "LAYER" resetlayer))) (dfn_layer_new resetlayer 255 1 "")) (if (and  $rr (tblsearch "LAYER" resetlayer)) (progn  (progn (setq;|a11728|;
	 ii (- (sslength $rr) 1)) (while (>= ii 0) (setq;|a11774|;
	 elf (entget (ssname $rr ii))
	 mli (entmod (subst (cons 8 resetlayer) (assoc 8 elf) elf))) (setq;|a11894|;
	 ii (- ii 1)))) (alert "okai"))) (princ) 
$rr)

You set "" for random 0layer at CurrentLayer-Destinationa

Code - Text: [Select]

  (setq CLD (Getstring "\nGive me Clear LayerDestination:"))
 

You see the entities on LayerList bellow
"0_mtext202008"
"0_hatch202008*
"0_line201007"
"0_point"
Thankl you

PM · « **Reply #5 on:** September 03, 2020, 10:58:06 AM »

Hi Tharwat i want to ask somethn else. I have 3 layers include polylines an hatches

Code - Auto/Visual Lisp: [Select]

(command "_layer" "_m" "test1" "_c" "103" "" "")
(command "_layer" "_m" "test2" "_c" "90" "" "")
(command "_layer" "_m" "test3" "_c" "10" "" "")
 

is it possible the hatches in this 3 layer to go in 3 othes layers

Code - Auto/Visual Lisp: [Select]

(command "_layer" "_m" "H1" "_c" "103"  "" "_lw" "0.18" "" "")
(command "_layer" "_m" "H2" "_c" "90"  "" "_lw" "0.18" "" "")
(command "_layer" "_m" "H3" "_c" "10" "" "_lw" "0.18" "" "")
 

and all other hatch go to

Code - Auto/Visual Lisp: [Select]

   (command "_layer" "_m" "HATCH" "_c" "171" "" "_lw" "0.18" "" "")
 

Code - Auto/Visual Lisp: [Select]

    (defun c:Test (/ s i e)
   (command "_layer" "_m" "HATCH" "_c" "171" "" "_lw" "0.18" "" "")
  (if (setq s (ssget "_X" '((0 . "HATCH"))))
    (repeat (setq i (sslength s))
      (setq i (1- i)
            e (entget (ssname s i))
      )
      (entmod (subst '(8 . "HATCH") (assoc 8 e) e))
    )
  )
  (princ)
)
 
 

Thanks

Tharwat · « **Reply #6 on:** September 03, 2020, 11:03:50 AM »

Hi PM,

Sorry i did not get your point so can you elaborate your idea a bit more?

PM · « **Reply #7 on:** September 03, 2020, 01:27:24 PM »

I have 3 spesific layers with polyline and hatch :

Code - Auto/Visual Lisp: [Select]

(command "_layer" "_m" "test1" "_c" "103" "" "")
(command "_layer" "_m" "test2" "_c" "90" "" "")
(command "_layer" "_m" "test3" "_c" "10" "" "")
 

I want the hatch from this 3 layers to go to this layers

Code - Auto/Visual Lisp: [Select]

    (command "_layer" "_m" "H1" "_c" "103"  "" "_lw" "0.18" "" "")
    (command "_layer" "_m" "H2" "_c" "90"  "" "_lw" "0.18" "" "")
    (command "_layer" "_m" "H3" "_c" "10" "" "_lw" "0.18" "" "")
     
 

All the other hach in the drawing i want to go to this layer

Code - Auto/Visual Lisp: [Select]

(command "_layer" "_m" "HATCH" "_c" "171" "" "_lw" "0.18" "" "")
 

is this possible ?

thanks

Tharwat · « **Reply #8 on:** September 03, 2020, 01:48:55 PM »

Something like this?

Code - Auto/Visual Lisp: [Select]

(defun c:test (/ s i e y)
  (if (setq s (ssget "_X" (list '(0 . "HATCH"))))
    (repeat (setq i (sslength s))
      (setq i (1- i)
            e (entget (ssname s i))
            y (assoc (cdr (assoc 8 e))
                     '(("test1" "H1") ("test2" "H2") ("test3" "H3"))
              )
      )
      (entmod (subst (cons 8
                           (if y
                             (cadr y)
                             "HATCH"
                           )
                     )
                     (assoc 8 e)
                     e
              )
      )
    )
  )
  (princ)
)
 

PM · « **Reply #9 on:** September 03, 2020, 04:47:21 PM »

Yes but i need to create this layers if does not exist

Code - Auto/Visual Lisp: [Select]

    (command "_layer" "_m" "H1" "_c" "103"  "" "_lw" "0.18" "" "")
    (command "_layer" "_m" "H2" "_c" "90"  "" "_lw" "0.18" "" "")
    (command "_layer" "_m" "H3" "_c" "10" "" "_lw" "0.18" "" "")
     
 

Tharwat · « **Reply #10 on:** September 03, 2020, 04:52:28 PM »

You can just add them in the program at the top and that's enough although the program would create them if they are not existed but with default values.

PM · « **Reply #11 on:** September 03, 2020, 05:00:51 PM »

Yes but if i will write it like this will create this 3 layes every time .But some times i will not need 3 layers i will need 1 or 2 of them? Is any way to filter and create the layer if it is necessary ?

Code - Auto/Visual Lisp: [Select]

    (defun c:test (/ s i e y)
 (command "_layer" "_m" "H1" "_c" "103"  "" "_lw" "0.18" "" "")
    (command "_layer" "_m" "H2" "_c" "90"  "" "_lw" "0.18" "" "")
    (command "_layer" "_m" "H3" "_c" "10" "" "_lw" "0.18" "" "")
 (command "_layer" "_m" "HATCH" "_c" "171" "" "_lw" "0.18" "" "")
      (if (setq s (ssget "_X" (list '(0 . "HATCH"))))
        (repeat (setq i (sslength s))
          (setq i (1- i)
                e (entget (ssname s i))
                y (assoc (cdr (assoc 8 e))
                         '(("test1" "H1") ("test2" "H2") ("test3" "H3"))
                  )
          )
          (entmod (subst (cons 8
                               (if y
                                 (cadr y)
                                 "HATCH"
                               )
                         )
                         (assoc 8 e)
                         e
                  )
          )
        )
      )
      (princ)
    )
     
 
 

Thanks

PM · « **Reply #12 on:** September 03, 2020, 05:11:35 PM »

~~i find that the code dont work well.Create the layers but all the hach go to layer~~

my mistake. I write the names of layers wrong. But creates Unnecessary layers like i said in the previous post

Tharwat · « **Reply #13 on:** September 03, 2020, 05:12:45 PM »

Code - Auto/Visual Lisp: [Select]

(defun c:test (/ s i e y l)
  (if (setq s (ssget "_X" (list '(0 . "HATCH"))))
    (repeat (setq i (sslength s))
      (setq i (1- i)
            e (entget (ssname s i))
            y (assoc (cdr (assoc 8 e))
                     '(("test1" "H1" 103)
                       ("test2" "H2" 90 0.18)
                       ("test3" "H3" 10)
                      )
              )
      )
      (and y
           (or (tblsearch "LAYER" (setq l (cadr y)))
               (Layer_ l (caddr y))
           )
      )
      (entmod (subst (cons 8
                           (if y
                             l
                             "HATCH"
                           )
                     )
                     (assoc 8 e)
                     e
              )
      )
    )
  )
  (princ)
)
(defun Layer_ (lay clr)
  (entmake (list '(0 . "LAYER")
                 '(100 . "AcDbSymbolTableRecord")
                 '(100 . "AcDbLayerTableRecord")
                 (cons 2 lay)
                 (cons 62 clr)
                 '(370 . 18)
                 '(70 . 0)
           )
  )
)

PM · « **Reply #14 on:** September 03, 2020, 05:27:10 PM »

the code works but the HATCH layer is not

Code - Auto/Visual Lisp: [Select]

 (command "_layer" "_m" "HATCH" "_c" "171" "" "_lw" "0.18" "" "")
 

Tharwat · « **Reply #15 on:** September 03, 2020, 05:30:44 PM »

Quote from: PM on September 03, 2020, 05:27:10 PM

the code works but the HATCH layer is not
Code - Auto/Visual Lisp: [Select]
(command "_layer" "_m" "HATCH" "_c" "171" "" "_lw" "0.18" "" "")

Yes, because the codes for this layer name was added into the first posted codes but anyway here you go.

Code - Auto/Visual Lisp: [Select]

(defun c:test (/ s i e y l)
  (or (tblsearch "LAYER" "HATCH")
      (Layer_ "HATCH" 171)
  )
  (if (setq s (ssget "_X" (list '(0 . "HATCH"))))
    (repeat (setq i (sslength s))
      (setq i (1- i)
            e (entget (ssname s i))
            y (assoc (cdr (assoc 8 e))
                     '(("test1" "H1" 103)
                       ("test2" "H2" 90 0.18)
                       ("test3" "H3" 10)
                      )
              )
      )
      (and y
           (or (tblsearch "LAYER" (setq l (cadr y)))
               (Layer_ l (caddr y))
           )
      )
      (entmod (subst (cons 8
                           (if y
                             l
                             "HATCH"
                           )
                     )
                     (assoc 8 e)
                     e
              )
      )
    )
  )
  (princ)
)
(defun Layer_ (lay clr)
  (entmake (list '(0 . "LAYER")
                 '(100 . "AcDbSymbolTableRecord")
                 '(100 . "AcDbLayerTableRecord")
                 (cons 2 lay)
                 (cons 62 clr)
                 '(370 . 18)
                 '(70 . 0)
           )
  )
)
 

PM · « **Reply #16 on:** September 03, 2020, 06:01:03 PM »

Ok now work.

Thanks Tharwat

PM · « **Reply #17 on:** September 04, 2020, 01:59:55 AM »

Ηι Tharwat. I want to ask something else about layers thats way i didnt change post.

I am using a simple command for purge ,audit and overkill. The problem is i have sone spesific layers with close polylines the most of the times are overlap and i want them. If i use the overkill command i loose parts of them

If i wright the code like bellow the code search to find the same time in the drawing all this layers TEST1,TEST2,TEST3,TEST4,TEST5,TEST6.

I want not to find all of them just one of them (TEST1 or TEST2 or TEST3 or TEST4 or TEST5 or TEST6), because in the drawing i will have one or two or thee of them etc.

The question is how to filter if find one or more of this 6 layers then

(COMMAND "-PURGE" "A" "*" "N" "_AUDIT" "Y" "" "")

unless

(COMMAND "-PURGE" "A" "*" "N" "_AUDIT" "Y" "-overkill" "all" "" "")

Code - Auto/Visual Lisp: [Select]

(defun c:test () 
 
(if (not (tblsearch "LAYER" "TEST1" "TEST2" "TEST3" "TEST4" "TEST5" "TEST6"))
(COMMAND "-PURGE" "A" "*" "N"  "_AUDIT" "Y" "-overkill" "all" "" ""))
(or 
 (COMMAND "-PURGE" "A" "*" "N"  "_AUDIT" "Y" "" "")
)
(princ)
)
 
 

Dlanor · « **Reply #18 on:** September 04, 2020, 07:03:46 AM »

IIRC you can't select anything on locked layers in the overkill command, therefore if you lock the layers you don't want altering overkill shouldn't touch them.

PM · « **Reply #19 on:** September 04, 2020, 07:12:54 AM »

hi Dianor .I want to learn how i can do this

Code - Auto/Visual Lisp: [Select]

want not to find all of them just one of them (TEST1 or TEST2 or TEST3 or TEST4 or TEST5 or TEST6)
 

it will be usefull .

Quote

IIRC you can't select anything on locked layers in the overkill command, therefore if you lock the layers you don't want altering overkill shouldn't touch them.

What is IIRC, there is no IIRC command in Autocad 2020

Thanks

PM · « **Reply #20 on:** September 04, 2020, 07:35:47 AM »

Code - Auto/Visual Lisp: [Select]

(if (not (tblsearch "LAYER" "test1" "test2"))
 

I try again this and now work . But if i do this not working.

Code - Auto/Visual Lisp: [Select]

(if (not (tblsearch "LAYER" "test1" "test2" "test3"))
 

I dont know. Please help

Thanks

Tharwat · « **Reply #21 on:** September 04, 2020, 08:08:01 AM »

You can't check if many layer names are existed in a drawing at the same time with tblsearch function so you can check only once per one, but if you want to check for a list of layer names then you can use any of the iteration functions like, foreach, mapcar .. etc.

eg:

Code - Auto/Visual Lisp: [Select]

(foreach lay '("test1"  "test2"  "test3")
  (if (tblsearch "LAYER" lay) ;; variable 'lay' represents the layer name in the above list. eg: "test1" then next, next ... 
     ;; do your stuff here if layer found ....
   )
)

Just go back to any of my posted codes in this thread for more info.

Dlanor · « **Reply #22 on:** September 04, 2020, 08:30:29 AM »

Quote from: PM on September 04, 2020, 07:12:54 AM

What is IIRC, there is no IIRC command in Autocad 2020
Thanks

It's not a command. It is an abbreviated form of the phrase "If I Recall Correctly" Like "LOL" = Lots Of Laughs

PM · « **Reply #23 on:** September 04, 2020, 09:42:18 AM »

Hi Tharwat ,can you show me an example ?

JohnK · « **Reply #24 on:** September 04, 2020, 09:55:13 AM »

Jumping in the middle of the conversation...

You can always do something like the following:

Code - Auto/Visual Lisp: [Select]

(defun Layer-p (l)
  ;; return boole for layer existence
   (and (tblsearch "LAYER" l)) )
 
(mapcar '(lambda ( x ) (Layer-p x)) '("test1"  "test2"  "test3"))

PM · « **Reply #25 on:** September 04, 2020, 10:11:05 AM »

I try this but

Quote

; error: bad argument type: stringp nil

Code - Auto/Visual Lisp: [Select]

(defun c:test () 
(if (not (tblsearch "LAYER" l))
(mapcar '(lambda ( x ) (Layer-p x)) '("test1"  "test2"  "test3"))
(COMMAND "-PURGE" "A" "*" "N"  "_AUDIT" "Y" "-overkill" "all" "" "")
)
(or 
(COMMAND "-PURGE" "A" "*" "N"  "_AUDIT" "Y" "" "")
    )
 (princ)
   )     
 

JohnK · « **Reply #26 on:** September 04, 2020, 10:15:44 AM »

You get that error because there is very little correct about the code you have. I will read the thread and see if I can help.

Quote from: PM on September 04, 2020, 10:11:05 AM

I try this but

Quote
; error: bad argument type: stringp nil

Code - Auto/Visual Lisp: [Select]
(defun c:test ()
(if (not (tblsearch "LAYER" l))
(mapcar '(lambda ( x ) (Layer-p x)) '("test1" "test2" "test3"))
(COMMAND "-PURGE" "A" "*" "N" "_AUDIT" "Y" "-overkill" "all" "" "")
)
(or
(COMMAND "-PURGE" "A" "*" "N" "_AUDIT" "Y" "" "")
)
(princ)
)

PM · « **Reply #27 on:** September 04, 2020, 10:31:42 AM »

JohnK · « **Reply #28 on:** September 04, 2020, 10:50:13 AM »

So if I understand you would like to run either one operation if one of those layers is found in the drawing and another operation if not. Correct?

You can run the layer check, build a list of the results, and check those results for for a true value. If one of the test come back true then you can run an operation otherwise run another.

Building a list of results and checking that list--vs iterating and checking as you go--is more efficient in times that you find yourself crunching a lot of data (like points, blocks, etc) so it is a good habit to get into.

Code - Auto/Visual Lisp: [Select]

(defun Layer-p (l)
  ;; return boole for layer existence
   (and (tblsearch "LAYER" l)) )
 
(if (member 't 
        (mapcar 
                '(lambda ( x ) (Layer-p x)) 
                '("test1"  "test2"  "test3")))
 (COMMAND "-PURGE" "A" "*" "N"  "_AUDIT" "Y" "" "")
 (COMMAND "-PURGE" "A" "*" "N"  "_AUDIT" "Y" "-overkill" "all" "" "")
)

And you can restructure the code if this is a bit more readable for you.

Code - Auto/Visual Lisp: [Select]

(defun Layer-p (l)
  ;; return boole for layer existence
   (and (tblsearch "LAYER" l)) )
 
(setq results (mapcar 
                '(lambda ( x ) (Layer-p x)) 
                '("test1"  "test2"  "test3"))
 
(if (member 't results)
 (COMMAND "-PURGE" "A" "*" "N"  "_AUDIT" "Y" "" "")
 (COMMAND "-PURGE" "A" "*" "N"  "_AUDIT" "Y" "-overkill" "all" "" "")
)

And you would build a function of all of that like this:

Code - Auto/Visual Lisp: [Select]

(defun c:test ( / Layer-p results )
        (defun Layer-p (l)
         ;; return boole for layer existence
         (and (tblsearch "LAYER" l)) )
 
   (setq results (mapcar 
                  '(lambda ( x ) (Layer-p x)) 
                  '("test1"  "test2"  "test3")))
 
   (if (member 't results)
    (COMMAND "-PURGE" "A" "*" "N"  "_AUDIT" "Y" "" "")
    (COMMAND "-PURGE" "A" "*" "N"  "_AUDIT" "Y" "-overkill" "all" "" "")
   )
)
 

PM · « **Reply #29 on:** September 04, 2020, 11:43:57 AM »

thank you John Kaul (Se7en). i think i understand the code .I add some comments ,if i am wrong correct me

Code - Auto/Visual Lisp: [Select]

(defun c:test ( / Layer-p results )
        (defun Layer-p (l)
         ;; return boole for layer existence
         (and (tblsearch "LAYER" l)) )
 
   (setq results (mapcar 
                  '(lambda ( x ) (Layer-p x)) 
                  '("test1"  "test2"  "test3"))) ; here search for existing layers
 
   (if (member 't results)
    (COMMAND "-PURGE" "A" "*" "N"  "_AUDIT" "Y" "" "") ; if find  one or some  of them execute this command
    (COMMAND "-PURGE" "A" "*" "N"  "_AUDIT" "Y" "-overkill" "all" "" "") ; unless execute this command
   )
)
 
 

JohnK · « **Reply #30 on:** September 04, 2020, 11:49:57 AM »

You are correct.

No problem. Glad I could help.

News:

Author Topic: Help with find hatch lisp (Read 4688 times)

PM

PM

PM

PM

PM

PM

PM

PM

PM

PM

PM

PM

PM

PM

PM

PM