Topic: retrieve the names of Civil-corridors from database

[Peter2]

The question is 95% the same as here:
retrieve the names of Civil-surfaces from database
https://www.theswamp.org/index.php?topic=53271.0

It seems that the way to get the corridors (as object) is the third way (beside getting alignments and getting surfaces). So -

How to get the corridors (plus names) via Lisp?

Have a fine evening!

[Jeff_M]

You need to use the RoadwayApplication...

Code - Auto/Visual Lisp: [Select]

1. (defun getRoadApp (/ *acad* C3D)
2.   (vl-load-com)
3.   (if (and (setq *acad* (vlax-get-acad-object))
4.            (setq C3D (strcat "HKEY_LOCAL_MACHINE\\"
5.                              (if vlax-user-product-key
6.                                (vlax-user-product-key)
7.                                (vlax-product-key)
8.                              )
9.                      )
10.                  C3D (vl-registry-read C3D "Release")
11.                  C3D (substr
12.                        C3D
13.                        1
14.                        (vl-string-search
15.                          "."
16.                          C3D
17.                          (+ (vl-string-search "." C3D) 1)
18.                        )
19.                      )
20.                  C3D (vla-getinterfaceobject
21.                        (vlax-get-acad-object)
22.                        (strcat "AeccXUiRoadway.AeccRoadwayApplication." C3D)
23.                      )
24.            )
25.       )
26.     C3D
27.   )
28. )
29.  
30. (setq roadapp (getRoadapp)
31.       Roaddoc (vlax-get roadapp 'activedocument)
32.       corridors (vlax-get Roaddoc 'Corridors))
33.  
34. (vlax-for c corridors
35.   (setq names (cons (vlax-get c 'name) names))
36.   )
37.  

[Peter2]

Great. Thanks a lot! 

Edit:
I browsed through this documents:
http://docs.autodesk.com/CIV3D/2018/ENU/API_Reference_Guide/html/e7b1fa34-671e-acd5-7f56-5f97d04c1494.htm

Am I too blind to find the information which Application (Roadway, Land, Pipe, ..) has to be used?

[Jeff_M]

This is what I use to get the desired application:

Code - Auto/Visual Lisp: [Select]

1. (defun getaeccApp (module / *acad* C3D) ;; module must be "Land", "Pipe", "Roadway", or "Survey"
2.   (vl-load-com)
3.   (if (and (setq *acad* (vlax-get-acad-object))
4.            (setq C3D (strcat "HKEY_LOCAL_MACHINE\\"
5.                              (if vlax-user-product-key
6.                                (vlax-user-product-key)
7.                                (vlax-product-key)
8.                              )
9.                      )
10.                  C3D (vl-registry-read C3D "Release")
11.                  C3D (substr
12.                        C3D
13.                        1
14.                        (vl-string-search
15.                          "."
16.                          C3D
17.                          (+ (vl-string-search "." C3D) 1)
18.                        )
19.                      )
20.                  C3D (vla-getinterfaceobject
21.                        (vlax-get-acad-object)
22.                        (strcat "AeccXUi" module ".Aecc" (if (= (strcase module) "LAND") "" module) "Application." C3D)
23.                      )
24.            )
25.       )
26.     C3D
27.   )
28. )
29.  

Corridors are in the Roadway application.