Topic: sum text contained number ?

[dussla]

sorry my poor english
if you see my attached , friends understand ?
pls pls can you help ?

[Marc'Antonio Alessi]

Just to start:

Code: [Select]

(defun Test (Str001 Str002 / Num001 Num002 Nm1Str)
  (setq
    Num001 (atof Str001)   Num002 (atof Str002)   Nm1Str (rtos Num001)
  )
  (strcat (rtos (+ Num001 Num002)) (substr Str001 (1+ (strlen Nm1Str))))
)
Comand: (Test "1.3m-b" "1.3m-b") "2.6m-b"
Comand: (Test "1.3m-b" "3.3m-b") "4.6m-b"
Comand: (Test "2100-a" "3100-a") "5200-a"
Comand: (Test "2.72m2-c" "3.72m2-c") "6.44m2-c"
Comand: (Test "212.12f-d" "322.12f-d") "534.24f-d"
Comand: (Test "27.05kg-e" "60.05kg-e") "87.1kg-e"

[ronjonp]

Like so? 

Code - Auto/Visual Lisp: [Select]

1. (defun c:sumitupyo (/ fuzz ip n1 o o2 o3 r ss suf txt x)
2.   ;; 05.24.2016 RJP
3.   ;; Sums up text items on similar Y plane
4.   (vl-load-com)
5.   (if
6.     (and ;; Get text
7.          (setq ss (ssget ":L" '((0 . "Text"))))
8.          ;; Convert selection set to list
9.          (setq ss (mapcar 'vlax-ename->vla-object (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))))
10.          ;; Sort by smalles X coordinate
11.          (setq
12.            ss (vl-sort ss
13.                        '(lambda (a b)
14.                           (< (car (vlax-get a 'insertionpoint)) (car (vlax-get b 'insertionpoint)))
15.                         )
16.               )
17.          )
18.     );; While we have a list
19.      (while (setq o (car ss))
20.        ;; Remove the first item
21.        (setq ss (cdr ss))
22.        ;; Get insertion point
23.        (setq ip (vlax-get o 'insertionpoint))
24.        ;; Get texstring
25.        (setq txt (vla-get-textstring o))
26.        ;; Convert text to number
27.        (setq n1 (atof txt))
28.        ;; Get suffix
29.        (setq suf (substr txt (1+ (strlen (rtos n1)))))
30.        ;; Fuzz value = 1/2 text height
31.        (setq fuzz (* 0.5 (vla-get-height o)))
32.        ;; Find the other item in the list on the same Y plane within a fuzz value
33.        (setq o2
34.               (vl-remove-if-not '(lambda (x) (equal (cadr ip) (cadr (vlax-get x 'insertionpoint)) fuzz))
35.                                 ss
36.               )
37.        )
38.        ;; Remove those items from the list
39.        (mapcar '(lambda (x) (setq ss (vl-remove x ss))) o2)
40.        ;; Add the values
41.        (setq
42.          r (strcat
43.              (rtos
44.                (apply '+ (mapcar '(lambda (x) (atof (vla-get-textstring x))) (append (list o) o2)))
45.              )
46.              suf
47.            )
48.        )
49.        ;; If we've added items, make a copy of the last text object & put summed value
50.        (if o2
51.          (progn (setq o3 (vlax-invoke (last o2) 'copy))
52.                 (vla-put-color o3 3)
53.                 (vlax-invoke o3
54.                              'move
55.                              ip
56.                              (polar ip
57.                                     (angle ip (vlax-get (car o2) 'insertionpoint))
58.                                     (distance ip (vlax-get (car o2) 'insertionpoint))
59.                              )
60.                 )
61.                 (vla-put-textstring o3 r)
62.          )
63.        )
64.      )
65.   )
66.   (princ)
67. )

[Lee Mac]

Nice one Ron 

[ronjonp]

Nice one Ron 

Thanks Lee 

[Lee Mac]

I'll wager that the OP actually wants a general purpose program will no constraints on the position of the text items, but your program exactly performs to the requirements given, so they can't complain.

[ronjonp]

I'll wager that the OP actually wants a general purpose program will no constraints on the position of the text items, but your program exactly performs to the requirements given, so they can't complain.

I bet you're right .. but for a freebie it's a good start 

[Lee Mac]

I'll wager that the OP actually wants a general purpose program will no constraints on the position of the text items, but your program exactly performs to the requirements given, so they can't complain.

I bet you're right .. but for a freebie it's a good start 

Oh definitely 

[Marc'Antonio Alessi]

Ron you have done an excellent job but, I believe, the greatest satisfaction I think it needs to come from the OP to know if his request was fulfilled.
Unfortunately many, solved their need, do not bother to inform future readers of these messages if the given problem has been solved and how. 

See also: https://www.theswamp.org/index.php?topic=51489.0.

I think a new acronym (Mosquito, Swamp Rat, Water Moccasin...) needs for these gentlemen: NED (not educated person). 
Ciao.

[kdub_nz]

Marc'Antonio,
Yes, posters who don't bother to respond are annoying, but I don't advocate forcing them to wear a "scarlet letter".

gentle nudges sometimes work.

A post by a peer, as you have done, lauding the veracity of a solution does help those who follow.

Thanks.

[Marc'Antonio Alessi]

Marc'Antonio,
Yes, posters who don't bother to respond are annoying, but I don't advocate forcing them to wear a "scarlet letter".

gentle nudges sometimes work.

A post by a peer, as you have done, lauding the veracity of a solution does help those who follow.

Thanks.

Prego. I agree. 

[dussla]

perpect  wow  wow
friend  is really genius
wow  wow  wow ~~~~

really thank you ~~~

[dussla]

thank you   friends

but there is some problem ~~
pls check ~~~
sorry for my many ask

if you see image  , you can see error~

[kdub_nz]

dussla,

You've been visiting here for 9 or 10  years.
Have you learnt how to read code yet ?
How much code writing have you done.
How many posts have you made trying to help people.

The reason you are getting the result you get is because of the color of your text.

[roy_043]

..
The reason you are getting the result you get is because of the color of your text.

Reading ronjons code I think the (shifted) Y coordinates are causing this issue.