Topic: Function to convert selection set to vla selection set?

[Ben Clark]

Does anyone have a slick function that accepts a standard selection set (created using ssget) and converts it to a vla selection set?

[Marco Jacinto]

http://www.lee-mac.com/selectionsettolist.html

[Grrr1337]

I've had similar idea before, but left it unfinished. So you could try this:

Code - Auto/Visual Lisp: [Select]

1. ; SS - Pickset
2. ; SSnm - name for the selection set to be stored in the SS collection
3. (defun VanillaSS->VlaSS ( SS SSnm / i L SScoll SfArrayObjs vSS )
4.   (cond
5.     ( (not (eq 'PICKSET (type SS))) nil)
6.     ( (not (and (eq 'STR (type SSnm)) (snvalid SSnm))) nil)
7.     (T
8.       (repeat (setq i (sslength SS))
9.         (setq L (cons (vlax-ename->vla-object (ssname SS (setq i (1- i)))) L))
10.       )
11.       (setq SScoll (vla-get-SelectionSets (vla-get-ActiveDocument (vlax-get-acad-object))))
12.       (if (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-Item (list SScoll SSnm))))
13.         (vla-Delete (vla-Item SScoll SSnm))
14.       )
15.       (setq vSS (vla-Add SScoll SSnm))
16.       (setq SfArrayObjs (vlax-make-safearray vlax-vbObject (cons 0 (1- (length L)))))
17.       (setq i -1)
18.       (foreach o L (vlax-safearray-put-element SfArrayObjs (setq i (1+ i)) o) )
19.       (vla-AddItems vSS SfArrayObjs)
20.       vSS
21.     )
22.   ); cond
23. ); defun VanillaSS->VlaSS
24.  

[ronjonp]

Quick one to vla list .. what are you doing with a vla ss that you can't accomplish with a list of vla objects?

Code - Auto/Visual Lisp: [Select]

1. (defun ss2vlalst (ss)
2.   (if (= (type ss) 'pickset)
3.     (mapcar 'vlax-ename->vla-object (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss))))
4.   )
5. )
6. ;; (ss2vlalst (ssget))

[Grrr1337]

what are you doing with a vla ss that you can't accomplish with a list of vla objects?

Saving it as a named SS, that could be gripped later (I think).
But I like tasks, even if they have purely academical purpose.

[ronjonp]

what are you doing with a vla ss that you can't accomplish with a list of vla objects?

Saving it as a named SS, that could be gripped later (I think).
But I like tasks, even if they have purely academical purpose.

I like tasks too, but also like to know why I'm trying to solve that task when other avenues are simpler .