Topic: Error Handler Help

[KHoughton]

I am trying to add an error handler to a lisp routine to restore previous settings/variables in the event the user hits enter or esc. The attached routine seems to work as desired but if enter or esc is pressed there is no error message. I would like for a message to display if the command is interrupted.

The purpose of the routine is to add a text label (attached block) in paper space by selecting a point in model space and automatically filling in the elevation value as the block is inserted.

Any suggestions to streamline the routine are definitely welcome and appreciated.

Thanks!

Code: [Select]

(defun C:tocell (/ olderror)

(setvar "CMDECHO" 0)
(setq olderror *error* *error* inserror)
(setq OM (getvar "osmode"))
(setvar "OSMODE" 1)
(setq attdia_org (getvar "attdia"))
(setvar "ATTDIA" 0)
(setq LYR (getvar "clayer"))
(setq LR10 (tblsearch "layer" "G-Text"))
    (if (= LR10 nil)
        (command "layer" "new" "G-Text" "color" "7" "G-Text" "d" "Standard Text, Leaders, Notes" "G-Text" "lw" ".18" "G-Text" "")
    )
(setvar "clayer" "G-Text")

(command "mspace")

(setq Elev (rtos (cadr(getpoint "\nPick Point for Elevation: "))))

(command "pspace")

(setq p1 (getpoint "\n Pick Insertion Point:"))
(command "insert" "S:/CAD_Standards/_SE_Custom/structural/symbols/blocks/Toc-Elev_Left" "_scale" "1" "_rotate" "0" "_non" p1 Elev "" "")
(setvar "clayer" LYR)
(setvar "ATTDIA" attdia_org)
(setvar "osmode" OM)
(prompt "\n:: done ::")
)
;
(defun inserror (msg)
    (setvar "OSMODE" OM)
(setvar "ATTDIA" attdia_org)
(command-s "layer" "set" LYR "")
(command-s "pspace")
    (setq *error* OLDERROR)
    (setq msg1 msg)
    (if (= msg "quit / exit abort")
        (prompt "\nCommand Cancelled\n")
    )
    (princ)
)


[roy_043]

... but if enter or esc is pressed there is no error message. I would like for a message to display if the command is interrupted.

So why do you have this in your code?:

Code: [Select]

    (if (= msg "quit / exit abort")
        (prompt "\nCommand Cancelled\n")
    )

[ronjonp]

Maybe this will give you some ideas. Also, remember to localize your variables.

Code - Auto/Visual Lisp: [Select]

1. (defun c:tocell (/ *error* elev p1 vars x)
2.   (vl-load-com)
3.   (defun *error* (msg)
4.     ;; Reset vars
5.     (mapcar '(lambda (x) (setvar (car x) (cdr x))) vars)
6.     (and (/= 1 (getvar 'cvport)) (command-s "_.pspace"))
7.     (or (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*") (princ (strcat "\n** Error: " msg " **")))
8.     (princ)
9.   )
10.   (if (= 1 (getvar 'cvport))
11.     (progn ;; Store all variable values before you change them
12.            (setq vars (mapcar '(lambda (x) (cons x (getvar x))) '(clayer cmdecho attdia osmode)))
13.            ;; Change them
14.            (setvar 'cmdecho 0)
15.            (setvar 'osmode 1)
16.            (setvar 'attdia 0)
17.            (if (null (tblobjname "layer" "G-Text"))
18.              (command "layer"         "new"           "G-Text"        "color"
19.                       "7"             "G-Text"        "d"
20.                       "Standard Text, Leaders, Notes" "G-Text"        "lw"
21.                       ".18"           "G-Text"        ""
22.                      )
23.            )
24.            (setvar 'clayer "G-Text")
25.            (if (and (null (command-s "_.mspace"))
26.                     (setq elev (rtos (cadr (getpoint "\nPick Point for Elevation: "))))
27.                     (null (command-s "_.pspace"))
28.                     (setq p1 (getpoint "\n Pick Insertion Point:"))
29.                )
30.              (progn (command "insert"
31.                              "S:/CAD_Standards/_SE_Custom/structural/symbols/blocks/Toc-Elev_Left"
32.                              "_scale"                        "1"
33.                              "_rotate"                       "0"
34.                              "_non"                          p1
35.                              elev                            ""
36.                              ""
37.                             )
38.              )
39.            )
40.            ;; Put vars back to original value
41.            (mapcar '(lambda (x) (setvar (car x) (cdr x))) vars)
42.     )
43.     (alert "NOT in paperspace!")
44.   )
45.   (princ)
46. )

[KHoughton]

So why do you have this in your code?:

Code: [Select]

    (if (= msg "quit / exit abort")
        (prompt "\nCommand Cancelled\n")
    )

Because I am trying to get it to show on the command line if the command is cancelled.


Ronjonp ~ Thank you for your input. I'm new to lisp so I'm working through your code trying to figure out what everything is doing. Your code does not return the osmode back to the original settings but I was able to fix that. Also if the command is cancelled it stays in model space rather than switching back to paper space as it did in the original routine. I'm trying to figure out how to accomplish this with your new code.

[ronjonp]

Code modified above to return to paperspace on error and will set osmode too.

[KHoughton]

Works great! Thanks for your help! I really appreciate it.

[ronjonp]

Works great! Thanks for your help! I really appreciate it.

Glad to help