Topic: question about MESHSMOOTH command

[ribarm]

Hi all...
I have a question regarding MESHSMOOTH command...

If I have selection set of boxes 3DSOLID primitives, when I enter or run through lisp (command "_.MESHSMOOTH" ss "") everything is fine - all primitives are converted to appropriate MESHES according to settings of MESH sysvars...
Now that's fine and good, but the problem arises in just slightly different situation :
If boxes aren't primitives - already had some kind of modeling operation performed UNION, SUBTRACT, INTERSECT, or similar when typed from command line (command "_.MESHSMOOTH" ss ""), CAD doesn't do anything... What's weird, when typed MESHSMOOTH directly from command line and 3DSOLIDS are selected, CAD do what should... So can anyone unlock this odd behaviour if 3DSOLIDS are complex and (command "_.MESHSMOOTH" ss "") function is used through LISP...

[roy_043]

There are several commands that have a different behavior when called from a (Lisp) script. The _Explode command is a well known example. Have you checked the prompts when you copy-paste (command "_.MESHSMOOTH")?

[ribarm]

Yes, prompts are fine... Should be supplied just sel. set and ENTER... or ename and ENTER... But like I explained, it works on first situation and on problematic modified 3DSOLIDS, it doesn't work and it should... Tested with various QAFLAGS settings and with both A2014 and A2016 CADs on Windows 7...

[ChrisCarlson]

Can you use vlisp?
 

Code - Auto/Visual Lisp: [Select]

1. (vla-SendCommand
2.     (vla-get-ActiveDocument (vlax-get-acad-object))
3.     (strcat "MESHSMOOTH" " " "(ssget \"X\" '((0 . \"3dsolid\")))" " " " ")
4. )

http://www.cadtutor.net/forum/showthread.php?89467-Solids-to-Mesh-LISP&p=612595&viewfull=1#post612595

[ribarm]

Can you use vlisp?
 

Code - Auto/Visual Lisp: [Select]

1. (vla-SendCommand
2.     (vla-get-ActiveDocument (vlax-get-acad-object))
3.     (strcat "MESHSMOOTH" " " "(ssget \"X\" '((0 . \"3dsolid\")))" " " " ")
4. )

http://www.cadtutor.net/forum/showthread.php?89467-Solids-to-Mesh-LISP&p=612595&viewfull=1#post612595

That's not what I was looking for... Of course I use VLISP often, but (vla-sendcommand adoc "...") works in separate namespace than LISP and my defined function... I want to use MESHSMOOTH at the beginning of LISP and then proceed with other things... With (vla-sendcommand) this is impossible... And yes, I haven't even checked if it would do as should, I'll check it and inform you...

[ribarm]

Thanks to Master_Shake... I solved it by using (vla-sendcommand)... Only thing that's little cumbersome is that I had to divide code in 2 parts calling separately...
So here it is - the purpose is that that when you are modeling simple models containing from cubic (not curved) surfaced 3DSOLIDS, you can now 2d scale your entire model, meaning that transformations are applied to 3DSOLIDS... So lets say, you projected house with minimal spacing measures, and you modeled house in 3D and you did find out that it's too small to put all the necessary things, you can now 2d scale it by specifying X scale factor and Y scale factors that should be little larger than 1.0 and Z scale factor remains 1.0... And that's it, complete model from 3DSOLIDS (cubic) is possible to transform - so no need for remodeling all from the beginning...

Code - Auto/Visual Lisp: [Select]

