Topic: Rename Layout Tab to include dwg size

[KimbleC]

New user and first time poster.

So far, and with many thanks I have used a routine that was found https://www.theswamp.org/index.php?topic=1466.0.

I have a minor problem in so far as I wish to add the drawing size to the Tab name.
We have several drawings....some with an A3 border/title block and others with an A1 border/title block.
Each drawing has either A3 or A1 but not both inserted in the paperspace layout tab.
In our case these blocks either start with A3_xxxx or A1_xxxx.

So is there an easy way to check for the name of the XX_title.dwg or XX_Border.dwg and add this XX information to layout  tab name.

I hope that this all makes sense.

Regards
Kim Williams

[roy_043]

Welcome to the Swamp!

Try:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun KGA_Conv_Collection_To_List (coll / ret)
4.   (reverse
5.     (vlax-for a coll
6.       (setq ret (cons a ret))
7.     )
8.   )
9. )
10.  
11. (defun KGA_Sys_Apply (expr varLst / ret)
12.   (if (not (vl-catch-all-error-p (setq ret (vl-catch-all-apply expr varLst))))
13.     ret
14.   )
15. )
16.  
17. ; Returns name of first block reference in block definition defObj that matches nmePat.
18. ; (FindRefInDef (vla-get-block (vla-item (vla-get-layouts (vla-get-activedocument (vlax-get-acad-object))) "Layout1")) "A3_*,A1_*") => "A3_Test"
19. (defun FindRefInDef (defObj nmePat)
20.   (vl-some
21.     '(lambda (obj / nme)
22.       (if
23.         (and
24.           (= "AcDbBlockReference" (vla-get-objectname obj))
25.           (wcmatch
26.             (strcase
27.               (setq nme
28.                 (
29.                   (if (vlax-property-available-p obj 'effectivename)
30.                     vla-get-effectivename
31.                     vla-get-name
32.                   )
33.                   obj
34.                 )
35.               )
36.             )
37.             (strcase nmePat)
38.           )
39.         )
40.         nme
41.       )
42.     )
43.     (KGA_Conv_Collection_To_List defObj)
44.   )
45. )
46.  
47. (defun c:Test ( / doc fnd)
48.   (setq doc (vla-get-activedocument (vlax-get-acad-object)))
49.   (vla-endundomark doc)
50.   (vla-startundomark doc)
51.   (vlax-for lyt (vla-get-layouts doc)
52.     (if
53.       (and
54.         (= :vlax-false (vla-get-modeltype lyt))
55.         (not (wcmatch (vla-get-name lyt) "* A3,* A1"))
56.         (setq fnd (FindRefInDef (vla-get-block lyt) "A3_*,A1_*"))
57.       )
58.       (KGA_Sys_Apply
59.         'vla-put-name
60.         (list lyt (strcat (vla-get-name lyt) " " (substr fnd 1 2)))
61.       )
62.     )
63.   )
64.   (vla-endundomark doc)
65.   (princ)
66. )

EDIT: Added (vl-load-com).

[ronjonp]

Another for fun. Welcome to TheSwamp!

Code - Auto/Visual Lisp: [Select]

