Topic: LISP help

[aswin]

Hi every one,
i have got a lisp from my friend.. this lisp is used to align objects in an even spacing.. the problem is.. we can't give a minimum spacing distance between objects and there is no option for align to a polyline ... because the osnap mode is not working when the command is active... please help.. the Lisp is given below

Code: [Select]

(defun _bboxandmid (obj / a b l)
  (vla-getboundingbox obj 'a 'b)
  (list (car (setq l (mapcar 'vlax-safearray->list (list a b))))
        (apply '(lambda (a b) (mapcar '(lambda (a b) (/ (+ a b) 2.)) a b)) l)
        (cadr l)
  )
)

(defun ss->lst (ss / i l)
  (if (eq (type ss) 'pickset)
    (repeat (setq i (sslength ss))
      (setq l (cons (vlax-ename->vla-object (ssname ss (setq i (1- i)))) l))
    )
  )
)




(defun c:spb (/ lst p1 g p2 a d)
  (if (and (setq lst (ss->lst (ssget "_:L")))
           (setq p1 (getpoint "\nSpecify first point: "))
      )

    (while (eq 5 (car (setq g (grread t 15 0))))
      (redraw)
      (grdraw p1 (polar (setq p2 (cadr g)) (angle p1 p2) 10000000.) 1 -1)

      (setq p1 (trans p1 1 0)
            p2 (trans p2 1 0)
            a  (angle p1 p2)
            d  (/ (distance p1 p2) (float (length lst)))
      )

      (vla-move (car lst) (vlax-3d-point (cadr (_bboxandmid (car lst)))) (vlax-3d-point p1))

      (mapcar
        '(lambda (o1 o2 / l)
           (vla-move o2
                     (vlax-3d-point (cadr (_bboxandmid o2)))
                     (vlax-3d-point
                       (polar (cadr (setq l (_bboxandmid o1)))
                              a
                              (+ d (distance (car l) (caddr l)))
                       )
                     )
           )
         )
        lst
        (cdr lst)
      )
    )
  )
  (redraw)
  (princ)
)

[ribarm]

It's not an answer to your request, but small remark...
I'd replace this value : 10000000.
with (distance p1 p2) syntax...

[CAB]

His friend: http://www.cadtutor.net/forum/showthread.php?58485-Spacing-LISP&p=396506&viewfull=1#post396506

[aswin]

@CAB  Thanks dude... for showing me the person who created this LISP   

[didier]

Coucou

If you want to learn, you should not copy and paste but to understand and thus learn you should begin with the base. 

"big coders" on the site one made active the osnap with grread ...

amicalement

[Mark]

Is it time to start another beginners thread?

[didier]

Coucou

I think so because a lot of people "copy-paste" the code and then asks questions why it does not work.
but this site is not really a beginner site...

[dgorsman]

This is very much a beginner site - lots of help to understand the common practices and algorithms of coding as they apply to LISP but also in general.  But copy'n'paste isn't the starting point of learning any more than taking a photo of the Mona Lisa makes someone the next Davinci.  So yeah, I think a beginners thread would be a good addition.

[Mark]

I'll bring in my book; AutoLISP Programming: Principles and Techniques tomorrow for reference.

[kdub_nz]

From http://lispexpert.blogspot.com.au/
AutoCAD expert's Visual LISP as an e-book. by Reinaldo N. Togores
From beginner onward ....

Volume 1, The Language and its Development Environment, includes Parts 1 an 2.

Volume 2, Controlling AutoCAD from Visual LISP, includes Part 3.

Volume 3, Programming 3D. Solids, Meshes & Surfaces, includes Part 4.

Volume 4, Advanced Programming Techniques, includes Part 5.

[Mark]

I'll bring in my book; AutoLISP Programming: Principles and Techniques tomorrow for reference.

Forgot the damn book! *sigh* Sorry.

[aswin]

so , no help?? 

[ur_naz]

maybe try to use vlax-curve-getClosestPointTo

[roy_043]

@ aswin:
Maybe you will like this version better.
Change:

Code: [Select]

((osnap p2 "_END,_MID"))to suit your needs.

Code:

Code - Auto/Visual Lisp: [Select]

1. (defun _bboxandmid (obj / a b l)
2.   (vla-getboundingbox obj 'a 'b)
3.   (list (car (setq l (mapcar 'vlax-safearray->list (list a b))))
4.         (apply '(lambda (a b) (mapcar '(lambda (a b) (/ (+ a b) 2.)) a b)) l)
5.         (cadr l)
6.   )
7. )
8.  
9. (defun ss->lst (ss / i l)
10.   (if (eq (type ss) 'pickset)
11.     (repeat (setq i (sslength ss))
12.       (setq l (cons (vlax-ename->vla-object (ssname ss (setq i (1- i)))) l))
13.     )
14.   )
15. )
16.  
17. (defun c:spb (/ doc fac g lst p1 p2 vec)
18.   (if
19.     (and
20.       (setq lst (ss->lst (ssget "_:L")))
21.       (or
22.         (< 1 (length lst))
23.         (prompt "\nSelection set must contain at least 2 entities ")
24.       )
25.       (or
26.         (setq fixDist (getdist "\nFixed distance or Enter: "))
27.         T
28.       )
29.       (setq p1 (getpoint "\nSpecify first point: "))
30.     )
31.     (progn
32.       (setq doc (vla-get-activedocument (vlax-get-acad-object)))
33.       (vla-endundomark doc) ; End open undo group.
34.       (vla-startundomark doc)
35.       (princ "\nSpecify second point: ")
36.       (while (eq 5 (car (setq g (grread t 15 0))))
37.         (redraw)
38.         (setq p2 (cadr g))
39.         (setq p2
40.           (cond
41.             ((osnap p2 "_END,_MID")) ; Change to suit your needs.
42.             (p2)
43.           )
44.         )
45.         (if (not (equal p1 p2 1e-4))
46.           (progn
47.             (grdraw p1 p2 1 -1)
48.             (setq fac
49.               (cond
50.                 (fixDist (/ (distance p1 p2) fixDist))
51.                 ((1- (length lst)))
52.               )
53.             )
54.             (setq vec (trans (mapcar '(lambda (crd1 crd2) (/ (- crd2 crd1) fac)) p1 p2) 1 0 T))
55.             (vlax-invoke (car lst) 'move (cadr (_bboxandmid (car lst))) (trans p1 1 0))
56.             (mapcar
57.               '(lambda (o1 o2 / l)
58.                  (vlax-invoke o2 'move (cadr (_bboxandmid o2)) (mapcar '+ (cadr (_bboxandmid o1)) vec))
59.                )
60.               lst
61.               (cdr lst)
62.             )
63.           )
64.         )
65.       )
66.       (vla-endundomark doc)
67.     )
68.   )
69.   (redraw)
70.   (princ)
71. )

[aswin]

@roy_043:
   PERFECT!!!! Sir, this is what i was looking for.... thank you soo much...