Topic: Passing a list to SSGET Logical Operators

[Coltm16]

Is it possible to pass a list to an SSGET function with conditional operators, or something similar to accomplish the same thing? I've tried everything I can think of but it is not working. Example:

Code - Auto/Visual Lisp: [Select]

1. (setq mylist (list (cons 8 "Layer1") (cons 8 "Layer2")))
2. (setq ss (ssget (list (cons -4 "<OR")  mylist (cons -4 "OR>"))))
3. (command "_stretch" ss "")

Thanks for any help.

[ronjonp]

Code - Auto/Visual Lisp: [Select]

1. (ssget '((8 . "Layer1,Layer2")))

[Coltm16]

Thanks, Have not tested it yet, but can it be:

Code - Auto/Visual Lisp: [Select]

1. (setq mylistoflayers (list "Layer1"" Layer2")
2. (ssget '((8 . mylistoflayers)))

or Do i need to use

Code - Auto/Visual Lisp: [Select]

1. (ssget (list (cons 8 mylistoflayers)))

edit: or should I use strcat with each element of the list of layers?

[ronjonp]

If you have a list of layer names, you could do something like this:

Code - Auto/Visual Lisp: [Select]

1. (ssget
2.   (list
3.     (cons 8
4.      (apply 'strcat (mapcar '(lambda (layname) (strcat layname ",")) (list "Layer1" " Layer2")))
5.     )
6.   )
7. )

Also be aware you can use wild cards too:

Code - Auto/Visual Lisp: [Select]

1. (ssget '((8 . "Layer*")))

[Coltm16]

Thanks! I am so close. However, my layerslist is coming out like ("layer1," "layer2,"....) Instead of one long string ("layer1,layer2,layer3....). Thank you for your help!

Code - Auto/Visual Lisp: [Select]

1. (defun c:stretchfilter (/ ss i l x ent layerlist)
2.  
3. (Princ "\nSelect object(s) to include their layers in a stretch command.")
4. (if (setq ss (ssget ":L"))
5.         (progn
6.                 (repeat (setq i (sslength ss))
7.                         (if (not (member (setq l (cdr (assoc 8 (entget (ssname ss (setq i (1- i))))))) x))
8.                                 (setq x (cons l x))
9.                                 );endif
10.                 );endrepeat
11.                 (setq layerlist (mapcar '(lambda (layname) (strcat layname ",")) x ))
12.                 (princ (strcat "\nOnly these layers will be included in the selection window: " layerlist))
13.                 (princ "\nSelect objects to stretch by crossing-window or crossing-polygon...")
14.                 (setq ss (ssget (list (cons -4 "<OR")  (cons 8 layerlist) (cons -4 "OR>"))))
15.                 (command "_Stretch" ss "")
16.         ));endif and progn
17. (princ)
18. );end func

[Lee Mac]

Code - Auto/Visual Lisp: [Select]

1. (apply 'strcat layerlist)

[Coltm16]

Awesome, Thank You!