Topic: copy attribute value to block's winthin a distance

[DraxJDM]

hey all,

a request, and not a small one i'm sorry.

i try to copy a list of attribute values from a block, to other block's that are within a given distance of de source block.
the block's to match are 2 are 3 not all the blocks in the distance from the source block

The drawing contains a few hundred cabinet blocks, all the switches and lightning blocks within a distance of 15m of a cabinet should get 4 to 6 attribute values from de source block, not all. 
The blocks are dynamic, visibility and rotation. The attribute tags are the same within the different blocks.
and if possible with a choise of a sqare are circilar distance.



i just don't have a idea where to start

greetz John

[DraxJDM]

i forgot to add a exemple drawing, now the is one in the top post.

i whant to copy from block "CFab__To_LS-Bord" the attribute values from, "GEO__ZONE", "GEO__OBJECT", "ELEC__ZONE" and "ELEC__BORD_ID"
to the blocks around inside the cirkel, the cirkel is just a reference distance, not  precent in the real drawing.

hope this helps you guys to help me

greetz John

[ronjonp]

Here's a quick example to fill in blocks within a radius of a 'base' block ( not much error checking ):

Code - Auto/Visual Lisp: [Select]

1. (defun c:foo (/ b blocks d p s tags x)
2.   (vl-load-com)
3.   (setq tags '("GEO__ZONE" "GEO__OBJECT" "ELEC__ZONE" "ELEC__BORD_ID"))
4.   (if (and (setq b (car (entsel "\nPick base block: ")))
5.       (vlax-property-available-p (setq b (vlax-ename->vla-object b)) 'hasattributes)
6.       (setq p (vlax-get b 'insertionpoint))
7.       (setq tags (vl-remove 'nil
8.              (mapcar '(lambda (x)
9.                    (if   (vl-position (vla-get-tagstring x) tags)
10.                      (cons (vla-get-tagstring x) (vla-get-textstring x))
11.                    )
12.                  )
13.                 (vlax-invoke b 'getattributes)
14.              )
15.             )
16.       )
17.       (setq d (getdist "\nEnter distance to search: "))
18.       (setq blocks (ssget "_x" '((0 . "insert") (66 . 1))))
19.       (setq blocks (mapcar 'vlax-ename->vla-object (mapcar 'cadr (ssnamex blocks))))
20.       )
21.     (foreach block blocks
22.       (if (<= (distance p (vlax-get block 'insertionpoint)) d)
23.    (mapcar   '(lambda (x)
24.          (if (setq s (cdr (assoc (vla-get-tagstring x) tags)))
25.            (vla-put-textstring x s)
26.          )
27.        )
28.       (vlax-invoke block 'getattributes)
29.    )
30.       )
31.     )
32.   )
33.   (princ)
34. )

[DraxJDM]

Thx ronjonp.

i think i do something wrong ..
i get a  "error: bad argument type: lselsetp nil" ...

and i only whant to put the attribute value to the twoo blocks in the sample drawing, not in others

[roy_043]

Code: [Select]

(ssnamex ss)should be:

Code: [Select]

(ssnamex blocks)

[DraxJDM]

Hey Roy, thank you

now it is working.


is it hard to change, so that it doing this for every block instance of the selected block in the drawing, not just the one i picked?


greetz john

[ronjonp]

Code: [Select]

(ssnamex ss)should be:

Code: [Select]

(ssnamex blocks)

Oops 😁 my bad .. thanks for picking this up Roy.

[DraxJDM]

a little exra help please...

is it possible to let this work for every instance of the selected block, it is a dynamic block.
there are a few hundred "base" blocks in the drawing.

this would be very helpful for me


as a extra,  copy the attribute value not just from attribute to the same atribute, but from one source attribute to a different attribute, 3 or 4 sets of this.


thx

[ronjonp]

Give this a try for multiple blocks. I added comments so you can try to understand what's going on.

Code - Auto/Visual Lisp: [Select]

1. (defun c:foo (/ b bases blocks d en p s ss tags x)
2.   ;; RJP 12/21/2016
3.   (vl-load-com)
4.   (if (and ;; Get the base block
5.            (setq b (car (entsel "\nPick base block: ")))
6.            ;; Check if it has attributes
7.            (vlax-property-available-p (setq b (vlax-ename->vla-object b)) 'hasattributes)
8.            ;; Get effectivename .. yes this can bonk if no effective name prop ( I'll let you add a check :P )
9.            (setq en (vlax-get b 'effectivename))
10.            ;; Get all blocks in the drawing minus the 'bases' .. effective name bonky'ness could exist here too
11.            (setq blocks (vl-remove-if
12.                           '(lambda (x) (= (vlax-get x 'effectivename) en))
13.                           (setq ss (mapcar 'vlax-ename->vla-object
14.                                            (mapcar 'cadr (ssnamex (ssget "_x" '((0 . "insert") (66 . 1)))))
15.                                    )
16.                           )
17.                         )
18.            )
19.            ;; Duh
20.            (setq d (getdist "\nEnter distance to search: "))
21.            ;; Get the base blocks
22.            (setq bases (vl-remove-if-not '(lambda (x) (= (vlax-get x 'effectivename) en)) ss))
23.       )
24.     (progn ;; Foreach base
25.            (foreach base bases
26.              ;; Get the base insertion point
27.              (setq p (vlax-get base 'insertionpoint))
28.              ;; Get a list of tagstrings & values from the 'base'
29.              (setq tags
30.                     (vl-remove 'nil
31.                                (mapcar '(lambda (x) (cons (vla-get-tagstring x) (vla-get-textstring x)))
32.                                        (vlax-invoke base 'getattributes)
33.                                )
34.                     )
35.              )
36.              ;; Cycle through all the other attributed blocks
37.              (foreach block blocks
38.                ;; If the distance is bueno ..
39.                (if (<= (distance p (vlax-get block 'insertionpoint)) d)
40.                  ;; Put the base block's value into the 'radius' block
41.                  (mapcar '(lambda (x)
42.                             (if (setq s (cdr (assoc (vla-get-tagstring x) tags)))
43.                               (vla-put-textstring x s)
44.                             )
45.                           )
46.                          (vlax-invoke block 'getattributes)
47.                  )
48.                )
49.              )
50.            )
51.     )
52.   )
53.   ;; ssshhh
54.   (princ)
55. )

[DraxJDM]

Thx roy  this works perfectly for me 

a special thx for the comments, this helps me a little more in understanding the code

[ronjonp]

Thx roy Ron this works perfectly for me 

a special thx for the comments, this helps me a little more in understanding the code

You're welcome Charlie. 

[DraxJDM]

charlie bit in trouble

now I just have to try how to just copy certain attrubites 

[ronjonp]

charlie bit in trouble

now I just have to try how to just copy certain attrubites 

Try this version ... it will only copy the defined tags: ("GEO__ZONE" "GEO__OBJECT" "ELEC__ZONE" "ELEC__BORD_ID")

Code - Auto/Visual Lisp: [Select]

1. (defun c:foo (/ b bases blocks d en p s ss tags x)
2.   ;; RJP 12/21/2016
3.   (vl-load-com)
4.   (if (and ;; Get the base block
5.            (setq b (car (entsel "\nPick base block: ")))
6.            ;; Check if it has attributes
7.            (vlax-property-available-p (setq b (vlax-ename->vla-object b)) 'hasattributes)
8.            ;; Get effectivename .. yes this can bonk if no effective name prop ( I'll let you add a check :P )
9.            (setq en (vlax-get b 'effectivename))
10.            ;; Get all blocks in the drawing minus the 'bases' .. effective name bonky'ness could exist here too
11.            (setq blocks (vl-remove-if
12.                           '(lambda (x) (= (vlax-get x 'effectivename) en))
13.                           (setq ss (mapcar 'vlax-ename->vla-object
14.                                            (mapcar 'cadr (ssnamex (ssget "_x" '((0 . "insert") (66 . 1)))))
15.                                    )
16.                           )
17.                         )
18.            )
19.            ;; Duh
20.            (setq d (getdist "\nEnter distance to search: "))
21.            ;; Get the base blocks
22.            (setq bases (vl-remove-if-not '(lambda (x) (= (vlax-get x 'effectivename) en)) ss))
23.       )
24.     (progn ;; Foreach base
25.            (foreach base bases
26.              ;; Get the base insertion point
27.              (setq p (vlax-get base 'insertionpoint))
28.              ;; Defined tag names to copy
29.              (setq tags '("GEO__ZONE" "GEO__OBJECT" "ELEC__ZONE" "ELEC__BORD_ID"))
30.              ;; Get a list of tagstrings & values from the 'base'
31.              (setq tags (vl-remove 'nil
32.                                    (mapcar '(lambda (x)
33.                                               (if (vl-position (vla-get-tagstring x) tags)
34.                                                 (cons (vla-get-tagstring x) (vla-get-textstring x))
35.                                               )
36.                                             )
37.                                            (vlax-invoke base 'getattributes)
38.                                    )
39.                         )
40.              )
41.              ;; Cycle through all the other attributed blocks
42.              (foreach block blocks
43.                ;; If the distance is bueno ..
44.                (if (<= (distance p (vlax-get block 'insertionpoint)) d)
45.                  ;; Put the base block's value into the 'radius' block
46.                  (mapcar '(lambda (x)
47.                             (if (setq s (cdr (assoc (vla-get-tagstring x) tags)))
48.                               (vla-put-textstring x s)
49.                             )
50.                           )
51.                          (vlax-invoke block 'getattributes)
52.                  )
53.                )
54.              )
55.            )
56.     )
57.   )
58.   ;; ssshhh
59.   (princ)
60. )

[DraxJDM]

thx Roy..

i get  .... ; error: bad argument type: VLA-OBJECT nil

i had a try with the same solution .. a copy of the first version you give to me


only i had the "setq tags" after the "VL-load-com" 
is there a reason why it has to be set after "foreach" ... 

[ronjonp]

Not sure what's causing the error .. I set it within the foreach because it is set on line 29 then redefined on line 31.