Author Topic: Lisp routine working for some users, not for others (Read 1676 times)

Dan · « **on:** May 20, 2016, 10:57:21 AM »

I created this program for quickly labelling dados of varying sizes in our drawings. On a few users' machines, this program runs perfectly and does what it's supposed to. There's others for whom the code aborts after putting <Selection set:blahblah> into the message window.

The problem occurs in the section starting on Line 119.

Is there a different way to do what I've got here, or is there some system variable that I can temporarily change to prevent the routine stopping for those users?

Code - Auto/Visual Lisp: [Select]

;Set defaults
(setq dadwid "3/4")
(setq daddep "1/4")
 
(defun c:dado ()
  (setq echovar (getvar "cmdecho"))
  (setvar 'cmdecho 0)
;Get origin point for multileader
  (setq orig (getpoint "\nDado - Leader Origin"))
  (setq x (car orig))
  (setq y (cadr orig))
;Choose one of 8 layouts with real-time preview
  (princ "\nChoose orientation: ")
  (setq loop 1)
;Update on mouse movement
  (while (and (setq gr (grread T 12 0)) loop)
    (cond
      ((= (car gr) 5) (preview)) ;On movement
      ((= (car gr) 3)
       (setq dest (cadr gr))
       (setq loop nil)
      ) ;On click, store click location, end routine
      (T (redraw) (setq loop nil))
    )
  )
;Display current default size, offer user option to change it
  (setq dquestion
         (strcat
           "\nEnter New Dado Depth (Leave blank to skip dado size entry) <"
           daddep
           "\"D x "
           dadwid
           "\"W Dado>:"
          )
  )
  (setq danswer (getstring
                  dquestion
                )
  )
;Skips both entry options if the user is satisfied with the current values
  (if (/= danswer "")
    (progn
      (setq daddep danswer)
      (setq
        dquestion (strcat
                    "\nEnter New Dado Width or (Enter) to confirm: <"
                    daddep
                    "\"D x "
                    dadwid
                    "\"W Dado>:"
                   )
      )
      (setq danswer2 (getstring
                       dquestion
                     )
      )
      (if (/= danswer2 "")
        (setq dadwid danswer2)
      )
    )
  )
;Set X multiplier, Y multiplier, angle of rotation based on which hemiquadrant was chosen
  (cond
    ((= ang 1)
     (setq xd 1.0
           yd 1.0
           rd 0.0
     )
    )
    ((= ang 2)
     (setq xd -1.0
           yd 1.0
           rd -90.0
     )
    )
    ((= ang 3)
     (setq xd 1.0
           yd 1.0
           rd 90.0
     )
    )
    ((= ang 4)
     (setq xd -1.0
           yd 1.0
           rd 0.0
     )
    )
    ((= ang 5)
     (setq xd -1.0
           yd -1.0
           rd 0.0
     )
    )
    ((= ang 6)
     (setq xd -1.0
           yd 1.0
           rd 90.0
     )
    )
    ((= ang 7)
     (setq xd 1.0
           yd 1.0
           rd -90.0
     )
     
    )
    ((= ang 8)
     (setq xd 1.0
           yd -1.0
           rd 0.0
     )
    )
  )
  (redraw)
; 
;
;
;THIS SECTION IS WHERE THE GLITCH HAPPENS
  (command "leader"
           orig
           (list (xm 2) (ym 2))
           ""
           (setq leaderset (ssget "_L")) ;Start selection set, grabbing multileader line just created - ERROR OCCURS HERE FOR SOME USERS, NO ERROR FOR OTHERS
           ""
           (strcat daddep "\"D x " dadwid "\"W Dado")
           ""
  )
  (setq leaderset (ssadd (entlast) leaderset)) ;Adds the text to the selection set
  (command "rotate" leaderset "" orig rd) ; If it's a vertical-oriented label, rotates as needed
  (setvar "cmdecho" echovar)
  (princ)
)
 
 
(defun horizontal ()
 
  (grvecs (list -6
                orig
                (list (xm 1) (ym 2))
                (list (xm 1) (ym 2))
                (list (xm 2) (ym 2))
                (list (xm 2.5) (ym 1.2))
                (list (xm 2.5) (ym 2.8))
                (list (xm 2.5) (ym 2.8))
                (list (xm 17) (ym 2.8))
                (list (xm 17) (ym 2.8))
                (list (xm 17) (ym 1.2))
                (list (xm 17) (ym 1.2))
                (list (xm 2.5) (ym 1.2))
          )
  )
)
(defun vertical ()
 
  (grvecs (list -6
                orig
                (list (xm 2) (ym 1))
                (list (xm 2) (ym 1))
                (list (xm 2) (ym 2))
                (list (xm 1.2) (ym 2.5))
                (list (xm 2.8) (ym 2.5))
                (list (xm 2.8) (ym 2.5))
                (list (xm 2.8) (ym 17))
                (list (xm 2.8) (ym 17))
                (list (xm 1.2) (ym 17))
                (list (xm 1.2) (ym 17))
                (list (xm 1.2) (ym 2.5))
          )
  )
)
;Takes the XD directional multiplier and uses it plus the absolute value given
;to find the relevant X coordinate.
(defun xm (xm1 /)
  (cond
    ((= xd 1.0) (+ x xm1))
    ((= xd -1.0) (- x xm1))
  )
)
;Same as XM but for Y axis
(defun ym (ym1 /)
  (cond
    ((= yd 1.0) (+ y ym1))
    ((= yd -1.0) (- y ym1))
  )
)
(defun preview ()
  (setq ppt (list (car (cadr gr)) (cadr (cadr gr))))
  (redraw)
  (setq
    ang (fix
          (+ 1 (* 4 (/ (angle (list (car orig) (cadr orig)) ppt) pi)))
        )
  )
;Sets variable "Ang" to an integer 1-8 corresponding to the number of the half-quadrant the
;mouse cursor is currently in relative to the selected startpoint
  (setq
    realang (* 180 (/ (angle (list (car orig) (cadr orig)) ppt) pi))
  )
;Conditional statements to show the preview above or below the X and Y axis, as well as
;whether to orient horizontally or vertically
  (cond
    ((= 1 ang)
     (setq xd 1.0
           yd 1.0
     )
 
     (horizontal)
    )
    ((= 2 ang)
     (setq xd 1.0
           yd 1.0
     )
     (vertical)
    )
    ((= 3 ang)
     (setq xd -1.0
           yd 1.0
     )
     (vertical)
    )
    ((= 4 ang)
     (setq xd -1.0
           yd 1.0
     )
     (horizontal)
    )
    ((= 5 ang)
     (setq xd -1.0
           yd -1.0
     )
     (horizontal)
    )
    ((= 6 ang)
     (setq xd -1.0
           yd -1.0
     )
     (vertical)
    )
    ((= 7 ang)
     (setq xd 1.0
           yd -1.0
     )
     (vertical)
    )
    ((= 8 ang)
     (setq xd 1.0
           yd -1.0
     )
     (horizontal)
    )
  )
)
 

hmspe · « **Reply #1 on:** May 20, 2016, 11:10:01 AM »

Autocad? What year(s)? Base or vertical?

Dan · « **Reply #2 on:** May 20, 2016, 11:37:54 AM »

AutoCAD 2014, base.

Matt__W · « **Reply #3 on:** May 20, 2016, 11:43:28 AM »

All of your variables are defined globally, meaning they don't lose their value once the program ends, so I would be inclined to think that values of some of the variables are being pulled from other programs that are also using global variables with the same name.

Could you maybe replace SSGET _L with ENTLAST and see what happens?

ronjonp · « **Reply #4 on:** May 20, 2016, 11:48:16 AM »

What M@hem said. Try localizing your variables.

Quote

[CHECKING TEXT <Untitled-2> loading... SELECTION]
.
; === Top statistic:
; Global variables: (DADWID)
.
; === Top statistic:
; Global variables: (DADDEP)
.
; === Top statistic:
; Global variables: (ANG DADDEP DADWID DANSWER DANSWER2 DEST DQUESTION ECHOVAR GR LEADERSET LOOP ORIG RD X XD Y YD)
; Function definition (with number of arguments): ((C:DADO . 0))
.
; === Top statistic:
; Global variables: (ORIG)
; Function definition (with number of arguments): ((HORIZONTAL . 0))
.
; === Top statistic:
; Global variables: (ORIG)
; Function definition (with number of arguments): ((VERTICAL . 0))
.
; === Top statistic:
; Global variables: (X XD)
; Function definition (with number of arguments): ((XM . 1))
.
; === Top statistic:
; Global variables: (Y YD)
; Function definition (with number of arguments): ((YM . 1))
.
; === Top statistic:
; Global variables: (ANG GR ORIG PPT REALANG XD YD)
; Function definition (with number of arguments): ((PREVIEW . 0))
; Check done.

Dan · « **Reply #5 on:** May 20, 2016, 02:21:42 PM »

Tried switching to entlast, tried localizing variables, nothing has worked. I tried a few experiments, and finally figured it out. It seems having the LISP selection in the middle of the multileader command is what's causing the issues - and only for some people.

To work around it, this is the code that was used instead:

Code - Auto/Visual Lisp: [Select]

(setq prioritem (entlast))
    (command "leader"
           orig
           (list (xm 2) (ym 2))
           "a"
           ""
           "m"
           (strcat daddep "\"D x " dadwid "\"W Dado")
           ""
  )
  (setq leaderset (ssadd))
  (setq leaderset (ssadd (entlast) leaderset))
  (setq leaderset (ssadd (entnext prioritem) leaderset))
  (command "rotate" leaderset "" orig rd)
 

Thank you all for your help! Without having your suggestions as starting points, I probably would not have figured this out.

ChrisCarlson · « **Reply #6 on:** May 23, 2016, 09:34:39 AM »

Definitely good practice localize all of your variables and specifically globalize variables with asterisks ex; *var*.

Sounds like there is an issue with SSGET getting the last entity. Looking at your routine really quick I do not see an entity created before line 119?

Refernce lee-mac's website on the SSGET function, specifically "L".

Quote

Selects the last visible object added to the drawing database.

Caution: when using the "L" selection method in an MDI environment, you cannot always count on the last object drawn to remain visible. For example, if your application draws a line, and the user subsequently minimizes or cascades the AutoCAD drawing window, the line may no longer be visible. If this occurs, ssget with the "L" option will return nil.

http://www.lee-mac.com/ssget.html

CAB · « **Reply #7 on:** May 23, 2016, 10:26:48 AM »

I would take a different approach. Use these functions: Call one before the command & the other after the command.

Code: [Select]

  ;; Rune Wold and Michael Puckett - modified ale_lastent ale_ss-after
  (defun ale_lastent (/ entnam outval) 
    (and
      (setq outval (entlast))
      (while (setq entnam (entnext outval))
        (setq outval entnam)
      )
    )
    outval
  )

  (defun ale_ss-after (entnam / entnxt selset)
    (cond
      ((not entnam) (ssget "_X"))
      ((setq entnxt (entnext entnam))
       (setq selset (ssadd entnxt))
       (while (setq entnxt (entnext entnxt))
         (if (entget entnxt)
           (ssadd entnxt selset)
         )
       )
       selset
      )
    )

This will get the leader & text objects.

Dan · « **Reply #8 on:** May 23, 2016, 04:52:56 PM »

Chris - I stopped using SSGet entirely. I wound up changing it to store the last entity drawn before creating the leader, then after the leader and text item are created, create an empty selection set, add the Entnext from that stored item (The leader) and then add the EntLast (the text attached to the leader). Not very versatile but it does what I need it to.

CAB - I'm not good enough at this point to be able to look through that code and see clearly what it does. I know this is a "stupid newbie" kind of question, but could you explain what those two functions are doing?

MP · « **Reply #9 on:** May 23, 2016, 05:09:09 PM »

The first returns the very last entity in the drawing, the second returns a selection set of every entity after the one you supply as an argument.

Marc'Antonio Alessi · « **Reply #10 on:** May 24, 2016, 03:18:38 AM »

Full history (?) and description:

Code: [Select]

; Function: ALE_LastEnt - original by Rune Wold and Michael Puckett (lastent)  
;
; Version 1.01 - 20/12/2004 - modified with (and ...)
;
; Description:
;   get the absolute last entity in the database,
;   for problems in >=r15 in blocks with attrib, and polylines
;
; Arguments: none
;
; Return Values:
;   An entity name;
;   otherwise nil, if there are no entities in the current drawing
;
; Example: (setq marker (ALE_LastEnt)) see ALE_Ss-After
;
(defun ALE_LastEnt ( / EntNam OutVal)
  (and
    (setq OutVal (entlast))
    (while (setq EntNam (entnext OutVal))
      (setq OutVal EntNam)
    )
  )
  OutVal
)
; 
; Marc'Antonio Alessi
; Function: ALE_Ss-After thanks to Michael Puckett (Ss-After)
;
; Version 1.01 - 20/12/2004 for empty DWG
; Version 1.02 - 30/09/2005 
; Version 1.03 - 06/05/2010 to support Bricscad
;
; Description:
;   get a selection set of items after EntNam in the database
;
; Arguments: An entity name
;
; Return Values:
;   A selection set;
;   otherwise nil, if there are no entities after EntNam
;
; Examples:
;   (setq marker (ALE_LASTENT)) ...create new entities...
;   to include reference entity:
;   (command "_.MOVE" (ALE_SS-AFTER marker) marker "" ...) 
;   Note: NOT valid if marker is a SEQEND of
;   blocks with attrib or old polylines (PLINETYPE = 0)
;
;   not include reference entity:
;   (command "_.MOVE" (ALE_SS-AFTER marker) "" ...) 
;
(defun ALE_Ss-After (EntNam / SelSet)
  (cond 
    ( (not EntNam) (ssget "_X" '((0 . "~VIEWPORT"))) ); "~VIEWPORT" x Bricscad
    ( (setq EntNam (entnext EntNam))
      (setq SelSet (ssadd EntNam))
      (while (setq EntNam (entnext EntNam))
        (if (entget EntNam) (ssadd EntNam SelSet))
      )
      SelSet
    )
  )
)

Dan · « **Reply #11 on:** May 24, 2016, 08:11:24 AM »

Ah, that's definitely more versatile and elegant than what I wound up slapping in there - thank you very much!

ChrisCarlson · « **Reply #12 on:** May 24, 2016, 08:17:11 AM »

Can I ask what the workflow is? Relying on the last entity in a drawing created outside of a routine can be problematic. Perhaps the creation of that entity and this routine can be consolidated?

CAB · « **Reply #13 on:** May 24, 2016, 09:44:23 AM »

substitute this:

Code: [Select]

;THIS SECTION IS WHERE THE GLITCH HAPPENS
  (command "leader"
       orig
       (list (xm 2) (ym 2))
       ""
       (setq leaderset (ssget "_L")) ;Start selection set, grabbing multileader line just created - ERROR OCCURS HERE FOR SOME USERS, NO ERROR FOR OTHERS
       ""
       (strcat daddep "\"D x " dadwid "\"W Dado")
       ""
  )
  (setq leaderset (ssadd (entlast) leaderset)) ;Adds the text to the selection set

with this:

Code: [Select]

; Function: ALE_LastEnt - original by Rune Wold and Michael Puckett (lastent) 
;
; Version 1.01 - 20/12/2004 - modified with (and ...)
;
; Description:
;   get the absolute last entity in the database,
;   for problems in >=r15 in blocks with attrib, and polylines
;
; Arguments: none
;
; Return Values:
;   An entity name;
;   otherwise nil, if there are no entities in the current drawing
;
; Example: (setq marker (ALE_LastEnt)) see ALE_Ss-After
;
(defun ALE_LastEnt ( / EntNam OutVal)
  (and
    (setq OutVal (entlast))
    (while (setq EntNam (entnext OutVal))
      (setq OutVal EntNam)
    )
  )
  OutVal
)
;
; Marc'Antonio Alessi
; Function: ALE_Ss-After thanks to Michael Puckett (Ss-After)
;
; Version 1.01 - 20/12/2004 for empty DWG
; Version 1.02 - 30/09/2005
; Version 1.03 - 06/05/2010 to support Bricscad
;
; Description:
;   get a selection set of items after EntNam in the database
;
; Arguments: An entity name
;
; Return Values:
;   A selection set;
;   otherwise nil, if there are no entities after EntNam
;
; Examples:
;   (setq marker (ALE_LASTENT)) ...create new entities...
;   to include reference entity:
;   (command "_.MOVE" (ALE_SS-AFTER marker) marker "" ...)
;   Note: NOT valid if marker is a SEQEND of
;   blocks with attrib or old polylines (PLINETYPE = 0)
;
;   not include reference entity:
;   (command "_.MOVE" (ALE_SS-AFTER marker) "" ...)
;
(defun ALE_Ss-After (EntNam / SelSet)
  (cond
    ( (not EntNam) (ssget "_X" '((0 . "~VIEWPORT"))) ); "~VIEWPORT" x Bricscad
    ( (setq EntNam (entnext EntNam))
      (setq SelSet (ssadd EntNam))
      (while (setq EntNam (entnext EntNam))
        (if (entget EntNam) (ssadd EntNam SelSet))
      )
      SelSet
    )
  )
)

(setq entlast (ALE_LastEnt))
;THIS SECTION IS WHERE THE GLITCH HAPPENS
  (command "leader"
       orig
       (list (xm 2) (ym 2))
       ""
       ""
       (strcat daddep "\"D x " dadwid "\"W Dado")
       ""
  )

  (setq lst (mapcar 'cadr (ssnamex (ALE_Ss-After lastent)))) 
  (setq ent (vl-remove-if-not '(lambda(e) (equal (assoc 0 (entget e)) '(0 . "LEADER"))) lst))
  (setq leaderset (ssadd ent leaderset)) ;Adds the text to the selection set

Note that I did not test the COMMAND leader function so it may need adjustment.

Dan · « **Reply #14 on:** May 24, 2016, 04:57:50 PM »

Chris - this is for annotating shop drawings. We're a store fixture shop, and almost all of our construction uses dados of varying depths. I'm the CNC programmer, and usually the last stop before drawings go out to the shop, as well as doing drafting myself when needed. I wanted to be able to annotate my dados quickly and neatly without having to either make a bunch of macros or stop and adjust the position of each leader. Rather than relying on a standard macro and then going back and editing, this lets me simply run this lisp and generate an annotation in the orientation needed with a couple of mouse clicks, and allows for adjusting the width and depth with a minimal number of keystrokes.

It's one of a series of simple routines I've written that save time on repetitive tasks, and it is doubtlessly the most complicated one I've written. I'm certainly not going to pretend it's anything professional level, but thanks to the help of everyone on here, it now does the job it is needed to do, and will work for all members of the engineering department.

News:

Author Topic: Lisp routine working for some users, not for others (Read 1676 times)

Dan

Lisp routine working for some users, not for others

hmspe

Re: Lisp routine working for some users, not for others

Dan

Re: Lisp routine working for some users, not for others

Matt__W

Re: Lisp routine working for some users, not for others

ronjonp

Re: Lisp routine working for some users, not for others

Dan

Re: Lisp routine working for some users, not for others

ChrisCarlson

Re: Lisp routine working for some users, not for others

CAB

Re: Lisp routine working for some users, not for others

Dan

Re: Lisp routine working for some users, not for others

MP

Re: Lisp routine working for some users, not for others

Marc'Antonio Alessi

Re: Lisp routine working for some users, not for others

Dan

Re: Lisp routine working for some users, not for others

ChrisCarlson

Re: Lisp routine working for some users, not for others

CAB

Re: Lisp routine working for some users, not for others

Dan

Re: Lisp routine working for some users, not for others