Topic: How To Update Text Style Table for Bigfontfile?

[Hrishikesh]

Hi All,
I have set of Erection drawing which has 17 text styles are used of which 10 are with Bigfont styles,
dimensions, text, with these style are not visible.
I removed Bigfont option manually from text style editor.
But there are bunch of Erection drawing so I tried to remove Bigfont file by lisp, But something is wrong in my code so its not working.
Need help on this code.

Thanks,
Hrishikesh

Code - Auto/Visual Lisp: [Select]

1. (defun C:TxtStUp ()
2. (setq doc (vla-get-activedocument (vlax-get-acad-object)))
3. (vlx-for txtst (vla-get-textstyles doc)
4. (setq StName (vla-get-name txtst))
5. (vla-put-Bigfontfile StName "")
6. )
7.  

[roy_043]

Typo: vlx-for should be vlax-for.

[Hrishikesh]

Is it possible to use tblnext and and change assoc code (4 . "bigfont.shx") to (4 . "").

[roy_043]

Is it possible to use tblnext and and change assoc code (4 . "bigfont.shx") to (4 . "").

No. The output of tblnext does not contain a reference to the ename. If you want to perform this task using 'Classic' Lisp you will need to (also) use tblobjname.

To get a usable entity list for the first text style this will work:

Code: [Select]

(entget (tblobjname "style" (cdr (assoc 2 (tblnext "style" T)))))

[Hrishikesh]

If you want to perform this task using 'Classic' Lisp you will need to (also) use tblobjname.

To get a usable entity list for the first text style this will work:

Code: [Select]

(entget (tblobjname "style" (cdr (assoc 2 (tblnext "style" T)))))

Thanks Roy,
As you said I used tblobjname and it works.

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun C:REMOVEBIGFONT (/ DOC NBF NM OBF TBL)
3.  (setvar "CMDECHO" 0)
4.  (setq DOC (vla-get-activedocument (vlax-get-acad-object)))
5.  (vlax-for TXTST (vla-get-textstyles DOC)
6.   (setq NM (vla-get-name TXTST))
7.   (setq TBL (entget (tblobjname "STYLE" NM)))
8.   (setq OBF (assoc 4 TBL))
9.   (setq NBF (cons '4 ""))
10.   (setq TBL (subst NBF OBF TBL))
11.   (entmod TBL)
12.  )
13.  (vl-cmdf "REGENALL")
14. )
15.  

[roy_043]

That is a strange approach, why do you choose it? I would either use your original code or *only* use Classic Lisp.

[Lee Mac]

That is a strange approach, why do you choose it? I would either use your original code or *only* use Classic Lisp.

Agreed - if using Vanilla AutoLISP, I would suggest something along the lines of:

Code - Auto/Visual Lisp: [Select]

1. (defun c:rembigfont ( / enx sty )
2.     (while (setq sty (tblnext "style" (not sty)))
3.         (setq enx (entget (tblobjname "style" (cdr (assoc 2 sty)))))
4.         (entmod (subst '(4 . "") (assoc 4 enx) enx))
5.     )
6.     (princ)
7. )

[Hrishikesh]

Thanks Lee & Roy,
Yes I agreed too thats a strange to use classic Autolisp & Visuallisp together.
But I am doing my lisp programming by studying it by books & internet so struggling with some basic things in lisp programming.
But when I got my answers from professionals like you it help me to understand & improve my lisp programming.

Thanks,
Hrishikesh