Topic: dynamic block grid

[ifncdylan]

Hey all, long time! 

I've written a routine that inserts a tonne of blocks in a grid format, based on some input. Basically the grid is a X,Y grid with position 1,1 being labelled AA up to position 26,26 which would be ZZ, along with a 'type' attribute for each block. Basically the grid represents a bank of underground conduits in real life - e.g. a bank of 16 100mm copper conduits labeled AA to DD.

Essentially I'm just calculating a base point and then adding up the width/height required to get the block inserted at the right location. It works, but it can insert hundreds blocks in one large grid which then becomes pretty difficult to select/move around, especially when it gets large and it's on top of linework.

I was wondering if there was a way to make a dynamic block that could display information dynamically from a set of attributes (even if its 1000 attributes) in a single block object rather than what is possibly over 700 blocks in a grid layout - it would make it way easier to work with after it's inserted!

Essentially it would just be drawing a grid of circles from one list of 'position references' (AA-ZZ) and inserting a text inside that circle if that 'position reference' is in another list. Is that possible with dynamic blocks, or is it too fancy?

[ChrisCarlson]

An XY array is perfect for dynamic blocks.

[dgorsman]

Only up to a certain point - I've had problems with using it for grid lines with a dotted linetype.

[ronjonp]

Maybe posting an example drawing would help explain exactly what you're looking for.

[ifncdylan]

I should learn to post drawings with this kind of stuff 

Here's two basic grids that show the inputs and outputs required. Essentially the direction determines which side of the grid AA is on and the ducts/empty lists are the information used to make the grid of blocks up.

In the right box you can see a simple grid setup, it is just a bunch of P100 types with some "vacant" ducts in the mix. The type P100 goes in the center-bottom of the 'box' that makes up the P100 types (in this case the 'box' is position AA to DD, so the attribute goes in the middle there).

As you see in the left box, there is two different types, so the A100 types would be inserted and one of the attributes is then moved to the middle of that 'array' of ducts, then the C100 types have their own attribute centered on their 'base point' as well. I'm pretty sure I can't do this with my current approach.

The inputs are generated from a larger array of information, so if the way the information in those lists is organized stops it from being efficiently processed, then it can be changed in format easily.

This is the code I currently use to make the ducts, however it won't do stuff like what's in the left box, that was a manual one and something I'm hoping I could automate

Code - Auto/Visual Lisp: [Select]