1. (defun c:cubic3dsolidmodel2dscale ( / sel )
2.  
3.   (vl-load-com)
4.  
5.   (defun continue ( / sel i sol msh )
6.     (while (entnext el)
7.       (setq el (entnext el))
8.       (ssadd el s)
9.     )
10.     (setq sel (ssadd))
11.     (command "_.-BLOCK" "{_MODEL_}" "_non" bp s "")
12.     (command "_.-INSERT" "{_MODEL_}" "_non" bp xscf yscf 0.0)
13.     (vla-put-zscalefactor (vlax-ename->vla-object (entlast)) zscf)
14.     (setq el (entlast) s (ssadd))
15.     (command "_.EXPLODE" "_L")
16.     (while (setq el (entnext el))
17.       (ssadd el s)
18.     )
19.     (repeat (setq i (sslength s))
20.       (setq msh (ssname s (setq i (1- i))))
21.       (command "_.CONVTOSOLID" msh "")
22.       (ssadd (entlast) sel)
23.     )
24.     (repeat (setq i (sslength sel))
25.       (setq sol (ssname sel (setq i (1- i))))
26.       (command "_.SOLIDEDIT" "_B" "_L" sol "")
27.       (while (< 0 (getvar 'cmdactive))
28.         (command "")
29.       )
30.       (if (= (getvar 'solidhist) 1)
31.         (vla-put-history (vlax-ename->vla-object sol) :vlax-true)
32.         (vla-put-history (vlax-ename->vla-object sol) :vlax-false)
33.       )
34.     )
35.     (setq s (ssget "_X" '((0 . "INSERT") (2 . "{_MODEL_}"))))
36.     (if s
37.       (repeat (setq i (sslength s))
38.         (if (not (vlax-erased-p (ssname s (setq i (1- i)))))
39.           (entdel (ssname s i))
40.         )
41.       )
42.     )
43.     (command "_.-PURGE" "_B" "{_MODEL_}" "_N")
44.     (setq s nil i nil bp nil xscf nil yscf nil zscf nil)
45.     (setvar 'faceterprimitivemode fpm)
46.     (setvar 'facetermeshtype fmt)
47.     (setvar 'smoothmeshconvert smc)
48.     (vla-endundomark adoc)
49.     (princ)
50.   )
51.  
52.   (defun message nil
53.     (prompt "\nType \"UNDO\" \"B\" to undo...")
54.     (setq fpm nil fmt nil smc nil continue nil message nil adoc nil)
55.     (textscr)
56.     (princ)
57.   )
58.  
59.   (vla-startundomark (setq adoc (vla-get-activedocument (vlax-get-acad-object))))
60.   (setq fpm (getvar 'faceterprimitivemode))
61.   (setvar 'faceterprimitivemode 0)
62.   (setq fmt (getvar 'facetermeshtype))
63.   (setvar 'facetermeshtype 2)
64.   (setq smc (getvar 'smoothmeshconvert))
65.   (setvar 'smoothmeshconvert 3)
66.   (if
67.     (and
68.       (not (prompt "\nSelect cubic 3DSOLID entities of model that you want to 2d scale..."))
69.       (setq sel (ssget "_:L" '((0 . "3DSOLID"))))
70.       (setq bp (getpoint "\nPick or specify base point : "))
71.       (not (initget 2))
72.       (setq xscf
73.         (cond
74.           ( (getreal "\nSpecify X scale factor <1.0> : ") )
75.           ( t 1.0 )
76.         )
77.       )
78.       (not (initget 2))
79.       (setq yscf
80.         (cond
81.           ( (getreal "\nSpecify Y scale factor <1.0> : ") )
82.           ( t 1.0 )
83.         )
84.       )
85.       (not (initget 2))
86.       (setq zscf
87.         (cond
88.           ( (getreal "\nSpecify Z scale factor <1.0> : ") )
89.           ( t 1.0 )
90.         )
91.       )
92.     )
93.     (progn
94.       (setq s (ssadd))
95.       (setq el (entlast))
96.       (while (entnext el)
97.         (setq el (entnext el))
98.       )
99.       (command "_.SELECT" sel "")
100.       (vla-sendcommand adoc "_.MESHSMOOTH\nP\n\n(continue)\n(message)\n")
101.     )
102.   )
103. )
104.  

HTH., M.R.

[ChrisCarlson]

That was from GP many years ago. I got frustrated that passing

Code - Auto/Visual Lisp: [Select]

1. (command "MESHSMOOTH" ss "")

returned "nil" but

Code - Auto/Visual Lisp: [Select]

1. (vl-cmdf "MESHSMOOTH" ss "")

returns "t"

[mailmaverick]

That was from GP many years ago. I got frustrated that passing

Code - Auto/Visual Lisp: [Select]

1. (command "MESHSMOOTH" ss "")

returned "nil" but

Code - Auto/Visual Lisp: [Select]

1. (vl-cmdf "MESHSMOOTH" ss "")

returns "t"

Can anyone explain why the behavior is different in above two commands ?

Also, Marko, in that case, instead of using (vla-sendcommand...) you can use (vl-cmdf "MESHSMOOTH" ss "").
Please try and let us know. Or otherwise, if you can share your drawing for us to try it.

[ribarm]

That was from GP many years ago. I got frustrated that passing

Code - Auto/Visual Lisp: [Select]

1. (command "MESHSMOOTH" ss "")

returned "nil" but

Code - Auto/Visual Lisp: [Select]

1. (vl-cmdf "MESHSMOOTH" ss "")

returns "t"

Can anyone explain why the behavior is different in above two commands ?

Also, Marko, in that case, instead of using (vla-sendcommand...) you can use (vl-cmdf "MESHSMOOTH" ss "").
Please try and let us know. Or otherwise, if you can share your drawing for us to try it.

The behaviour of these 2 examples isn't different - it's the same; the only difference is return value - read more ab command and vl-cmdf... And in my case neither (command), nor (vl-cmdf), nor (command-s) don't give desired results... Read carefully whole topic - I've explained several times what I want to achieve and only way is - it turned that way, (vla-sendcommand) way... For DWG, you have to experiment on your own to see what i was speaking of - GP had the same problem (look in link Master_Shake provided)... Like routine name explains it should be applied only in special case situations (flat or 2 sloped roofs - hip roof (sloped on more sides) won't be correct and geometry of model house should be only cubic for meshsmooth to operate adequate)...

[ribarm]

I have to ask...

Have someone found solution to warning message I posted here :
https://www.theswamp.org/index.php?PHPSESSID=uu45uen7nmavbj6cq5442oh2t7&topic=52160.msg571590#msg571590

[ribarm]

I have to ask...

Have someone found solution to warning message I posted here :
https://www.theswamp.org/index.php?PHPSESSID=uu45uen7nmavbj6cq5442oh2t7&topic=52160.msg571590#msg571590

I've found solution... :
https://knowledge.autodesk.com/support/autocad/troubleshooting/caas/sfdcarticles/sfdcarticles/Restore-dialog-boxes-that-display-warning-messages.html

Thanks for your attention...
M.R.