Topic: Remove annotative properties on dimension entity

[Lupo76]

With the following line of code I can see all the properties associated to an object:
(vlax-dump-object vlaobj T)

Can you help me find the property that controls whether a dimension entity is annotative?

[T.Willey]

I just post a code I use to find stuff associated with entities:
https://www.theswamp.org/index.php?topic=51751.0

This will allow you to select an entity and step though the stuff that makes it up.  For you, select an entity, then in the dialog select the extension dictionary (this is the first ename coded by number 360), then select the ename under "AcDbContextDataManager", as this is the name of the dictionary but the ename is the item after it in the list, then you will see a dictionary title "ACDB_ANNOTATIONSCALES" and you will select the ename after that.  Then you will see a list of all the annotation scales, but you will have to look at them as they are named crypticly.

Once you find how to get there, I think you can use the 'dictremove' lisp function to remove one or more annoscales from the entity.

I don't use annoscales, but I hope this helps.

[Crank]

Code: [Select]

(defun is_Annotative (ent / xdata)
(setq xdata (cadr (assoc -3 (entget ent '("AcadAnnotative")))))
(and xdata (= (cdr (nth 4 xdata)) 1)) ; returns T or nil
)

[Lupo76]

Code: [Select]

(defun is_Annotative (ent / xdata)
(setq xdata (cadr (assoc -3 (entget ent '("AcadAnnotative")))))
(and xdata (= (cdr (nth 4 xdata)) 1)) ; returns T or nil
)

thank you!

[roy_043]

@ Crank:
Your code works in most cases, but not on annotative mleaders and block references (note: I use BricsCAD instead of AutoCAD).

[roy_043]

Code - Auto/Visual Lisp: [Select]

1. ; (ObjectAnnotative_P (vlax-ename->vla-object (car (entsel))))
2. (defun ObjectAnnotative_P (obj / cnt)
3.   (and
4.     (= :vlax-true (vla-get-hasextensiondictionary obj))
5.     (not ; Check for the presence of the "ACDB_ANNOTATIONSCALES" dictionary.
6.       (vl-catch-all-error-p
7.         (vl-catch-all-apply
8.           (function
9.             (lambda ()
10.               (setq cnt
11.                 (vla-get-count
12.                   (vla-item
13.                     (vla-item
14.                       (vla-getextensiondictionary obj)
15.                       "AcDbContextDataManager"
16.                     )
17.                     "ACDB_ANNOTATIONSCALES"
18.                   )
19.                 )
20.               )
21.             )
22.           )
23.         )
24.       )
25.     )
26.     (/= 0 cnt) ; Check if the dictionary is not empty.
27.   )
28. )

[Lee Mac]

I have the following in my library, but I can't recall if I've tested it under all possible circumstances:

Code - Auto/Visual Lisp: [Select]

1. (defun annotative-p ( ent / dic )
2.     (and
3.         (member  '(102 . "{ACAD_XDICTIONARY") (setq ent (entget ent)))
4.         (setq dic (cdr (assoc 360 ent)))
5.         (setq dic (dictsearch dic "acdbcontextdatamanager"))
6.         (setq dic (dictsearch (cdr (assoc -1 dic)) "acdb_annotationscales"))
7.         (dictnext (cdr (assoc -1 dic)) t)
8.     )
9. )