Topic: Collect entities from a block definition

[QuestionEverything]

Hello everyone,
I'd like to see how many options can be figured out, about collecting the objects/entities inside a block definition. 

[MP]

Same as any other collection.

(vlax-for object collection (setq result (cons object result))) (reverse result)

vlax-map-collection is generally faster but at the expense of clarity.

[ Untested, abbreviated response from my phone. ]

[QuestionEverything]

What about Vanilla?

[MP]

If provided a vanilla block entity (e.g. block_ename) start iterating thru the collection via (entnext (cdr (assoc -2 (entget block_ename)))) bailing once an "ENDBLK" entity is encountered.

[QuestionEverything]

This seems to be right:

Code - Auto/Visual Lisp: [Select]

1. (defun CollectObjsInBlockDef1 ( BlockName / Lst )
2.   (vlax-for o (vla-item (vla-get-Blocks (vla-get-ActiveDocument (vlax-get-acad-object))) BlockName)
3.     (setq Lst (cons o Lst))
4.   )
5.   (reverse Lst)
6. )
7.  
8. (defun CollectObjsInBlockDef2 ( BlockName / Lst )
9.   (vlax-map-collection (vla-item (vla-get-Blocks (vla-get-ActiveDocument (vlax-get-acad-object))) BlockName) (function (lambda (o) (setq Lst (cons o Lst)))))
10.   (reverse Lst)
11. )
12.  
13. (defun CollectEnamesInBlockDef ( BlockName / e Lst )
14.   (setq e (cdr (assoc -2 (tblsearch "BLOCK" BlockName))))
15.   (while (and e (/= "ENDBLK" (cdr (assoc 0 (entget e)))))
16.     (setq Lst (cons e Lst))
17.     (setq e (entnext e))
18.   )
19.   (reverse Lst)
20. )
21.  

Thank you M.Puckett!

[ribarm]

Both are correct, just my second (which I often use) is little shorter and cleaner...

Code - Auto/Visual Lisp: [Select]

1. (defun CollectEnamesInBlockDef ( BlockName / e Lst )
2.   (setq e (cdr (assoc -2 (tblsearch "BLOCK" BlockName))))
3.   (while (and e (/= "ENDBLK" (cdr (assoc 0 (entget e)))))
4.     (setq Lst (cons e Lst))
5.     (setq e (entnext e))
6.   )
7.   (reverse Lst)
8. )
9.  
10. (defun CollectEnamesInBlockDef ( BlockName / e Lst )
11.   (setq e (tblobjname "BLOCK" BlockName))
12.   (while (and (setq e (entnext e)) (/= "ENDBLK" (cdr (assoc 0 (entget e)))))
13.     (setq Lst (cons e Lst))
14.   )
15.   (reverse Lst)
16. )
17.  

[Grrr1337]

Two more (less effective):

Code: [Select]

(defun CollectObjsInBlockDef ( BlockName / BlockDef i Lst )
  (setq BlockDef (vla-item (vla-get-Blocks (vla-get-ActiveDocument (vlax-get-acad-object))) BlockName))
  (repeat (setq i (vla-get-Count BlockDef))
    (setq Lst (cons (vla-item BlockDef (setq i (1- i))) Lst))
  )
  (reverse Lst)
)

(defun CollectObjsInBlockDef ( BlockName / BlockDef n o Lst )
  (setq BlockDef (vla-item (vla-get-Blocks (vla-get-ActiveDocument (vlax-get-acad-object))) BlockName))
  (setq n 0)
  (while (not (vl-catch-all-error-p (setq o (vl-catch-all-apply 'vla-item (list BlockDef n)))))
    (setq Lst (cons o Lst))
    (setq n (1+ n))
  )
  (reverse Lst)
)


[QuestionEverything]

So the conclusion I did is that the entities inside a block definition are located between the "BLOCK" and "ENDBLK" entities.
And for visual lisp they are simply collection objects.
Thank you all!