Topic: Slide Objects Along a Polyline

[MSTG007]

Is it possible to slide objects along a polyline that has curves in?

Here is the situation. I have a long polyline that is curvy. I have a bunch or park stalls (lines) that are already drawn 9 feet wide from each other.

If I could select the objects (stalls), select a base point, pick the polyline, then drag my cursor where I was it to slide all those stalls?

If the stalls where a block would that be easier?

Hopefully, I am explaining this more complicated than it really is.

[ChrisCarlson]

This is just an array, path array to be more specific. If you keep it associative it will be dynamic after execution of the command.

[Lee Mac]

If you don't have access to an AutoCAD version which offers a Path Array, search for 'Copy Along Curve' or 'Space Along Curve'.

EDIT: Here they are:
https://www.theswamp.org/index.php?topic=32789.0
https://www.theswamp.org/index.php?topic=34792.0

[ribarm]

Yes, if selected entities were grouped into block it would be easier to move them all and manipulate... I suppose you can make it insertion point to be on curve when bmaking... Then grip block and stretch/move with "nearest" osnap along curve... Haven't checked, but I suppose should be preview displayed while dragging...

[irneb]

This is just an array, path array to be more specific. If you keep it associative it will be dynamic after execution of the command.

Even in older ACad's it is possible through the measure & divide commands (given the objects you wish to "array" you first "grouped" as a block). Though the newer dynamic array along a path does help with making adjustments later.

[MSTG007]

This is kinda what I am looking at. Select the objects and slide them along a polyline while keeping the relative space in between.

[irneb]

Well the array by path allows something similar to that. See attached video screen capture.


However, those corner cases are going to be difficult. I'm assuming you want some form of minimum gap. That is definitely not a built-in command.

[MSTG007]

With the array, I notice to slide it one way I have to drag the polyline vertex. If I would want to slide the vertex of the array (start point); a box comes up to say continue or cancel the operation. it would be cool if you could slide that vertex of that array along that path. (again unless I am missing something)

[ribarm]

With the array, I notice to slide it one way I have to drag the polyline vertex. If I would want to slide the vertex of the array (start point); a box comes up to say continue or cancel the operation. it would be cool if you could slide that vertex of that array along that path. (again unless I am missing something)

Well like I said, have you tried to turn on "Nearest" OSNAP and drag vertex / end of path ?

[ronjonp]

This is kinda what I am looking at. Select the objects and slide them along a polyline while keeping the relative space in between.

Maybe this will get you started ( no error checking ).

Code - Auto/Visual Lisp: [Select]

1. (defun c:ladder (/ d e1 e2 l n p1 p2)
2.   (vl-load-com)
3.   (if (and (setq d (getdist "\nEnter spacing: "))
4.            (setq e1 (car (entsel "\nPick object to copy stuff on: ")))
5.            (setq e2 (car (entsel "\nPick parallel object: ")))
6.       )
7.     (progn (setq n (vlax-curve-getdistatparam e1 (vlax-curve-getstartparam e1)))
8.            (setq l (vlax-curve-getdistatparam e1 (vlax-curve-getendparam e1)))
9.            (while (<= n l)
10.              (setq p1 (vlax-curve-getpointatdist e1 n))
11.              (setq p2 (vlax-curve-getclosestpointto e2 p1))
12.              (entmakex (list '(0 . "line") '(8 . "stripe") (cons 10 p1) (cons 11 p2)))
13.              (setq n (+ n d))
14.            )
15.     )
16.   )
17.   (princ)
18. )

[steve.carson]

I've had to design these types of lots before too. The difficulty (like Irneb mentioned) is maintaining a consistent minimum distance between stalls when there is a mix of inside and outside curves. I'll usually break up the pline into pieces that only contain one or the other (inside or outside curves), then for the inside ones offset it the length of the stall and use that pline for the array.

I don't think my math skills are on par with handling this through lisp, since the array spacing on the inside curves will be dependent on the stall length and radius of the curve.

[ronjonp]

I've had to design these types of lots before too. The difficulty (like Irneb mentioned) is maintaining a consistent minimum distance between stalls when there is a mix of inside and outside curves. I'll usually break up the pline into pieces that only contain one or the other (inside or outside curves), then for the inside ones offset it the length of the stall and use that pline for the array.

I don't think my math skills are on par with handling this through lisp, since the array spacing on the inside curves will be dependent on the stall length and radius of the curve.

Here's a hack to somewhat account for the minimum distance on the ends for inside curves.

Code - Auto/Visual Lisp: [Select]

1. (defun c:ladder (/ d d2 e1 e2 i l n p1 p2 tmp)
2.   ;; RJP 05.03.2016
3.   (vl-load-com)
4.   ;; Hack precision :)
5.   (setq i 0.01)
6.   (if (and (setq d (getdist "\nEnter spacing: "))
7.            (setq e1 (car (entsel "\nPick object to copy stuff on: ")))
8.            (setq e2 (car (entsel "\nPick parallel object: ")))
9.       )
10.     (progn (setq n (vlax-curve-getdistatparam e1 (vlax-curve-getstartparam e1)))
11.            (setq l (vlax-curve-getdistatparam e1 (vlax-curve-getendparam e1)))
12.            (while (<= n l)
13.              (setq p1 (vlax-curve-getpointatdist e1 n))
14.              (setq p2 (vlax-curve-getclosestpointto e2 p1))
15.              (while (and tmp (setq d2 (distance p2 tmp)) (< d2 d))
16.                (setq p1 (vlax-curve-getpointatdist e1 (setq n (+ n i))))
17.                (setq p2 (vlax-curve-getclosestpointto e2 p1))
18.              )
19.              (entmakex (list '(0 . "line") '(8 . "stripe") (cons 10 p1) (cons 11 p2)))
20.              (setq tmp p2)
21.              (setq n (+ n d))
22.            )
23.     )
24.   )
25.   (princ)
26. )

[MSTG007]

Ron, GEESH! Amazing. Lisp is like a second language to you; isn't it? lol

[steve.carson]

Ron, GEESH! Amazing. Lisp is like a second language to you; isn't it? lol

+1!

[ronjonp]

Thanks guys. I wouldn't really call it a second language  .. More of something I'm trying to get better at when I get the chance.