Topic: Remove NIL values in a LIST

[mailmaverick]

How to remove NIL values in a LIST ?

[irneb]

Try: http://help.autodesk.com/cloudhelp/2015/ENU/AutoCAD-AutoLISP/files/GUID-1BF33827-5C9C-49B2-A21B-656E0F429B21.htm#!

[kpblc]

(vl-remove nil lst)

[mailmaverick]

Thanks a lot.

Sometimes we are so dumb

[MP]

Sometimes we are so dumb

(repeat 2 <game buzzer>)

Sorry, that is incorrect.



Not asking for help?

Now that would be dumb.

PS: The people you may consider gurus have asked LOTS of questions themselves.

[Lee Mac]

Some variations/benchmarks for academia:

Code - Auto/Visual Lisp: [Select]

1. (defun remove-nil-1 ( lst ) (vl-remove nil lst))
2. (defun remove-nil-2 ( lst ) (vl-remove-if 'null lst))
3. (defun remove-nil-3 ( lst ) (apply 'append (subst nil '(nil) (mapcar 'list lst))))
4. (defun remove-nil-4 ( lst ) (apply 'append (mapcar '(lambda ( x ) (if x (list x))) lst)))
5. (defun remove-nil-5 ( lst / rtn ) (foreach x lst (if x (setq rtn (cons x rtn)))) (reverse rtn))
6. (defun remove-nil-6 ( lst ) (if lst (if (car lst) (cons (car lst) (remove-nil-6 (cdr lst))) (remove-nil-6 (cdr lst)))))

Code - Auto/Visual Lisp: [Select]

1. _$ (setq lst '(1 2 nil 3 4 nil 5 6 nil))
2. (1 2 nil 3 4 nil 5 6 nil)
3. _$ (repeat 4 (setq lst (append lst lst)))
4. (1 2 nil 3 4 nil 5 6 nil 1 2 nil ... nil 5 6 nil)
5. _$ (length lst)
6. 144
7.  
8. _$ (benchmark '((remove-nil-1 lst)(remove-nil-2 lst)(remove-nil-3 lst)(remove-nil-4 lst)(remove-nil-5 lst)(remove-nil-6 lst)))
9. Benchmarking ....................Elapsed milliseconds / relative speed for 131072 iteration(s):
10.  
11.     (REMOVE-NIL-1 LST).....1669 / 5.16 <fastest>
12.     (REMOVE-NIL-2 LST).....2792 / 3.08
13.     (REMOVE-NIL-4 LST).....6723 / 1.28
14.     (REMOVE-NIL-3 LST).....6724 / 1.28
15.     (REMOVE-NIL-5 LST).....7379 / 1.17
16.     (REMOVE-NIL-6 LST).....8611 / 1.00 <slowest>

[Grrr1337]

This is Lee Mac right there, a.k.a. the List Manipulator. Thanks for posting this!