Topic: Rename all Dimstyles

[Biscuits]

Using AutoCAD 2015
Using LISP,  I'm looking to rename all dimstyles in a drawing file by adding a suffix.
Anyone have an idea where to start on a routine like this?

Thanks

[tedg]

Why don't you just use the "Rename" command, choose Dimstyles.


Rename * to *-YOURSUFFIX


(using wild cards)

[tedg]

Ok maybe not, I tried my example and it won't work as I thought...
Surely there's a way with rename and wildcards ??


Update,
for some reason you can add a prefix with my example, not a suffix:
Rename * to MYPREFIX-*

[MP]

Quick & Dirty is all I've time for ...

Code: [Select]

(defun _AddSuffixToTableEntries ( table suffix / pattern table_name old_name new_name )

    (setq
        pattern    (strcase (strcat "*" suffix))
        table_name (substr (vla-get-objectname (vla-item table 0)) 5)
        table_name (substr table_name 1 (- (strlen table_name) (strlen "TableRecord")))
    )

    (vlax-for entry table
        (princ
            (strcat
                "\n" table_name " \""
                (setq old_name (vla-get-name entry)) "\" "
                (if (wcmatch (strcase old_name) pattern)
                    "<no need to rename>"
                    (if
                        (vl-catch-all-error-p
                            (vl-catch-all-apply 'vla-put-name
                               (list entry (setq new_name (strcat old_name suffix)))
                            )
                        )
                        "<cannot rename>"
                        (strcat "renamed to <\"" new_name "\">")
                    )
                )
            )
        )
    )

    (princ)

)   
Example usage ...

Code: [Select]

(vl-load-com)

(_AddSuffixToTableEntries
    (vla-get-dimstyles (vla-get-activedocument (vlax-get-acad-object)))
    "_WTF"
)