Topic: Auto Circle Placement . . .

[MSTG007]

Another wonderful morning and another crazy question. Im curious if there is a way that I can get a circle drawn in between 2 parallel lines or polylines? something like this |o|. So if there are several hundreds of these parallel lines, it could place a circle in the middle of them.

If not possible, it was sure worth the question. Thanks guys, have a great day!

[ChrisCarlson]

It's really just a circle between two points. Select line1, select line2, wambam circle.

[ronjonp]

Try this:

Code - Auto/Visual Lisp: [Select]

1. (defun c:foo (/ a b d i p ss x)
2.   ;; RJP - 05.11.2017
3.   ;; Places circles between parallel lines and 2 pt polylines
4.   ;; Not the fastest code in the world, but faster than doing by hand :P
5.   (vl-load-com)
6.   (if (and (setq ss (ssget '((-4 . "<OR")
7.                              (0 . "line")
8.                              (-4 . "<AND")
9.                              (0 . "lwpolyline")
10.                              (90 . 2)
11.                              (-4 . "AND>")
12.                              (-4 . "OR>")
13.                             )
14.                     )
15.            )
16.            (setq d (getdist "\nEnter MAX distance to search: "))
17.       )
18.     (progn
19.       (setq ss
20.              (mapcar
21.                '(lambda (x)
22.                   (list
23.                     (angle (setq a (vlax-curve-getstartpoint x)) (setq b (vlax-curve-getendpoint x)))
24.                     (polar a (angle a b) (* 0.5 (distance a b)))
25.                     x
26.                   )
27.                 )
28.                (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
29.              )
30.       )
31.       (while (setq i (car ss))
32.         (setq ss (cdr ss))
33.         (mapcar
34.           '(lambda (x)
35.              (and
36.                (<= (distance (cadr i) (setq p (vlax-curve-getclosestpointto (last x) (cadr i)))) d)
37.                (or (equal (car i) (car x) 1e-8) (equal (+ pi (car i)) (car x) 1e-8))
38.                (entmakex
39.                  (list
40.                    '(0 . "circle")
41.                    (assoc 8 (entget (last i)))
42.                    (cons
43.                      10
44.                      (polar (cadr x) (angle (cadr x) (cadr i)) (* 0.5 (distance (cadr x) (cadr i))))
45.                    )
46.                    (cons 40 (* 0.5 (distance p (vlax-curve-getclosestpointto (last i) p))))
47.                  )
48.                )
49.                ;; (setq ss (vl-remove x ss))
50.              )
51.            )
52.           ss
53.         )
54.       )
55.     )
56.   )
57.   (princ)
58. )

[MSTG007]

lol. That is sweet. Do you think they can do it in a row? All in all that is awesome stuff Ron. (As usual)!

[ronjonp]

Comment out line 49 (setq ss (vl-remove x ss))

[Atook]

Ninja!

[ronjonp]

Ninja!

[MSTG007]

just got to dive into this bad boy. I hope I have OE errors on my part. lol. Anyways that's usually what it is. This is the drawing I am working with polylines evenly spaced.

[ronjonp]

You should post a sample drawing with all of your questions. That's a bit more involved than |0|... *edit* actually simple if you just array the circle.

[MSTG007]

You right. Sorry. Usually I come up with the idea and then go.. .wait can it do this. My wonderful mind is no conventional. lol. I saw that, and said, that be cool if you could select a bunch of stalls and it puts circles in there for counting. But still I do like what you came up with! Great job.

[ronjonp]

You right. Sorry. Usually I come up with the idea and then go.. .wait can it do this. My wonderful mind is no conventional. lol. I saw that, and said, that be cool if you could select a bunch of stalls and it puts circles in there for counting. But still I do like what you came up with! Great job.

No worries .. just saying the more info you provide in the initial question, the more likely you'll get an answer that suits your needs. 

[alanjt]

Slick!

[ronjonp]

Slick!

Thanks!