Topic: Error in vlax-3d-point

[@_Bilal]

Hello,

Could some one help me to fix this error or explain to me why I get this error
"Error: Automation Error. UCS X axis and Y axis are not perpendicular" when
runing the below routine, noting that the the 2 segments are perpendicular.

Code - Auto/Visual Lisp: [Select]

1. (defun ucsadd (ORg Xpt Ypt NAME / acaddoc_obj ucs_obj item)
2.   (vl-load-com)
3.  
4.  
5. ;; V^V
6. ;; Cross product of two vectors
7. (defun v^v (u v)
8.   (list (- (* (cadr u) (caddr v)) (* (caddr u) (cadr v)))
9.         (- (* (caddr u) (car v)) (* (car u) (caddr v)))
10.         (- (* (car u) (cadr v)) (* (cadr u) (car v)))
11.   )
12. );; Endof//v^v
13.  
14.  
15.  
16. ;; Calculate the yptp which is perpendicular to segment Org and Xpt
17. ;; u and v vectors
18.   (setq u (list (- (car Xpt) (car ORg)) (- (cadr Xpt) (cadr ORg)) (- (caddr Xpt) (caddr ORg))))
19.   (setq v (list (- (car Ypt) (car ORg)) (- (cadr Ypt) (cadr ORg)) (- (caddr Ypt) (caddr ORg))))
20.   (setq z (v^v u v));; calculate z vector
21.   (setq Yptp (v^v z u))
22.  
23.  
24. ;;;Start adding UCS
25.   (setq acaddoc_obj (vla-get-activedocument (vlax-get-acad-object)))
26.   (setq ucs_obj (vla-get-UserCoordinateSystems acaddoc_obj))
27.   (setq item (vla-add ucs_obj
28.                 (vlax-3d-point org) ;;origin
29.                 (vlax-3d-point Xpt) ;;x axis point
30.                 (vlax-3d-point Yptp) ;;y axis point
31.                 name;;name
32.              ) ;_ end of vla-add
33.   ) ;_ end of setq
34.   (princ)
35. );; Endof//ucsadd

[Stefan]

Xpt is in WCS and Yptp is relative to origin.
Change this line

Code: [Select]

(setq Yptp (mapcar '+ org (v^v z u)))

[ribarm]

Try changing this line :

Code - Auto/Visual Lisp: [Select]

1. (setq Yptp (v^v z u))
2.  

To this :

Code - Auto/Visual Lisp: [Select]

1. (setq Yptp (mapcar '+ ORg (v^v z u)))
2.  

Note that your Yptp in your code is vector, and you need point at position of ORg + vector...

[@_Bilal]

Thank you very much Ribarm and Stefan

I changed this line, the routine and i get accurate result
I understand where was my fault
thanks again