1. (defun c:foo (/ a s sz tb)
2.   (if (setq s (ssget "_x" '((0 . "insert") (2 . "A#_*") (410 . "~Model"))))
3.     (foreach b (mapcar 'cadr (ssnamex s))
4.       (setq a  (cdr (assoc 330 (entget b)))
5.             a  (cdr (assoc 340 (entget a)))
6.             a  (vlax-ename->vla-object a)
7.             tb (cdr (assoc 410 (entget b)))
8.             sz (substr (cdr (assoc 2 (entget b))) 1 2)
9.       )
10.       (and (not (wcmatch tb "*_A#*")) (vla-put-name a (strcat tb "_" sz)))
11.     )
12.   )
13.   (princ)
14. )
15. (vl-load-com)

[Lee Mac]

Nice Ron 

[ronjonp]

Nice Ron 

Cheers Lee 😁

[KimbleC]

Thanks Roy_043.....works well.
ronjonp I like your one better as it is much simpler.
But........
How do I change the order so that Tab reads A#_Layoutx.
I tried to experiment around with line 10 but ended  with extra A# still at the end not the beginning of the string.
I hope to add this one the Ron has come up with to  the one that CAB has
https://www.theswamp.org/index.php?topic=1466.0.

Thanks in advance
Kim

ps......this looks like it works
(and (not (wcmatch tb "*A#_*")) (vla-put-name a (strcat sz "_" tb)))

[roy_043]

OK FWIW then :

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun KGA_Conv_Collection_To_List (coll / ret)
4.   (reverse
5.     (vlax-for a coll
6.       (setq ret (cons a ret))
7.     )
8.   )
9. )
10.  
11. ; Returns name of first block reference in block definition defObj that matches nmePat.
12. ; (FindRefInDef (vla-get-block (vla-item (vla-get-layouts (vla-get-activedocument (vlax-get-acad-object))) "Layout1")) "A3_*,A1_*") => "A3_Test"
13. (defun FindRefInDef (defObj nmePat)
14.   (vl-some
15.     '(lambda (obj / nme)
16.       (if
17.         (and
18.           (= "AcDbBlockReference" (vla-get-objectname obj))
19.           (wcmatch
20.             (strcase
21.               (setq nme
22.                 (
23.                   (if (vlax-property-available-p obj 'effectivename)
24.                     vla-get-effectivename
25.                     vla-get-name
26.                   )
27.                   obj
28.                 )
29.               )
30.             )
31.             (strcase nmePat)
32.           )
33.         )
34.         nme
35.       )
36.     )
37.     (KGA_Conv_Collection_To_List defObj)
38.   )
39. )
40.  
41. (defun c:Test ( / doc fnd str)
42.   (setq doc (vla-get-activedocument (vlax-get-acad-object)))
43.   (vla-endundomark doc)
44.   (vla-startundomark doc)
45.   (setq str "Layout")
46.   ;; Make sure the string is unique to avoid name clashes:
47.   (while
48.     (vl-some
49.       '(lambda (nme) (wcmatch (strcase nme) (strcase (strcat "*" str "*"))))
50.       (layoutlist)
51.     )
52.     (setq str (strcat str "X"))
53.   )
54.   (vlax-for lyt (vla-get-layouts doc)
55.     (if (= :vlax-false (vla-get-modeltype lyt))
56.       (vla-put-name
57.         lyt
58.         (strcat
59.           (if (setq fnd (FindRefInDef (vla-get-block lyt) "A#_*"))
60.             (strcat (substr fnd 1 2) "_")
61.             ""
62.           )
63.           str
64.           (itoa (vla-get-taborder lyt))
65.         )
66.       )
67.     )
68.   )
69.   ;; Substitute the string if required:
70.   (if (/= str "Layout")
71.     (vlax-for lyt (vla-get-layouts doc)
72.       (if (= :vlax-false (vla-get-modeltype lyt))
73.         (vla-put-name
74.           lyt
75.           (vl-string-subst "Layout" str (vla-get-name lyt))
76.         )
77.       )
78.     )
79.   )
80.   (vla-endundomark doc)
81.   (princ)
82. )

EDIT: Changed the name format from "Layout1_A3" to "A3_Layout1".

[ronjonp]

...

ps......this looks like it works
(and (not (wcmatch tb "*A#_*")) (vla-put-name a (strcat sz "_" tb)))

That's the ticket .. you could also remove the first asterisk in red.

[KimbleC]

Thanks to all   
So this is what it now looks like.......

;; CREDIT https://www.theswamp.org/index.php?topic=1466.0
;; This routine will rename all layout tabs in all open drawings
;;  to "Layoutx" where x = the tab count
(defun c:re-name-all-layouts (/ Tab_name doc x cnt)
  (vl-load-com)
  (setq Tab_name "Layout")
  (vlax-for doc (vla-get-documents (vlax-get-acad-object))
    (setq cnt 0)
    (vlax-for x (vla-get-layouts doc)
      (if (not (= (vla-get-name x) "Model"))
        (vla-put-name x
          (strcat Tab_name (itoa (setq cnt (1+ cnt))))
        )
      )
    )
  )
)

;; CREDIT https://www.theswamp.org/index.php?topic=53447.new#new

(defun c:foo (/ a s sz tb)
      (if (setq s (ssget "_x" '((0 . "insert") (2 . "A#_*") (410 . "~Model"))))
        (foreach b (mapcar 'cadr (ssnamex s))
          (setq a  (cdr (assoc 330 (entget b)))
           a  (cdr (assoc 340 (entget a)))
           a  (vlax-ename->vla-object a)
           tb (cdr (assoc 410 (entget b)))
           sz (substr (cdr (assoc 2 (entget b))) 1 2)
          )
          (and (not (wcmatch tb "A#_*")) (vla-put-name a (strcat sz "_" tb)))
        )
      )
      (princ)
    )
    (vl-load-com)


(defun C:LayTab ()
   (C:re-name-all-layouts)
   (c:foo)

)
(princ "\n\tre-name-all-layouts Loaded...........................Start command with LayTab.")
(princ)
(princ)

[ronjonp]

Nice job putting them together .. I''l have some time in the morning to consolidate them for you. Have a nice eve.

[Lee Mac]

Sorry Ron - I couldn't resist the urge to LISP 

Code - Auto/Visual Lisp: [Select]

1. (defun c:laytab ( / i n o s x )
2.     (if (setq s (ssget "_x" '((0 . "insert") (2 . "A#_*") (410 . "~Model"))))
3.         (repeat (setq i (sslength s))
4.             (or (wcmatch (setq n (cdr (assoc 410 (setq x (entget (ssname s (setq i (1- i)))))))) "A#_*")
5.                 (vla-put-name
6.                     (setq o (vlax-ename->vla-object (cdr (assoc 340 (entget (cdr (assoc 330 x)))))))
7.                     (strcat (substr (cdr (assoc 2 x)) 1 2) "_" n (itoa (vla-get-taborder o)))
8.                 )
9.             )
10.         )
11.     )
12.     (princ)
13. )
14. (vl-load-com)

[ronjonp]

Sorry Ron - I couldn't resist the urge to LISP 

Code - Auto/Visual Lisp: [Select]

1. (defun c:laytab ( / i n o s x )
2.     (if (setq s (ssget "_x" '((0 . "insert") (2 . "A#_*") (410 . "~Model"))))
3.         (repeat (setq i (sslength s))
4.             (or (wcmatch (setq n (cdr (assoc 410 (setq x (entget (ssname s (setq i (1- i)))))))) "A#_*")
5.                 (vla-put-name
6.                     (setq o (vlax-ename->vla-object (cdr (assoc 340 (entget (cdr (assoc 330 x)))))))
7.                     (strcat (substr (cdr (assoc 2 x)) 1 2) "_" n (itoa (vla-get-taborder o)))
8.                 )
9.             )
10.        )
11.     )
12.     (princ)
13. )
14. (vl-load-com)

No worries .. it is a disease you know. 


Here's mine:

Code - Auto/Visual Lisp: [Select]

1. (defun c:foo (/ a s sz tb to)
2.   (if (setq s (ssget "_x" '((0 . "insert") (2 . "A#_*") (410 . "~Model"))))
3.     (foreach b (mapcar 'cadr (ssnamex s))
4.       (setq a  (cdr (assoc 330 (entget b)))
5.             a  (cdr (assoc 340 (entget a)))
6.             to (cdr (assoc 71 (entget a)))
7.             a  (vlax-ename->vla-object a)
8.             tb (cdr (assoc 410 (entget b)))
9.             sz (substr (cdr (assoc 2 (entget b))) 1 2)
10.       )
11.       (and (not (wcmatch tb "A#_*")) (vla-put-name a (strcat sz "_Layout" (itoa to))))
12.     )
13.   )
14.   (princ)
15. )
16. (vl-load-com)