Topic: Length FIELD not working

[QuestionEverything]

Hi, I am trying something simple:
1. Entmakex a line from 2 points
2. Entmakex a mtext in the middle, and populate it with Length FIELD from the line
Whats wrong with my field content?

Code: [Select]

(vl-load-com) (princ)
(defun C:test ( / p1 p2 a e c str id )

(if
(and
(setq p1 (getpoint "\nFirst point for the line: "))
(setq p2 (getpoint "\nSecond point for the line: " p1))
(setq a (angle p1 p2))
); and
(progn
(setq e (entmakex (list (cons 0 "LINE")(cons 10 p1)(cons 11 p2))))
(setq c (mapcar '(lambda (a b) (/ (+ a b) 2.0)) p1 p2))
(setq str
(strcat
"%<\\AcObjProp.16.2 Object(%<\\_ObjId "
(setq id (Get-ObjectIDx64 (vlax-ename->vla-object e)))
">%).Length \\f \"%lu2%ds44%zs8%th32\">%"
)
)
(entmakex
(list
(cons 0 "MTEXT") (cons 100 "AcDbEntity") (cons 100 "AcDbMText") (cons 10 c)
(cons 40 (getvar 'textsize)) (cons 50 a) (cons 1 str) (cons 71 5)
)
)
)
)
(princ)
)

(defun Get-ObjectIDx64 (obj / util)
  (setq util (vla-get-Utility (vla-get-activedocument (vlax-get-acad-object))))
(if (> (vl-string-search "x64" (getvar "platform")) 0)
(vlax-invoke-method util "GetObjectIdString" obj :vlax-False)
(itoa (vla-get-Objectid obj))
)
)
I get this instead:

[Lee Mac]

entmake'ing a Field is relatively complex as you also have to create the accompanying dictionaries which drive the field update.

Using ActiveX methods, such dictionaries are generated automatically:

Code - Auto/Visual Lisp: [Select]

1. (defun c:test ( / ent ins mtx pt1 pt2 )
2.     (if
3.         (and
4.             (setq pt1 (getpoint "\n1st point for line: "))
5.             (setq pt2 (getpoint "\n2nd point for line: " pt1))
6.         )
7.         (progn
8.             (setq pt1 (trans pt1 1 0)
9.                   pt2 (trans pt2 1 0)
10.                   ent (entmakex (list '(0 . "LINE") (cons 10 pt1) (cons 11 pt2)))
11.                   ins (vlax-3D-point (mapcar '/ (mapcar '+ pt1 pt2) '(2.0 2.0 2.0)))
12.                   mtx
13.                 (vla-addmtext
14.                     (if (= 1 (getvar 'cvport))
15.                         (vla-get-paperspace (LM:acdoc))
16.                         (vla-get-modelspace (LM:acdoc))
17.                     )
18.                     ins 0.0
19.                     (strcat
20.                         "%<\\AcObjProp Object(%<\\_ObjId "
21.                         (LM:objectid (vlax-ename->vla-object ent))
22.                         ">%).Length \\f \"%lu2%ds44%zs8%th32\">%"
23.                     )
24.                 )
25.             )
26.             (vla-put-attachmentpoint mtx acattachmentpointmiddlecenter)
27.             (vla-put-rotation mtx (angle pt1 pt2))
28.             (vla-put-insertionpoint mtx ins)
29.         )
30.     )
31.     (princ)
32. )
33.  
34. ;; ObjectID  -  Lee Mac
35. ;; Returns a string containing the ObjectID of a supplied VLA-Object
36. ;; Compatible with 32-bit & 64-bit systems
37.  
38. (defun LM:objectid ( obj )
39.     (eval
40.         (list 'defun 'LM:objectid '( obj )
41.             (if (vlax-method-applicable-p (vla-get-utility (LM:acdoc)) 'getobjectidstring)
42.                 (list 'vla-getobjectidstring (vla-get-utility (LM:acdoc)) 'obj ':vlax-false)
43.                '(itoa (vla-get-objectid obj))
44.             )
45.         )
46.     )
47.     (LM:objectid obj)
48. )
49.  
50. ;; Active Document  -  Lee Mac
51. ;; Returns the VLA Active Document Object
52.  
53. (defun LM:acdoc nil
54.     (eval (list 'defun 'LM:acdoc 'nil (vla-get-activedocument (vlax-get-acad-object))))
55.     (LM:acdoc)
56. )
57.  
58. (vl-load-com) (princ)

[ribarm]

This worked for me, assuming that your FIELDEVAL = 31...

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com) (princ)
2. (defun C:test ( / p1 p2 a e c str mt )
3.  
4.   (if
5.     (and
6.       (setq p1 (getpoint "\nFirst point for the line: "))
7.       (setq p2 (getpoint "\nSecond point for the line: " p1))
8.       (setq a (angle p1 p2))
9.     ); and
10.     (progn
11.       (setq e (entmakex (list (cons 0 "LINE")(cons 10 p1)(cons 11 p2))))
12.       (setq c (mapcar '(lambda (a b) (/ (+ a b) 2.0)) p1 p2))
13.       (setq str
14.         (strcat
15.           "%<\\AcObjProp.16.2 Object(%<\\_ObjId "
16.           (Get-ObjectIDx64 (vlax-ename->vla-object e))
17.           ">%).Length \\f \"%lu2%ds44%zs8%th32\">%"
18.         )
19.       )
20.       (setq mt
21.         (entmakex
22.           (list
23.             (cons 0 "MTEXT") (cons 100 "AcDbEntity") (cons 100 "AcDbMText") (cons 10 c)
24.             (cons 40 (getvar 'textsize)) (cons 50 a) (cons 1 str) (cons 71 5)
25.           )
26.         )
27.       )
28.       (vla-put-textstring (vlax-ename->vla-object mt) (eval (vla-get-textstring (vlax-ename->vla-object mt))))
29.     )
30.   )
31.   (princ)
32. )
33.  
34. (defun Get-ObjectIDx64 (obj / util)
35.   (setq util (vla-get-Utility (vla-get-activedocument (vlax-get-acad-object))))
36.   (if (> (vl-string-search "x64" (getvar "platform")) 0)
37.     (vlax-invoke-method util "GetObjectIdString" obj :vlax-False)
38.     (itoa (vla-get-Objectid obj))
39.   )
40. )
41.  

[QuestionEverything]

Hm, so as I understand for the Object ID to be "readen/evaluated" correctly, vla-object must be used for the text/mtext instead of entity.
This row of Marko Ribar perfectly describes this:

Code: [Select]

(vla-put-textstring (vlax-ename->vla-object mt) (eval (vla-get-textstring (vlax-ename->vla-object mt)))) I thought it was just enough to "put/paste" the content (with strcat) and It would work... just like vla-add... (which is commonly seen if one googles enough about FIELD & LISP).
Lee mac's example shows this - during vla-add that content/textstring is evaluated automatically. And I didn't knew that FIELD can be entmaked (thanks for shedding light on this subject).
Both answers I got are incredibly useful!

[ChrisCarlson]

Are the distances going to change? If not, you can easily just calculate the distance between pt1 and pt2 and pass it into the mtext entity as a string.

Code - Auto/Visual Lisp: [Select]

1. (setq str (rtos (distance pt1 pt2) 2 2))

[QuestionEverything]

I was practicing with FIELDs, its way too easy to get the distance straight.

[ribarm]

Lee is correct... You can remove (eval) from here :

Code: [Select]

(vla-put-textstring (vlax-ename->vla-object mt) (vla-get-textstring (vlax-ename->vla-object mt)))

It's about Activex functionality...

[QuestionEverything]

Next time I'll try not to ignore Lee Mac's short comments, instead of giving straight look into the code.