Topic: select previous group via lisp problem...

[danglar]

Hi folks.


This lisp ( attached one) can draw spline ,Select Objects Within/Crossing it and erase spline used for selection.


In this case I need to reselect previoustly selected entities within spline and than I created group from these objects..


But now I need to select previous group.. It's possible if I use GROUP command from command line, but problematical for me to do it via lisp


Do you have any idea how to do it?


I appreciate your quick response and the time you spent in helping me out. Thanks

 

[ronjonp]

Maybe this will help:

Code - Auto/Visual Lisp: [Select]

1. (defun c:swc (/ _addgroup _pac add e i ss temp)
2.   ;; Select Objects Within/Crossing Curve
3.   ;; Alan J. Thompson, 03.31.11
4.   ;; Slightly modified by Igal Averbuh 2017 (added option for splines)
5.   ;; RJP simplified & added groups 02.22.2017
6.   (vl-load-com)
7.   (defun _pac (e / l v d lst)
8.     (setq d (- (setq v (/ (setq l (vlax-curve-getdistatparam e (vlax-curve-getendparam e))) 500.))))
9.     (while (< (setq d (+ d v)) l) (setq lst (cons (vlax-curve-getpointatdist e d) lst)))
10.   )
11.   (defun _addgroup (listofobjects / grp grps name)
12.     ;; Check that all items in the list are vla-objects
13.     (if (and (vl-every '(lambda (x) (eq (type x) 'vla-object)) listofobjects)
14.              (setq grps (vla-get-groups (vla-get-activedocument (vlax-get-acad-object))))
15.         )
16.       (progn (setq grp (vla-add grps "*"))
17.              (vlax-invoke grp 'appenditems listofobjects)
18.              listofobjects
19.       )
20.     )
21.   )
22.   (initget 0 "Crossing Within")
23.   (setq *swc:opt*
24.          (cond ((getkword (strcat "\nSpecify selection method witin curve [Crossing/Within] <"
25.                                   (cond (*swc:opt*)
26.                                         ((setq *swc:opt* "Crossing"))
27.                                   )
28.                                   ">: "
29.                           )
30.                 )
31.                )
32.                (*swc:opt*)
33.          )
34.   )
35.   (princ "\nSelect closed curves to select object(s) within: ")
36.   (if (setq add (ssadd)
37.             ss  (ssget ":L" '((0 . "SPLINE")))
38.       )
39.     (progn
40.       (repeat (setq i (sslength ss))
41.         ;; Must be visible on screen for point selection to work
42.         (if (setq temp (ssget (if (eq *swc:opt* "Crossing")
43.                                 "_CP"
44.                                 "_WP"
45.                               )
46.                               (_pac (setq e (ssname ss (setq i (1- i)))))
47.                        )
48.             )
49.           (progn
50.             ;; Remove boundary from selection so it won't get grouped
51.             (ssdel e temp)
52.             ;; Delete boundary
53.             (entdel e)
54.             ;; Group objects
55.             (_addgroup
56.               (mapcar 'vlax-ename->vla-object (vl-remove-if 'listp (mapcar 'cadr (ssnamex temp))))
57.             )
58.             ;; Highlight selection
59.             ;; (sssetfirst nil temp)
60.           )
61.         )
62.       )
63.     )
64.   )
65.   (princ)
66. )

[danglar]

Thank you ronjonp for your significant approach
I did a little modification of this code: (see attached one)
1. code added to main routine
2. your code was slightly modified - now spline erased automatically
3. highlighting of selected objects was turned ON
Thank you again for cooperation

[ronjonp]

Thank you ronjonp for your significant approach
I did a little modification of this code: (see attached one)
1. code added to main routine
2. your code was slightly modified - now spline erased automatically
3. highlighting of selected objects was turned ON
Thank you again for cooperation

Glad it worked for you.