Topic: sssetfirst not Highlighting

[squirreldip]

I'm creating a routine to highlight linked entities - basically a sub program to my linked entities

I'm trying to set up a right-click and have an entry for "Select Linked" along side the "Select Similar".

So issuing a "(sssetfirst nil ENTSET)" will not highlight the entities unless I issue a "(command "._REGEN)" first...

I'm sure this has been covered off previously but I cannot seem to find the answer.

Any suggestions would be appreciated.

Thanks in advance,
Rob.

[tedg]

Does the "Pickadd" variable help?

[Lee Mac]

Try issuing (sssetfirst nil nil) prior to your sssetfirst call.

[squirreldip]

Changing "Pickadd" to 0, 1 or 2 has no effect...

Adding "(sssetfirst nil nil)" has no effect...

Here's the code I'm using:

Code: [Select]

(defun SELECTLINKED (/ C C2 ENT ENTSET LINKEDSET SOURCESET)
 (setq SOURCESET (ssget))
 (setq LINKEDSET (ssadd))
 (setq C 0)
 (while (< C (sslength SOURCESET))
  (setq ENT (ssname SOURCESET C))
  (setq ENTSET (RFL:GETALLENT ENT))
  (setq C2 0)
  (while (< C2 (sslength ENTSET))
   (ssadd (ssname ENTSET C2) LINKEDSET)
   (setq C2 (1+ C2))
  )
  (setq C (1+ C))
 )
 (command "._regen")  ; <-- I'd like to be able to get rid of this, slow for large drawings
; (sssetfirst nil nil)
 (sssetfirst nil LINKEDSET)
)

I'm using "(RFL:GETALLENT ENT)" which returns a set with all the entities linked to ENT.  This can be replaced by (ssadd ENT) for testing (not requiring my other routine).

Code: [Select]

(defun SELECTLINKED (/ C C2 ENT ENTSET LINKEDSET SOURCESET)
 (setq SOURCESET (ssget))
 (setq LINKEDSET (ssadd))
 (setq C 0)
 (while (< C (sslength SOURCESET))
  (setq ENT (ssname SOURCESET C))
  (setq ENTSET (ssadd ENT))
  (setq C2 0)
  (while (< C2 (sslength ENTSET))
   (ssadd (ssname ENTSET C2) LINKEDSET)
   (setq C2 (1+ C2))
  )
  (setq C (1+ C))
 )
 (command "._regen")  ; <-- I'd like to be able to get rid of this, slow for large drawings
; (sssetfirst nil nil)
 (sssetfirst nil LINKEDSET)
)

The idea of the command is that you would have an entity selected (or multiple) and you'd be able to right-click on one and have a Shortcut Menu item to execute "(SELECTLINKED) ".  "(SELECTLINKED)" would then highlight everything that is linked to the entities you first had highlighted.

Example for use is, say, in my alignment routines where I draw cross section lines, label alignments or profiles you can select all the linked by running "(SELECTLINKED)" on only one of the entities - there could be thousands of entities.

[squirreldip]

I believe I've found a solution...

Include "I" in the initial ssget call:

Code: [Select]

(ssget "I")
Also needed to revise code to check for nothing selected...

[Grrr1337]

Why you are regening before gripping the selection set?
Also you could regen only the active viewport (which should perform faster):

Code - Auto/Visual Lisp: [Select]

1. (vla-Regen (vla-get-ActiveDocument (vlax-get-acad-object)) acActiveViewport)

Another option would be to use the vla-Highlight method for every object in the selection set.

[squirreldip]

Why you are regening before gripping the selection set?
Also you could regen only the active viewport (which should perform faster):

Code - Auto/Visual Lisp: [Select]

1. (vla-Regen (vla-get-ActiveDocument (vlax-get-acad-object)) acActiveViewport)

Another option would be to use the vla-Highlight method for every object in the selection set.

The regen was required as without the entities would not highlight - they would be selected but nothing on screen (ie if you hit 'Delete' all would be deleated).

In the previous post I found that if I used '(ssget "I")' all worked without needing the regen.  Updated code here:

Code: [Select]

(defun RFL:SELECTLINKED (/ C C2 ENT ENTSET LINKEDSET SOURCESET)
 (if (setq SOURCESET (ssget "I"))
  (progn
   (setq LINKEDSET (ssadd))
   (setq C 0)
   (while (< C (sslength SOURCESET))
    (setq ENT (ssname SOURCESET C))
    (setq ENTSET (RFL:GETALLENT ENT))
    (setq C2 0)
    (while (< C2 (sslength ENTSET))
     (ssadd (ssname ENTSET C2) LINKEDSET)
     (setq C2 (1+ C2))
    )
    (setq C (1+ C))
   )
   (sssetfirst nil LINKEDSET)
   LINKEDSET
  )
  nil
 )
)