Topic: How do I offset a point in my script?

[dubb]

I wrote this script to insert a point a distance specified by the user. However, I would also like to include an offset distance. Thanks in advance.

Code: [Select]

(defun c:pp( / obj newlen plotpt pt)
  (princ "\nPlot point script will plot a point along a line or polyline.")
(setq ent (car (entsel "\n >> Select a line or polyline >>")))
(setq newlen 0)
(setq plotpt (getint "\nEnter a distance to plot a single point: "))
(setq newlen (+ plotpt newlen))
(setq pt (vlax-curve-getpointatdist ent newlen))
(entmakex (list
    (cons 0 "POINT")
    (cons 10 pt)
    (cons 8 "non-print")
    )
  )
  (princ "\Point created")
  )
*edited initial code because i saw some areas to clean up

[CAB]

And what is the offset amount relative to?
Would it be a set amount away from the new point & perpendicular to the vector the new point used?

[dubb]

And what is the offset amount relative to?
Would it be a set amount away from the new point & perpendicular to the vector the new point used?

Yes, the new point would be a user defined offset distance perpendicular from a point along a line.

[dubb]

A screenshot might help

[Lee Mac]

Change:

Code: [Select]

(setq obj (vlax-ename->vla-object (car (entsel "\n >> Select a line or polyline >>"))))
To:

Code: [Select]

(setq ent (car (entsel "\n >> Select a line or polyline >>")))
And then use the following to obtain the direction of the tangent vector at the given point, and then add or subtract pi/2 radians to this angle:

Code: [Select]

(angle '(0.0 0.0) (trans (vlax-curve-getfirstderiv ent (vlax-curve-getparamatpoint ent pt)) 0 ent t))

[dubb]

Posting before I go home from the office. This is what I have so far. Thanks for the hints.

Code: [Select]

(defun c:pp( / newlen plotpt pt offset ang side)
  (princ "\nPlot point script will plot a point along a line or polyline.")
(setq ent (car (entsel "\n >> Select a line or polyline >>")))
(setq newlen 0)
(setq plotpt (getint "\nEnter a distance to plot a single point: "))
(setq offset (getint "\nEnter an offset distance: "))


(setq newlen (+ plotpt newlen))
(setq pt (vlax-curve-getpointatdist ent newlen))
(setq ang (angle '(0.0 0.0) (trans (vlax-curve-getfirstderiv ent (vlax-curve-getparamatpoint ent pt)) 0 ent t)))
(initget "A B L R")
  (setq side (getkword "\nWhich side Above or Below [A/B/L/R]: "))
(cond
  ((or
   (= side "A")
   (= side "R"))
   (setq ang (+ ang 1.5708))
   )
  ((or
    (= side "B")
    (= side "L"))
    (setq ang (- ang 1.5708))
    )
  )
 
(setq obj (vlax-ename->vla-object ent))
(setq pt (polar pt ang offset))
(entmakex (list
    (cons 0 "POINT")
    (cons 10 pt)
    (cons 8 "non-print")
    )
  )
  (princ "\Point created")
  )