Topic: if #<%catch-all-apply-error%>

[mailmaverick]

I have a function which sometimes returns error.

For example (setq val (funcname argument1 argument 2))

Now sometimes val contains correct value. But sometimes, if there is an error within the function, it returns #<%catch-all-apply-error%>

(if (equal val #<%catch-all-apply-error%>) does not work.

How to check whether the function has returned correct value or error ?

Thanks.

[kpblc]

Smth like this
(if (vl-catch-all-error-p (setq  err (vl-catch-all-apply (function (lambda () ... )))))
(princ (strcat "\Error : " (vl-catch-all-error-message err)))
)

[Grrr1337]

Stick with kpblc's suggestion.
But I like alternatives, even if they seem useless... so:

Code: [Select]


(if (not (= 'VL-CATCH-ALL-APPLY-ERROR (type (setq err (vl-catch-all-apply (function (lambda () ... )))))))
< do stuff >
(princ (strcat "\Error : " (vl-catch-all-error-message err)))
)


[MP]

Given a couple quick defuns ...

Code: [Select]

(defun _Try ( try_statement / try_catch try_result )
    (if
        (vl-catch-all-error-p
            (setq try_catch
                (vl-catch-all-apply
                    (function
                        (lambda ( )
                            (setq try_result (eval try_statement))
                        )
                    )
                )
            )
        )
        (setq *try_errors* ;; global
            (cons
                (mapcar 'vl-prin1-to-string
                    (list
                        try_statement
                        (vl-catch-all-error-message try_catch)
                    )
                )   
                *try_errors* ;; global
            )
        )
    )
    try_result
)

Code: [Select]

(defun c:ShowErrors ( )
    (foreach error *try_errors*
        (princ "\n")
        (princ error)
    )
    (princ)
)

Code: [Select]

(defun c:ClearErrors ( )
    (setq *try_errors* nil)   
    (princ)
)
Then ...

(_Try '(/ 1 2.0))    >> 0.5 (normal execution)
(_Try '(/ 1 0))      >> nil (error caught)
(_Try '(strlen nil)) >> nil (error caught)
(_Try '(* "2" 2))    >> nil (error caught)

ShowErrors (LIFO):

((* "2" 2) "bad argument type: numberp: \"2\"")
((STRLEN nil) "bad argument type: stringp nil")
((/ 1 0) "divide by zero")

Cheers.

[mailmaverick]

Stick with kpblc's suggestion.
But I like alternatives, even if they seem useless... so:

Code: [Select]


(if (not (= 'VL-CATCH-ALL-APPLY-ERROR (type (setq err (vl-catch-all-apply (function (lambda () ... )))))))
< do stuff >
(princ (strcat "\Error : " (vl-catch-all-error-message err)))
)


Grrr1337's code did exactly what i wanted. Thanks to him and all others.

[Grrr1337]

Notice that

Code: [Select]

(not (= 'VL-CATCH-ALL-APPLY-ERROR (type ...is the same as

Code: [Select]

(not (vl-catch-all-error-p ...