Topic: Replace - AFLAYER

[MORITZK]

Hallo,
in bricscad there is sometime a bug with aflayer and "deutschen Umlauten". Aflayer ignore sometime Layers with ä,ö,ü,ß.
I use (command "aflayer")  in lisp- routines. Is there a way to replace aflayer by another lisp- routine?
Thank you
Christian

[roy_043]

aflayer = vplayer

Can you give a reproducible scenario? Your description ('sometimes') is rather vague.
BricsCAD version(s)?
Have you submitted a support request?

[MORITZK]

Hallo, Roy,
i know the failure with V14/V15/V16. Now i work with V17-German. Most of time bricscad vplayer works correct, but sometimes not.
The support knows the  problem since V17. I can´t give a reproducible scenario. Its sometimes, but i think, in V17 the failure is oftener.
Only Bricscad- restart helps. Very rare i must twice or triply restart. This was only in V17.

[roy_043]

There are some Lisp functions available since BricsCAD V17 for dealing with viewport overrides (See 'Lisp Developer Support Package' vl-vplayer-set-* and vl-vplayer-get-*).

[MORITZK]

Thank you,
but i think, this is not helpfull for me. There is no vl-vplayer-set-on / off / freeze / thaw.
Christian

[roy_043]

The names of layers that are 'vp frozen' are stored as Xdata attached to the viewport.

Here is what I use (KGA_Layer_VpVisibilityMultiChange):

Code - Auto/Visual Lisp: [Select]

1. ; (KGA_Conv_List_To_Array '(1 2 3 4 5) vlax-vbinteger)
2. (defun KGA_Conv_List_To_Array (lst typ)
3.   (if lst
4.     (vlax-safearray-fill
5.       (vlax-make-safearray typ (cons 0 (1- (length lst))))
6.       lst
7.     )
8.   )
9. )
10.  
11. ; (KGA_Data_ObjectXdataGet (vlax-ename->vla-object (car (entsel))) "MYAPP") => ((1000 . "ghi") (1000 . "jkl") (1000 . "mno") (1010 1.0 3.0 5.0))
12. (defun KGA_Data_ObjectXdataGet (object app / keyLst valueLst)
13.   (vla-getxdata object app 'keyLst 'valueLst) ; Vlax-invoke does not work here.
14.   (if keyLst
15.     (mapcar
16.       '(lambda (key value)
17.         (cons
18.           key
19.           (if (= 'safearray (type (setq value (vlax-variant-value value))))
20.             (vlax-safearray->list value)
21.             value
22.           )
23.         )
24.       )
25.       (cdr (vlax-safearray->list keyLst))
26.       (cdr (vlax-safearray->list valueLst))
27.     )
28.   )
29. )
30.  
31.  
32. ; The function does not check the xdroom.
33. ; The function always returns nil.
34. ; (KGA_Data_ObjectXdataSet (vlax-ename->vla-object (car (entsel))) "MYAPP" '((1000 . "ghi") (1000 . "jkl") (1000 . "mno") (1010 1.0 3.0 5.0)))
35. (defun KGA_Data_ObjectXdataSet (object app dataLst)
36.   (vla-add (vla-get-registeredapplications (vla-get-database object)) app)
37.   (vla-setxdata
38.     object
39.     (KGA_Conv_List_To_Array
40.       (cons 1001 (mapcar 'car dataLst))
41.       vlax-vbinteger
42.     )
43.     (KGA_Conv_List_To_Array
44.       (cons
45.         app
46.         (mapcar
47.           '(lambda (a) (if (vl-consp (cdr a)) (vlax-3d-point (cdr a)) (cdr a)))
48.           dataLst
49.         )
50.       )
51.       vlax-vbvariant
52.     )
53.   )
54. )
55.  
56. ; With speed improvement based on Reini Urban's (std-%setnth).
57. ; (KGA_List_DropRight '(0 1 2 3 4 5) 2)   => (0 1 2 3)
58. (defun KGA_List_DropRight (lst n)
59.   (cond
60.     ((minusp n)
61.       lst
62.     )
63.     ((zerop n)
64.       lst
65.     )
66.     ((>= n (length lst))
67.       nil
68.     )
69.     (T
70.       (setq lst (reverse lst))
71.       (repeat (/ n 4)
72.         (setq lst (cddddr lst))
73.       )
74.       (repeat (rem n 4)
75.         (setq lst (cdr lst))
76.       )
77.       (reverse lst)
78.     )
79.   )
80. )
81.  
82. ; (KGA_List_SplitBefore '(0 1 2 6 4 5 6 7 8) 6) => ((0 1 2) (6 4 5 6 7 8))
83. (defun KGA_List_SplitBefore (lst itm / tail)
84.   (if (setq tail (member itm lst))
85.     (list (KGA_List_DropRight lst (length tail)) tail)
86.     (list lst nil)
87.   )
88. )
89.  
90. ;;; 20161019
91. ;;; (KGA_Layer_VpVisibilityMultiChange (vlax-ename->vla-object (car (entsel))) '("NewLayer1") '("NewLayer2"))
92. ;;; ======================================================================
93. ;;; Lib function: KGA_Layer_VpVisibilityMultiChange
94. ;;; Purpose:      VP freeze layers in a viewport.
95. ;;; Arguments:    vpObj     - Viewport object.
96. ;;;               freezeLst - List of layer names to VP freeze.
97. ;;;               thawLst   - List of layer names to VP thaw.
98. ;;; Return value: T.
99. ;;; ======================================================================
100. (defun KGA_Layer_VpVisibilityMultiChange (vpObj freezeLst thawLst / lst tmp)
101.   (setq lst (mapcar 'strcase (append freezeLst thawLst)))
102.   (setq tmp (KGA_List_SplitBefore (KGA_Data_ObjectXdataGet vpObj "ACAD") '(1002 . "}")))
103.   (KGA_Data_ObjectXdataSet
104.     vpObj
105.     "ACAD"
106.     (append
107.       (vl-remove-if
108.         '(lambda (sub) (and (= (car sub) 1003) (vl-position (strcase (cdr sub)) lst)))
109.         (car tmp)
110.       )
111.       (mapcar
112.         '(lambda (lyrNme) (cons 1003 lyrNme))
113.         freezeLst
114.       )
115.       (cadr tmp)
116.     )
117.   )
118.   T
119. )

[MORITZK]

Thank you very much, Roy.
this ist the perfect replacement for german aflayer.
Thank you.

[Marc'Antonio Alessi]

The names of layers that are 'vp frozen' are stored as Xdata attached to the viewport.

Here is what I use (KGA_Layer_VpVisibilityMultiChange):
...