Topic: Adding Rotation Command

[MSTG007]

How hard is it to create a command for rotation like the fillet command?

The routine originally started from the fillet command.

Code: [Select]

(   (lambda nil
        (foreach rad '(0.5 1 1.5 2 2.5 3 3.5 4 4.5 5 5.5 6 6.5 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 40 50 60 70 80 90 100 200 300 400 500)
           (eval
              (list 'defun
                   (read (strcat "c:r" (vl-string-translate "." "-" (vl-princ-to-string rad))))
                  '( / fil )
                   '(setq fil (getvar 'rotaterad))
                    (list 'setvar ''rotaterad rad)
                  '(vl-cmdf "_.rotate")
                  '(while (< 0 (getvar 'cmdactive)) (vl-cmdf "\\"))
                 '(setvar 'rotaterad fil)
                  '(princ)
               )
           )
        )
     (princ)
   )
)

[roy_043]

Code - Auto/Visual Lisp: [Select]

1. (defun MyRotate (ang / *error* doc pt ss)
2.  
3.   (defun *error* (msg)
4.     (setvar 'cmdecho 1)
5.     (vla-endundomark doc)
6.   )
7.  
8.   (setq doc (vla-get-activedocument (vlax-get-acad-object)))
9.   (vla-endundomark doc)
10.   (vla-startundomark doc)
11.   (setvar 'cmdecho 0)
12.   (if                               ; Can be replaced with while.
13.     (and
14.       (setq ss (ssget))
15.       (setq pt (getpoint "\nRotation point: "))
16.     )
17.     (vl-cmdf "_.rotate" ss "" "_non" pt ang)
18.   )
19.   (setvar 'cmdecho 1)
20.   (vla-endundomark doc)
21.   (princ)
22. )
23.  
24. (foreach ang '(10 12 15 22.5 30 45 90 180)
25.   (eval
26.     (read
27.       (strcat
28.         "(defun c:r" (vl-string-translate "." "-" (vl-princ-to-string ang)) " () "
29.         "(MyRotate " (vl-princ-to-string ang) "))"
30.       )
31.     )
32.   )
33. )
34. (princ)

[MSTG007]

Hey thank you for taking a stab at this! Works great.

[Grrr1337]

Nice one Roy!
after you figured out the correct command-call and the code MSTG007 posted (author??), heres my attempt to modify the original code:

Code - Auto/Visual Lisp: [Select]

1. (  
2.   (lambda ( L )
3.     (foreach ang L
4.       (eval
5.         (list 'defun (read (strcat "c:r" (vl-string-translate "." "-" (vl-princ-to-string ang)))) '( / ss pt )
6.           (list
7.             'while  ; Can be replaced with if.
8.             '(and
9.               (setq ss (ssget))
10.               (setq pt (getpoint "\nRotation point: "))
11.             )
12.             (list 'vl-cmdf "_.rotate" 'ss "" "_non" 'pt (vl-prin1-to-string ang))
13.           )
14.           '(princ)
15.         )
16.       )
17.     )
18.     (princ)
19.   )
20.   '(10 12 15 22.5 30 45 90 180)
21. )
22.  

[MSTG007]

Now I see...

The original Author was Mr. LeeMac..https://www.theswamp.org/index.php?topic=49798.0

He makes things seem simple. lol