Topic: subfunction Rename Block

[amc.dicsac]

Hi, I need your help.

I have this subfunction that allows me to rename blocks but for some strange reason I get the following error

; Error: Automation Error. Key not found

Code - Auto/Visual Lisp: [Select]

1. (defun 2ap_BlockRename (bn nn / layout i)
2.   (vlax-for layout (vla-get-layouts (vla-get-ActiveDocument (vlax-get-acad-object)))
3.     (vlax-for i (vla-get-block layout)
4.       (if (and
5.             (= (vla-get-objectname i) "AcDbBlockReference")
6.             (= (strcase (vla-get-name i)) (strcase bn))
7.           )
8.         (vla-put-name i nn)
9.       )
10.     )
11.   )
12. )
13.  
14. (defun c:RNB (/ EntObj xx)
15. (vl-load-com)
16. (setq EntObj (car (entsel "\nSelecciona el bloque a renombrar:")))
17. (setq xx (getstring t "\nIngresa el nuevo nombre del bloque: "))
18. (2ap_BlockRename (cdr (assoc 2 (entget EntObj))) xx)
19. (princ))

[Lee Mac]

You are renaming block references, not the block definition, therefore a block definition corresponding to the new block name must exist otherwise you will receive the error you have reported.

[Lee Mac]

I would instead suggest something like:

Code - Auto/Visual Lisp: [Select]

1. (defun c:rnb ( / new obj old )
2.     (while
3.         (not
4.             (progn (setvar 'errno 0) (setq obj (car (entsel "\nSelect block to rename <exit>: ")))
5.                 (cond
6.                     (   (= 7 (getvar 'errno))
7.                         (prompt "\nMissed, try again.")
8.                     )
9.                     (   (null obj))
10.                     (   (/= "AcDbBlockReference" (vla-get-objectname (setq obj (vlax-ename->vla-object obj))))
11.                         (prompt "\nThe selected object is not a block.")
12.                     )
13.                     (   (progn
14.                             (setq old (vla-get-effectivename obj))
15.                             (while
16.                                 (not
17.                                     (progn (setq new (getstring t (strcat "\nSpecify new name for block \"" old "\" <exit>: ")))
18.                                         (cond
19.                                             (   (= "" new))
20.                                             (   (not (snvalid new))
21.                                                 (prompt (strcat "\n\"" new "\" is not a valid block name."))
22.                                             )
23.                                             (   (tblsearch "block" new)
24.                                                 (prompt (strcat "\nA block called \"" new "\" already exists."))
25.                                             )
26.                                             (   t   )
27.                                         )
28.                                   )
29.                                 )
30.                             )
31.                             (/= "" new)
32.                         )
33.                         (vla-put-name (vla-item (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))) old) new)
34.                         (princ (strcat "\nBlock \"" old "\" renamed to \"" new "\"."))
35.                     )
36.                 )
37.             )
38.         )
39.     )
40.     (princ)
41. )
42. (vl-load-com) (princ)

[amc.dicsac]

Thanks Lee   

An additional question, I would like to know if this section that I just wrote is correct ??

Code - Auto/Visual Lisp: [Select]

1. (while
2.    ( and  (tblsearch "block" new) )
3.             (prompt (strcat "\nA block called \"" new "\" already exists."))
4. )

[Lee Mac]

An additional question, I would like to know if this section that I just wrote is correct ??

Code - Auto/Visual Lisp: [Select]

1. (while
2.    ( and  (tblsearch "block" new) )
3.             (prompt (strcat "\nA block called \"" new "\" already exists."))
4. )

You will need a condition to terminate the loop