1. (defun dgrid ( tx ducts empty / width left up fleft fup tx vx lx)
2. (cond
3.                  ((and (= tdir "e"))
4.                   (vla-put-AttachmentPoint (vlax-ename->vla-object tx) 3)
5.                   )
6.                  ((and (= tdir "w"))
7.                   (vla-put-AttachmentPoint (vlax-ename->vla-object tx) 1)
8.                   )
9.  
10.   )
11.   (setq width 2.7268
12.         ductBlocks (list)
13.         vx (vlax-ename->vla-object tx)
14.         itemsInserted (list vx)
15.         lx (vla-get-TextString vx)
16.         inspt (vlax-safearray->list (vlax-variant-value (vla-get-InsertionPoint vx)))
17.         attpt (vla-get-AttachmentPoint vx)
18.         lastDuctRef (last ducts) ;(lastDuct ducts empty)
19.         ducts (vl-remove-if '(lambda (a) (member a empty)) ducts) ; remove emptys
20.         ;ducts (if (= "SINGLE-CONDUIT" (dxf "ROUTE_CONST" routeDetails))
21.         ;       (list "AA")
22.         ;       ducts) 
23.        
24.         maxw (- (ascii (substr lastDuctRef 1)) 64)
25.         maxh (- (ascii (substr lastDuctRef 2)) 64)
26.         base (shiftdown
27.                (cond
28.                  ((and (= dir "e") (= tdir "e")) ;; if the direction of the duct grid and which way we want the text justified dont match, we need to move the base point either way
29.                   inspt
30.                   )
31.                  ((and (= dir "w") (= tdir "w"))
32.                   inspt
33.                   )
34.                  ((and (= dir "e") (= tdir "w"))
35.                   (shiftleft inspt (+ width (* width maxw)))
36.                   )
37.                  ((and (= dir "w") (= tdir "e")) ;; test.. 'east east'
38.                   (shiftright inspt (+ width (* width maxw)))
39.                   )
40.                  
41.  
42.                 )
43.  
44.                
45.                 (+ (* maxh width) (/ width 2))
46.                )
47.         )
48.   (foreach i empty (if (not (member i ducts)) (makeDuct i " " base dir)))
49.   (foreach i ducts (makeDuct i i base dir))
50.   (makeLeader lastDuctRef base dir)
51.   (entmod (append (vl-remove-if '(lambda ( x ) (member (car x) '(45 63 90 421 431 441))) (entget (vlax-vla-object->ename vx)))
52.                            '((90 . 3) (63 . 256))
53.                         (list (cons 45 1) '(441 . 0))
54.                     )
55.                 )
56.  
57. )
58. (defun makeDuct (pos ref base dir / ip b ductRef ductType width)
59.   (setq width 2.7268
60.         y (- (ascii (substr pos 1)) 64)
61.         x (- (ascii (substr pos 2)) 64)
62.         ip (if (= dir "w")
63.              (shiftup (shiftleft base (* width y)) (* width x))
64.              (shiftup (shiftright base (* width y)) (* width x))
65.             )
66.         disp (if (= dir "w")
67.                                          (* -1 (/ (- maxw 1) 2.0))
68.                                          (/ (- maxw 1) 2.0)
69.                                          )
70.         b (if (and (< y 26) (> y -1) (< x 26) (> x -1)) (insertDuct ref ip))
71.         ductBlocks (cons b ductBlocks)
72.         )
73.   (if (= "AA" pos) (progn
74.     (vla-move
75.       (setq att (nth 0
76.                      (vlax-safearray->list
77.                        (variant-value (vla-getattributes b))
78.                      )
79.                 )
80.       )
81.       (vlax-3d-point '(0.0 0.0 0.0))
82.       (vlax-3d-point (list (* width disp) 0.0 0.0))
83.     )
84.     (vla-put-textString att dType)
85.     )
86.     )
87. )
88.  
89. (defun makeLeader (pos base dir / ip)
90.   (setq y (- (ascii (substr pos 1)) 64)
91.         x (- (ascii (substr pos 2)) 64)
92.         ip
93.             (if (= dir "w")
94.              (shiftup (shiftleft base (* maxw (/ width 2))) (+ (* width x) (/ width 2)))
95.              (shiftup (shiftright base (/ width 2)) (+ (* width x) (/ width 2)))
96.             )
97.         )
98. (setq pt1 (shiftup ip 1.6)
99.       pt2 (shiftup (shiftdown ip (/ width 2)) 0.3)
100.       pt3 (shiftleft (shiftdown ip (/ width 2)) 0.09)
101.       space (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
102.       ptlist (apply 'append (list pt1 pt2 pt3))
103.       txtobj (vla-addmtext space (vlax-3d-point pt3) 0 "")
104.       ldrobj (vlax-invoke space 'addleader ptlist txtobj acLineWithArrow)
105.  )
106.   (if (/= 1 gddScale) (vla-put-ScaleFactor ldrobj gddScale))
107. (vla-delete txtobj)  
108. (setq itemsInserted (append itemsInserted (list ldrobj)))
109.  
110. )
111. (defun insertDuct (ref ip)
112.         (setq thisdrawing (vla-get-activedocument
113.                               (vlax-get-acad-object)))
114.         (setq mspace (vla-get-modelspace thisdrawing))
115.         (setq theblock (vla-InsertBlock mspace (vlax-3d-point ip)
116.                               "DUCT" 1 1 1 0))
117.         (LM:vl-setattributevalue theblock "DUCTREF" ref)
118.         (setq itemsInserted (append itemsInserted (list theblock)))
119.         theblock
120. )
121. (defun shiftleft ( pt dist / p1 p2 p3 ) (list (- (car pt) dist) (cadr pt) 0.0))
122. (defun shiftright ( pt dist / p1 p2 p3 ) (list (+ (car pt) dist) (cadr pt) 0.0))
123. (defun shiftup ( pt dist / p1 p2 p3 ) (list (car pt) (+ (cadr pt) dist) 0.0))
124. (defun shiftdown ( pt dist / p1 p2 p3 ) (list (car pt) (- (cadr pt) dist) 0.0))
125.  

[ronjonp]

Give the code below a try. This is how I'd structure the data & apply offset values using the text info.

Code - Auto/Visual Lisp: [Select]

1. (defun c:ducts (/ att b bp dir ducts off ref spc)
2.   ;; RJP 10.20.2016
3.   ;; Example to place 'duct' blocks based off of offset values derived from ascii codes of text
4.   (vl-load-com)
5.   ;; Block offset distance ( from example drawing )
6.   (setq off 5.453578)
7.   (or *ductdirection* (setq *ductdirection* "1-RightUp"))
8.   (initget 0 "1-RightUp 2-RightDown 3-LeftUp 4-LeftDown")
9.   (setq   *ductdirection*
10.     (cond
11.       ((getkword
12.          (strcat "\nDuct Direction [1-RightUp/2-RightDown/3-LeftUp/4-LeftDown] <"
13.             *ductdirection*
14.             ">: "
15.          )
16.        )
17.       )
18.       (*ductdirection*)
19.     )
20.   )
21.   (setq
22.     dir   (cdr (assoc (atof *ductdirection*)
23.           (list (list 1.0 '(+ +)) (list 2.0 '(+ -)) (list 3.0 '(- +)) (list 4.0 '(- -)))
24.         )
25.    )
26.   )
27.   (if (and ;; Get start point
28.       (or (setq bp (getpoint "\nPick a base point: ")) (setq bp '(0. 0. 0.)))
29.       ;; Data structure
30.       (setq ducts '(("P100" ("AA" "AB" "AC" "AD" "AB" "BB" "CA" "CD" "DB" "DC" "DD"))
31.           ("EMPTY" ("BC" "BD" "CB" "CC" "CD"))
32.          )
33.       )
34.       ;; Get the smallest string value
35.       (setq ref (vl-string->list (car (vl-sort (apply 'append (mapcar 'cadr ducts)) '<))))
36.       ;; Make a list of strings & offset numbers that will be multiplied by 'off' variable above
37.       ;; These numbers can be modified with + - to get the desired offset direction
38.       (setq ducts (mapcar '(lambda (x) (cons x (mapcar '- (vl-string->list x) ref)))
39.                 (apply 'append (mapcar 'cadr ducts))
40.              )
41.       )
42.       ;; Current space to insert attributed block below
43.       (setq spc (vlax-get (vla-get-activedocument (vlax-get-acad-object))
44.                 (if (= (getvar 'cvport) 1)
45.              'paperspace
46.              'modelspace
47.                 )
48.            )
49.       )
50.       )
51.     (foreach duct ducts
52.       ;;Try to insert block if it's defined
53.       (if (and (tblobjname "block" "duct")
54.           (setq b (vla-insertblock
55.           spc
56.           (vlax-3d-point
57.             (list ((eval (caar dir)) (car bp) (* off (cadr duct)))
58.              ((eval (cadar dir)) (cadr bp) (* off (caddr duct)))
59.              (caddr bp)
60.             )
61.           )
62.           "duct"
63.           2.
64.           2.
65.           2.
66.           0.
67.              )
68.           )
69.           ;; Get the attribute to add the text to
70.           (setq att (car (vl-remove-if-not
71.             '(lambda (x) (= "DUCTREF" (vla-get-tagstring x)))
72.             (vlax-invoke b 'getattributes)
73.                )
74.           )
75.           )
76.      )
77.    ;; Fill in the value
78.    (vla-put-textstring
79.      att
80.      (if (member (car duct) (cadr (assoc "EMPTY" ducts)))
81.        ""
82.        (car duct)
83.      )
84.    )
85.       )
86.     )
87.   )
88.   (princ)
89. )

[ifncdylan]

Thanks Ron! That's a much better way to deal with the offsetting and it performs a whole lot quicker too.

My next challenge is to deal with the groupings on the left example. I'm thinking of perhaps drawing a bounding box around all P100 type blocks and then putting the P100 text at the bottom center of that box.

That will probably be a lot easier to achieve with Ron's code

[ronjonp]

Thanks Ron! That's a much better way to deal with the offsetting and it performs a whole lot quicker too.

My next challenge is to deal with the groupings on the left example. I'm thinking of perhaps drawing a bounding box around all P100 type blocks and then putting the P100 text at the bottom center of that box.

That will probably be a lot easier to achieve with Ron's code

Glad to help .. perhaps you could find the 'base' of each scenario & fill that in. Seems like that would get the point across.

[ifncdylan]

I'm trying to set that up this week, we've had some new work come in so I've been preparing for that. I think the main thing would be ability to set an attribute on the center block of a set, how to figure out which one that is is what's eluding me so far.