Topic: MTEXT to TEXT.

[FELIX]

How to get the text of a MTEXT with several lines?

OK.

[ribarm]

How to get the text of a MTEXT with several lines?

OK.

Have you tried EXPLODE command ?

[FELIX]

This serves me. If you have something better, please.
OK.

Code: [Select]

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun SPLIT-LINHA (str del / len lst pos SS II LL)
  (setq len (1+ (strlen del)))
  (while (setq pos (vl-string-search del str))
         (setq lst (cons (substr str 1 pos) lst))
         (setq str (substr str (+ pos len)))
  )
  (setq SS (reverse (cons str lst)))
  ;
  (SETQ LL '())
  (SETQ II 0)
  (REPEAT (LENGTH SS)
     (IF (/= "" (NTH II SS)) (SETQ LL (CONS (NTH II SS) LL)))
     (SETQ II (+ II 1))
  )
  (REVERSE LL)
)
;..............................................................................
(SETQ ENT (CAR (ENTSEL)))
(SETQ LIS (ENTGET ENT))
(SETQ TIP (CDR (ASSOC 0 LIS)))
(IF (= TIP "MTEXT")
  (PROGN
  (SETQ TXTSE (CDR (ASSOC  1 LIS)))
  (SETQ TXTPT (CDR (ASSOC 10 LIS)))
  (SETQ TXTHE (CDR (ASSOC 40 LIS)))
  (SETQ LTXT  (SPLIT-LINHA TXTSE "\\P"))
  )
)
(PRINT LTXT)
(PRINC)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


[rkmcswain]

Have you tried EXPLODE command ?

Maybe OP means when an MTEXT object contains more than 250 characters and is split up into multiple chunks?

[Lee Mac]

Something like this?

Code - Auto/Visual Lisp: [Select]

1. (defun mtextlines ( ent / enx itm str )
2.     (setq enx (reverse (entget ent))
3.           str (list (cdr (assoc 1 enx)))
4.     )
5.     (while (setq itm (assoc 3 enx))
6.         (setq str (cons (cdr itm) str)
7.               enx (cdr (member itm enx))
8.         )
9.     )
10.     (LM:str->lst (apply 'strcat str) "\\P")
11. )
12.  
13. ;; String to List  -  Lee Mac
14. ;; Separates a string using a given delimiter
15. ;; str - [str] String to process
16. ;; del - [str] Delimiter by which to separate the string
17. ;; Returns: [lst] List of strings
18.  
19. (defun LM:str->lst ( str del / pos )
20.     (if (setq pos (vl-string-search del str))
21.         (cons (substr str 1 pos) (LM:str->lst (substr str (+ pos 1 (strlen del))) del))
22.         (list str)
23.     )
24. )

Code - Auto/Visual Lisp: [Select]

1. (mtextlines (car (entsel)))

[FELIX]

Very good! Code more compact, as I like.

Okay and Close.